前文介绍了如果使用bochs来启动官网提供的镜像，本文将简单介绍如何编写一个软盘启动镜像，并通过bochs启动它，启动完成后，将在屏幕的最下方打印出红色的"Hello bochs!"，主要步骤如下：
- 了解BIOS对软盘引导分区的加载过程，可以参考这里
- 使用汇编编写程序将"Hello bochs!"输出到屏幕
- 将上一步编写的程序编译成二进制文件，写入到软盘镜像中
- 在bochsrc配置中增加上一步的软盘镜像为启动镜像
下面分别来看一下各个步骤：
编写"Hello bochs!"
本文采用nasm汇编器，代码如下：
; hello_bochs.asm
org 07c00h ; BIOS会跳到此处执行，但是CS段仍指向0，IP指向0x7c00，因此boot内的偏移需要以0x7c00为基准
mov ax, cs
mov ds, ax
mov es, ax
; 使用BIOS的0x10中断输出显示
mov bp, MessageDisp ; 显示字符串的地址，最终指向es:bp
mov cx, MessageDispLen ; 假设待显示字符个数存放在cx寄存器中，因此此处不需要设置
mov ah, 13h ; 功能码13h
mov al, 1 ; 显示方式为1：字符串中只包含字符，显示属性在bl中，光标位置改变
mov bl, 0ch ; 显示属性：黑底红字
mov bh, 0 ; 页码 0，当前还没有滚屏操作
mov dx, 1800h ; 0x18行，0列位置开始显示
int 10h
jmp $
MessageDisp: db "Hello bochs!"
MessageDispLen equ $ - MessageDisp
times 510-($-$$) db 0
dw 0xaa55
分为几个部分：
- 首先，引导扇区的代码是从0x7c00处开始执行，因此要告诉编译器，所有的地址计算都要基于0x7c00进行偏移，也就是
org 7c00h这句。 - 接着，加载对应的段寄存器，主要是数据段(ds)和es段，ds段用于定位待显示的字符内容，es段用于字符显示需要。
- 接着，调用BIOS提供的0x10中断显示指定的字符：es:bp指向待显示的字符起始位置；cx为待显示字符串的长度；ah=13h是显示字符串的功能码；al指定显示方式，此处为1；bl指定显示属性，此处为黑底红字；bh为页码，此处为0；dx指定显示的起始位置，实际为(dh,dl)=(行坐标,列坐标)，此处在24行0列，也就是显示屏的底部进行显示（显示屏为25*80）。
- 接着，定义待显示字符串的内容和长度。
- 接着，由于引导扇区是512字节，且引导扇区需要以0xAA55标记作为512字符的最后两个字符，因此要将中间不足512字节的位置填0，最后定义0xAA55标记，位于511和512字节处。
使用如下命令编译程序：
nasm hello_bochs.asm -o hello_bochs.bin
将编译好的程序写入到软盘镜像
首先，使用安装bochs时生成的bximage命令生成一个软盘镜像a.img，执行bximage命令后，输入1后会提示需要创建软盘还是硬盘镜像，继续输入fd创建软盘镜像，接着的输入直接回车使用默认即可，最终得到一个a.img的软盘镜像文件。
$ bximage
========================================================================
bximage
Disk Image Creation / Conversion / Resize and Commit Tool for Bochs
$Id: bximage.cc 14091 2021-01-30 17:37:42Z sshwarts $
========================================================================
1. Create new floppy or hard disk image
2. Convert hard disk image to other format (mode)
3. Resize hard disk image
4. Commit 'undoable' redolog to base image
5. Disk image info
0. Quit
Please choose one [0] 1
Create image
Do you want to create a floppy disk image or a hard disk image?
Please type hd or fd. [hd] fd
Choose the size of floppy disk image to create.
Please type 160k, 180k, 320k, 360k, 720k, 1.2M, 1.44M, 1.68M, 1.72M, or 2.88M.
[1.44M]
What should be the name of the image?
[a.img]
Creating floppy image 'a.img' with 2880 sectors
The following line should appear in your bochsrc:
floppya: image="a.img", status=inserted
将hello_bochs.bin写入到软盘的第1个扇区（也就是引导扇区），执行如下命令：
dd if=hello_bochs.bin of=a.img bs=512 count=1 conv=notrunc
在bochsrc配置中指定启动软盘镜像
bochs的配置文件简介可以参考这里，此处我们使用的配置如下，主要是指定了上一步生成的a.img作为我们的启动软盘镜像：
megs: 32
romimage: file=$BXSHARE/BIOS-bochs-latest
vgaromimage: file=$BXSHARE/VGABIOS-lgpl-latest
vga: extension=vbe, update_freq=15
floppya: 1_44=a.img, status=inserted
boot: floppy
log: bochsout.txt
mouse: enabled=0
cpu: ips=15000000
启动镜像
截止目前，我们的目录下包含的目录树结构如下：
test
├── a.img
├── bochsrc
├── hello_bochs.asm
└── hello_bochs.bin
在当前的目录下执行bochs -f bochsrc，输入6后会启动调试，继续输入c后最终得到的界面如下，可以看到在屏幕底部打印了我们想要的红色字符"Hello bochs!"。
启动效果
附录
本文所使用的环境信息
| 软件名称 | 软件版本 |
|---|---|
| Linux操作系统 | Ubuntu 22.04 LTS（X64） |
| bochs | 2.7 |
| nasm | 2.15.05 |
网友评论