bat 设置ip地址

@echo off
::双冒号表示注释，注释只能单独一行写，@表示不让执行的命令又显示在屏幕上
cls
::清屏
color 0A
::设置显示字体颜色
echo IP地址更改小工具
set IP=192.168.1.33
set MASK=255.255.255.0
set GATEWAY=192.168.1.1
set NAME="本地连接"
set DNS1="202.103.224.68"
set DNS2="202.103.225.68"

:ENTER
echo.
echo.
echo 更改为33的IP 请按 1
echo 手动更改IP 请按 2
echo 设置ip动态获取 请按 3
echo 设置dns动态获取 请按 4
echo 手动设置dns 请按 5
echo 显示网络配置信息 请按 6
echo 退出 请按 7

set /p KEY= [您的选择是：]
:: /p表示将KEY设置为输入行
if %KEY% == 1 goto ONE
if %KEY% == 2 goto TWO
if %KEY% == 3 goto THREE
if %KEY% == 4 goto FOUR
if %KEY% == 5 goto FIVE
if %KEY% == 6 goto SIX
if %KEY% == 7 goto EXIT

:TWO
ECHO 您选择了手工修改设置。
ECHO.
echo 默认IP地址是%IP%，回车输入默认地址
set /p IP= [请输入IP地址:]
echo.
echo 默认MASK是%MASK%，回车输入默认值
set /p MASK= [请输入 子网掩码 地址:]
echo.
echo 默认GATEWAY是%GATEWAY%，回车输入默认值
set /p GATEWAY= [请输入 网关 地址:]
echo.

:ONE
echo 正在自动更改IP......
netsh interface ip set address %NAME% static %IP% %MASK% %GATEWAY%
echo IP地址/子网掩码/网关设置完成
goto ENTER

:THREE
netsh interface ip set address name="本地连接" source=dhcp
echo IP地址设置完成
goto ENTER

:FOUR
netsh interface ip set dns name="本地连接" source=dhcp
echo dns设置完成
goto ENTER

:FIVE
echo 默认DNS1地址是%DNS1%，回车输入默认地址
set /p DNS1= [请输入DNS1地址:]
echo.
echo 默认DNS2地址是%DNS2%，回车输入默认地址
set /p DNS2= [请输入DNS2地址:]
echo.

echo 正在设置DNS......
netsh interface ip add dns "本地连接" %DNS1% index=1 >nul
netsh interface ip add dns "本地连接" %DNS2% index=2 >nul
echo dns设置完成
goto ENTER

:SIX
ipconfig /all
goto ENTER

:EXIT
pause
exit