我们紧接着上一部分的内容，继续讨论表达式。
        有了上一部分的基础，相信大家对这样的抽象描述已经有所了解了。类似的，我们可以直接写出包含关系和逻辑运算符的表达式的描述。

relation_expression : additive_expression
                    | relation_expression < additive_expression
                    | relation_expression <= additive_expression
                    | relation_expression > additive_expression
                    | relation_expression >= additive_expression

equality_expression : relation_expression
                    | equality_expression == relation_expression
                    | equality_expression != relation_expression

logical_and_expression : equality_expression
                       | logical_and_expression && equality_expression

logical_or_expression : logical_and_expression
                      | logical_or_expression || logical_and_expression

        不知道大家有没有注意到一个细节：这些表达式为何这样安排？这其实涉及到C语言中运算符优先级的问题，例如：&&就比||优先级高。也就是说，在列出的这些表达式描述中，运算符优先级从上到下依次递减。其实，在上一部分我们处理四则运算表达式时也是基于同样的考虑：乘除法优先级高于加减法。只是这里列出的由表达式顺序决定运算符优先级的方式更加明显而已。
        在写出带赋值运算符的表达式之前，我们需要理解一下C语言中的两个概念：左结合和右结合。

• 左结合
  对于表达式a + b + c，C语言是默认执行(a + b) + c这样的运算顺序（除非用括号显示地进行操作分配）。这样的运算方式就称之为左结合。
• 右结合
  对于表达式a = b = c + d，C语言是默认执行a = (b = (c + d))这样的运算顺序（除非用括号显示地进行操作分配）。这样的运算方式就称之为右结合。

        再回过头看之前我们写出来的这些表达式的描述方法，它们都出现在自己运算符的左边，这样保证了我们能够按照左结合的方式去处理。那么，触类旁通，包含赋值运算符的表达式的描述就该写成：

expression : logical_or_expression
           | logical_or_expression = expression

我不知道商业化的编译器是怎样实现的这个过程，但是通过学习这部分的内容，对于C语言表达式的运算实际结果就有了一个清晰的认识，知其然也知其所以然了。
我们将表达式的这些描述方法都汇总起来，之前用primary_expression表示的，现在可以都用expression来描述，这样就扩展了C语言所支持的表达式形式的范围。例如，primary_expression可以更新为：

primary_expression : ( expression )
                   | CHAR
                   | INT
                   | ID

        到此，我们的表达式描述已经基本上涵盖了C语言中出现的大部分表达式，剩下没有出现的我们将在后面进行介绍。
        至于实现，都大同小异，这里就不在重复了。

3.2 语句（statement）

        在前面的表达式中，我们从最小单元primary_expression起逐渐构建起最终完整的表达式expression。但是，和表达式的这种自底向上的分析方法相反，我们需要采用自顶向下的方式来分析C语言中出现的语句，因为语句都是层层嵌套的，并不按照递归的方式进行实现。因此，为了方便，我们将语句分成以下几类：

• 表达式语句（expression statement）
  表达式后面用分号结尾的语句，语法结构为：

expression_statement : expression ;

• 跳转语句（jump statement）
  类似于break，continue和return的这类语句，目的是使程序“跳转”到期望的位置上，它们的语法结构可以表示为：

jump_statement : RETURN ;
               | RETURN expression ;
               | BREAK ;
               | CONTINUE ;

• 迭代语句（iteration statment）
  即进行循环运算的过程的语句，比如for和while，它们的语法结构可以表示为：

iteration_statement : FOR ( expression ; expression ; expression ) statement
                    | WHILE ( expression ) statement
                    | DO statement WHILE ( expression ) ;

这里的statement就是所有语句的集合。

• 选择语句（selection statement)
  即有选择性地执行的语句，如if和switch。它们的语法结构如下：

selection_statement : IF ( expression ) statement
                    | IF ( expression ) statement ELSE statement

• 复合语句（compound statement）
  就是一对大括号内的所有语句（可能不太准确，因为大括号内还可以包含声明，我们将在后面详细介绍），它的语法结构可以表示为：

compound_statement : { declaration_list }
                   | { declaration_list statement_list }

这里的statement_list和declaration_list是语句和声明的组合，可以描述为：

statement_list : statement 
               | statement_list statement

declaration_list : declaration 
                 | declaration_list declaration

• 空语句（empty statement）
  只包含分号的语句，语法结构为：

empty_statement : ;

        最后，我们将这些语句组合在一起，得到最终的语句集合描述：

statement : expression_statement
          | jump_statement
          | iteration_statement
          | selection_statement
          | compound_statement
          | empty_statement

        一旦搭建了底层的实现模板，不管是表达式还是语句，只需要按照这样的一种模式，就能非常简单快速地编写语法分析的实现代码了，具体代码我们会在后面介绍。
        语法分析的过程就是这样，给定期望的语法模板，如果匹配，就进行下一项匹配；否则，停止并返回错误。下一部分即将分析的声明部分也是这样，大家可以看一看C语言代码，如何归纳总结出它们的描述。

实现简易的C语言编译器（part 0）
实现简易的C语言编译器（part 1）
实现简易的C语言编译器（part 2）
实现简易的C语言编译器（part 3）
实现简易的C语言编译器（part 5）
实现简易的C语言编译器（part 6）
实现简易的C语言编译器（part 7）
实现简易的C语言编译器（part 8）
实现简易的C语言编译器（part 9）