iOS - isa指针

[toc]

参考

isa指针

isa 简介

isa (is a kind of) 是一个 Class 类型的指针, 而 Class 是 struct objc_class * 的别名, 所以 isa 实际上是指向 objc_class 类型结构体 的指针。

可以理解为是谁的实例

isa 指向

• instance 的 isa 指向 class

  • 当调用对象方法时，通过instance的isa找到class，最后找到对象方法的实现进行调用

• class 的 isa 指向 meta-class

  • 当调用类方法时，通过class的isa找到meta-class，最后找到类方法的实现进行调用

• 根类的isa指向根元类, 而根元类也继承自根类

<img src="https://cdn.jsdelivr.net/gh/coder-felix/image/20200605155514.png" style="zoom:50%;" />

isa 地址

查看实例对象 isa 指向的地址

查看的是 struct objc_object 的 isa 指针

(lldb)p person->isa // 控制台输出 person 所属的类 QGPerson

(lldb)p/x (long)person->isa // 控制台输出 isa 的十六进制地址值

查看类对象 isa 指向的地址

查看的是 struct objc_class 的 isa 指针

因为类对象的isa没有暴露出来, 所以 p/x personClass->isa 这样是查看不到的

// 根据系统的 objc_class 新建一个结构体, 用于指向 personClass
struct qg_objc_class {
    Class isa;
    Class superclass;
};

// OC对象桥接给C结构体
struct qg_objc_class *personClass = (__bridge struct qg_objc_class *)([Person class]);

p/x (long)personClass -> isa // 

真实地址需要位运算

从 64bit 开始，isa需要进行一次位运算，由 isa & ISA_MASK 计算出真实地址。

注: superclass 指针不需要这个位运算, 直接指向父class地址

<img src="https://cdn.jsdelivr.net/gh/coder-felix/image/20200605175643.png" style="zoom: 50%;" />

image

---

isa 底层 ★

基础知识分解

共用体 + 掩码 + 位域

实现内存优化

#import "Person.h"

#define TallMask (1<<0)
#define RichMask (1<<1)
#define HandsomeMask (1<<2)
#define ThinMask (1<<3)

@interface Person()
{
    // 共用体
    // 大家共用一块内存, 共用这一个字节
    // 存取采用位运算, 使用位域增加可读性
    union {
        // 外界访问的是 bits
        char bits;
        // 位域
        // 在共用体这里, 仅仅是为了增加代码可读性, 没有实质作用, 不影响存储
        // 这个结构体与 bits 共用一个字节
        struct {
            char tall : 1; // : 1 代表只占1位, 与前面的char类型无关, 这个存储在最低位 ★
            char rich : 1;
            char handsome : 1;
            char thin : 1;
        };
    } _tallRichHandsome;
}
@end

@implementation Person

// 使用位运算, 更高效
- (void)setTall:(BOOL)tall {
    if (tall) { // 1 按位或
        _tallRichHandsome.bits |= TallMask;
    } else { // 0  按位取反, 再按位与
        _tallRichHandsome.bits &= ~TallMask;
    }
}

- (BOOL)isTall {
    return !!(_tallRichHandsome.bits & TallMask);
}

- (void)setRich:(BOOL)rich {
    if (rich) {
        _tallRichHandsome.bits |= RichMask;
    } else {
        _tallRichHandsome.bits &= ~RichMask;
    }
}

- (BOOL)isRich {
    return !!(_tallRichHandsome.bits & RichMask);
}

- (void)setHandsome:(BOOL)handsome {
    if (handsome) {
        _tallRichHandsome.bits |= HandsomeMask;
    } else {
        _tallRichHandsome.bits &= ~HandsomeMask;
    }
}

- (BOOL)isHandsome {
    return !!(_tallRichHandsome.bits & HandsomeMask);
}


- (void)setThin:(BOOL)thin {
    if (thin) {
        _tallRichHandsome.bits |= ThinMask;
    } else {
        _tallRichHandsome.bits &= ~ThinMask;
    }
}

- (BOOL)isThin {
    return !!(_tallRichHandsome.bits & ThinMask);
}

@end

---

isa union ★

在 arm64 架构之前, isa就是一个普通的指针, 存储着 Class、Meta-Class 对象的内存地址;

从 arm64 架构开始, 对isa进行了优化, 变成了一个 union , 这8个字节(64位)不仅仅用来放地址值(其中33位), 还使用位域来存储更多的信息; ★

isa_t

// objc-private.h
// 共用体
union isa_t {
    isa_t() { }
    isa_t(uintptr_t value) : bits(value) { }

    Class cls;
    uintptr_t bits; // 主要成员, 通过bits获取isa的相关数据
#if defined(ISA_BITFIELD)
    struct {
        ISA_BITFIELD;  // 位域 defined in isa.h
    };
#endif
};

ISA_BITFIELD

// isa.h
ISA_BITFIELD in arm64: 

// 0: 代表是普通的指针, 存储着Class、Meta-Class对象的内存地址
// 1: 代表优化过, 使用位域存储更多的信息
uintptr_t nonpointer        : 1; 
// 是否有设置过关联对象(就算清空了, 也是设置过), 如果没有, 释放时会更快
uintptr_t has_assoc         : 1; 
// 是否有C++的析构函数（.cxx_destruct）, 如果没有, 释放时会更快
uintptr_t has_cxx_dtor      : 1; 
// 存储着Class、Meta-Class对象的内存地址信息
uintptr_t shiftcls          : 33;
// 用于在调试时分辨对象是否未完成初始化
uintptr_t magic             : 6; 

// 是否有被弱引用指向过(就算清空了, 也是指向过), 如果没有, 释放时会更快
// 弱指针 weak 存储在 SideTable 中 ★
uintptr_t weakly_referenced : 1; 
// 对象是否正在释放
uintptr_t deallocating      : 1; 

// 引用计数器是否过大无法存储在 isa 中 (大于19bit) ★
// 若为1, 引用计数会存储在单独的结构体 SideTable 中
// 若为0, 引用计数会存储在 isa 的 extra_rc 中
uintptr_t has_sidetable_rc  : 1; 

// 里面存储的值是引用计数器减1
uintptr_t extra_rc          : 19

ISA()

inline Class objc_object::ISA() {
    ASSERT(!isTaggedPointer()); 
#if SUPPORT_INDEXED_ISA
    if (isa.nonpointer) {
        uintptr_t slot = isa.indexcls;
        return classForIndex((unsigned)slot);
    }
    return (Class)isa.bits;
#else
    return (Class)(isa.bits & ISA_MASK);
#endif
}

// arm64
#define ISA_MASK        0x0000000ffffffff8ULL 
// __x86_64__
#define ISA_MASK        0x00007ffffffffff8ULL // shiftcls : 44

ISA_MASK 对应二进制是 0b111...111000 (33个1 + 3个0)
所以, 类对象, 元类对象的地址值, 最后三位永远是0 (对应十六进制, 最后一位, 只可能是0或8)

---

SideTable

// NSObject.mm
struct SideTable {
    spinlock_t slock;
    RefcountMap refcnts; // 一个存放着对象引用计数的散列表

    weak_table_t weak_table; // 弱引用表

    SideTable() {
        memset(&weak_table, 0, sizeof(weak_table));
    }

    ~SideTable() {
        _objc_fatal("Do not delete SideTable.");
    }

    void lock() { slock.lock(); }
    void unlock() { slock.unlock(); }
    void forceReset() { slock.forceReset(); }

    // Address-ordered lock discipline for a pair of side tables.

    template<HaveOld, HaveNew>
    static void lockTwo(SideTable *lock1, SideTable *lock2);
    template<HaveOld, HaveNew>
    static void unlockTwo(SideTable *lock1, SideTable *lock2);
};

RefcountMap

// RefcountMap disguises its pointers because we 
// don't want the table to act as a root for `leaks`.
typedef objc::DenseMap<DisguisedPtr<objc_object>, size_t, RefcountMapValuePurgeable> RefcountMap;

weak_table_t

见《weak》

weak_entry_t

见《weak》