泛型擦除引发的一个血案

先上代码
Node.java

public class Node<T> {
    public T data;
    public Node(T data) { this.data = data; }
    public void setData(T data) {
        System.out.println("Node.setData");
        this.data = data;
    }
}

MyNode.java

public class MyNode extends Node<Integer> {
    public MyNode(Integer data) { super(data); }
    public void setData(Integer data) {
        System.out.println("MyNode.setData");
        super.setData(data);
    }
}

Test.java

    public static void main(String[] args) {
        MyNode mn = new MyNode(5) ;
        Node n = mn; 
        n.setData("Hello"); 
 
    }

我们先想一下，执行Test.java 中的main方法会发生什么？哈哈，你们先想，我接着分析我的
想法，这几个类编译后应该是这样的
Node.java

public class Node {
    public Object data;
    public Node(Object  data) { this.data = data; }
    public void setData(Object  data) {
        System.out.println("Node.setData");
        this.data = data;
    }
}

MyNode.java

public class MyNode extends Node<Integer> {
    public MyNode(Integer data) { super(data); }
    public void setData(Integer data) {
        System.out.println("MyNode.setData");
        super.setData(data);
    }
}

Test.java

    public static void main(String[] args) {
        MyNode mn = new MyNode(5) ;
        Node n = mn; 
        n.setData("Hello"); 
    
    }

那么n.setData方法其实最终会调用到父类Node类中的setData（Object data）方法，所以最后会打印出Node.setData;.
好，分析完了，代码运行下，what？竟然报了一个String can not be cast to Integer 异常；咋回事啊。
其实代码很简单，结果却不能预期，这时候我们就要想想能否从字节码上看看，能不能找出端倪，因为源码上没有太多的信息了。
MyNode.class

// class version 51.0 (51)
// access flags 0x21
// signature Lnfc/ips/com/test/Node<Ljava/lang/Integer;>;
// declaration: nfc/ips/com/test/MyNode extends nfc.ips.com.test.Node<java.lang.Integer>
public class nfc/ips/com/test/MyNode extends nfc/ips/com/test/Node {

  // compiled from: MyNode.java

  // access flags 0x1
  public <init>(Ljava/lang/Integer;)V
   L0
    LINENUMBER 9 L0
    ALOAD 0
    ALOAD 1
    INVOKESPECIAL nfc/ips/com/test/Node.<init> (Ljava/lang/Object;)V
    RETURN
   L1
    LOCALVARIABLE this Lnfc/ips/com/test/MyNode; L0 L1 0
    LOCALVARIABLE data Ljava/lang/Integer; L0 L1 1
    MAXSTACK = 2
    MAXLOCALS = 2

  // access flags 0x1
  public setData(Ljava/lang/Integer;)V
   L0
    LINENUMBER 11 L0
    GETSTATIC java/lang/System.out : Ljava/io/PrintStream;
    LDC "MyNode.setData"
    INVOKEVIRTUAL java/io/PrintStream.println (Ljava/lang/String;)V
   L1
    LINENUMBER 12 L1
    ALOAD 0
    ALOAD 1
    INVOKESPECIAL nfc/ips/com/test/Node.setData (Ljava/lang/Object;)V
   L2
    LINENUMBER 13 L2
    RETURN
   L3
    LOCALVARIABLE this Lnfc/ips/com/test/MyNode; L0 L3 0
    LOCALVARIABLE data Ljava/lang/Integer; L0 L3 1
    MAXSTACK = 2
    MAXLOCALS = 2

  // access flags 0x1041
  public synthetic bridge setData(Ljava/lang/Object;)V
   L0
    LINENUMBER 8 L0
    ALOAD 0
    ALOAD 1
    CHECKCAST java/lang/Integer
    INVOKEVIRTUAL nfc/ips/com/test/MyNode.setData (Ljava/lang/Integer;)V
    RETURN
   L1
    LOCALVARIABLE this Lnfc/ips/com/test/MyNode; L0 L1 0
    MAXSTACK = 2
    MAXLOCALS = 2
}

我们会发现多了一个setData方法，这应该是是编译器生成的，CHECKCAST java/lang/Integer 这句话的翻译成java代码就是（Integer）Object,我们把 public synthetic bridge setData(Ljava/lang/Object;) 这个方法翻译下就变成了下面的了

  public void setData(Object data) {
      setData((Integer)data) ;
    }

原因我们就清楚了， n.setData("Hello")调用的是编译器生成的一个桥接的方法，如上，自然会报异常。