本文假定读者是没有Cypher语法基础的，故先补充介绍一点基本知识。

几个基本符号的含义：

• 节点：( )
• 关系：[ ]
• 节点的关系：-
• 关系的方向：->，<-，也可以不带方向，就是上一个

注意关键字同sql一样依然不区分大小写，注释使用“//”。

---

创建节点

• 创建最简单的单个节点

CREATE (n)

• 创建多个节点

CREATE (n),(m)

• 创建带标签的节点

CREATE (n:Stu)

• 创建带多个标签的节点

CREATE (n:Stu:Chinese)

• 创建带有标签和属性的节点

create (stu:Stu { id:1,name:"cyq7on",sex:"m" })

• 使用参数创建节点

{
  "props" : {
     "id":1
    "name" : "cyq7on",
    "sex" : "m"
  }
}
create (stu:Stu $props)

但是请注意，使用了参数进行创建和更新的操作，在浏览器和桌面客户端上都是不支持的，这种方式是开发API时使用的。

查找节点

一般与后面介绍的return命令一起使用

match (stu)
match (stu:Stu)
match (stu:Stu{id:"1"})

返回

返回的对象可以是节点、属性和关系

 return stu
 return stu.name,stu.sex

执行match (stu:Stu) return stu.name,stu.sex

执行match (stu:Stu) return stu

条件过滤

WHERE <condition>
WHERE <condition> <boolean-operator> <condition>

• 布尔运算符

AND
OR
NOT
XOR

• <condition>语法

<property-name> <comparison-operator> <value>

• 比较运算符

=
<>(不等于)
<
>
<=
>=
获取一条记录：
match (stu:Stu) where stu.name="cyq7on" and stu.sex="m" return stu

创建关系

MATCH (<node1-name>:<node1-label-name>),(<node2-name>:<node2-label-name>)
CREATE  
    (<node1-name>)-[<relationship-name>:<relationship-label-name>
    {<define-properties-list>}]->(<node2-name>)
RETURN <relationship-name>

新创建一个uestc节点并创建study in关系

match (stu:Stu) where stu.name="cyq7on" and stu.sex="m"
create (uestc:School{name:"uestc",location:"Chengdu"}),
(stu)-[study:STUDY_IN{start:"201809"}]->(uestc)
return study;

如果不使用该关系，study是可省的，即：
create (stu)-[:STUDY_IN{start:"201809"}]->(uestc)

删除节点、关系和路径

使用delete关键字

• 删除没有任何关系节点

MATCH (n { name: 'Andy' })
DELETE n

• 删除带有关系的节点

MATCH (n { name: 'Andy' })
DETACH DELETE n

为了测试删除，首先给男主找一个女朋友：

match (stu:Stu) where stu.name="cyq7on" and stu.sex="m"
create (qg:Stu{id:2,name:"Qiangu",sex:"f"}),
(stu)-[:LOVE{start:"201809"}]->(qg)

再添加一个跟男主没有关系的女神

create (goddess:Stu{id:3,name:"goddess",sex:"f"})

女神终究是遥不可及的：

match (n:Stu) where n.id=3
delete n

不使用where关键字的写法：

match (n:Stu{id:3})
delete n

男主单恋，分了：

match (boy:Stu)-[r:LOVE]-(girl:Stu)
where boy.id=1 and girl.id=2
DETACH DELETE r

又出现了一个女孩

create (anotherGril:Stu{id:4,name:"Zhang CY",sex:"f"})

和男主彼此相爱

match (boy:Stu) ,(girl:Stu)
where boy.id=1 and girl.id=4
create (boy)-[:LOVE{start:"201810"}]->(girl)

这里本想创建一个没有方向的关系,但是并不被允许

match (boy:Stu) ,(girl:Stu)
where boy.id=1 and girl.id=4
create (boy)-[:LOVE{start:"201810"}]-(girl)

Neo.ClientError.Statement.SyntaxError
Neo.ClientError.Statement.SyntaxError: Only directed relationships are supported in CREATE (line 3, column 13 (offset: 69))
"create (boy)-[:LOVE{start:"201810"}]-(girl)"
             ^

更新

使用set更新节点和关系的标签、属性

match (n:Stu{name:"cyq7on"})
set n.surname="Chen"

如果属性不存在则会添加，存在则更新

在set中加入表达式：

MATCH (n { name: 'cyq7on' })
SET (
CASE
WHEN n.id = 1
THEN n END ).hobby = 'pingpong'

更新所有属性的方式：

MATCH (n { name: "cyq7on" })
SET n = { name: "Chen YQ", position: 'Entrepreneur' }

删除属性：

match (n:Stu{name:"cyq7on"})
set n.surname=null
MATCH (n { name:"cyq7on"})
SET n = { }

使用参数：

{
  "surname" : "Chen"
}
MATCH (n { name:"cyq7on"})
SET n.surname = $surname

{
  "props" : {
    "name" : "Andy",
    "position" : "Developer"
  }
}
MATCH (n { name: "cyq7on"})
SET n = $props

删除属性、标签

使用remove删除节点和关系的属性、标签。使用remove能做的，set也能做，只是remove直观些。

• 删除属性

match(n{name:"cyq7on"})
remove n.hobby

• 删除节点标签

MATCH (n { name: 'Peter' })
REMOVE n:German
RETURN n.name, labels(n)

好了，最基本的增删改查都实践过了，第一篇就到此结束了。