动态分派

动态分派的实现过程与Java语言多态性的另外一个重要体现——重写（Override）有着密切的关联。
使用代码来讲解动态分派：

package com.test;

/**
 * 方法动态分派演示
 * @author huyl
 *
 */
public class DynamicDispatch {

    static abstract class Human{
        protected abstract void sayHello();
    }
    
    static class Man extends Human{
        protected void sayHello(){
            System.out.println("man say hello");
        }
    }
    
    static class Woman extends Human{
        protected void sayHello(){
            System.out.println("woman say hello");
        }
    }
    
    public static void main(String[] args) {
        Human man = new Man();
        Human woman = new Woman();
        man.sayHello();
        woman.sayHello();
        man = new Woman();
        man.sayHello();
    }
}

运行结果

man say hello
woman say hello
woman say hello

分析：
Java虚拟机是如何判断应该调用哪个方法的？
显然这里选择调用的方法版本是不可能再根据静态类型来决定的，因为静态类型同样是Human的两个变量man和woman在调用sayHello()方法时产生了不同的行为，甚至变量man在两次调用中还调用中还执行了两个不同的方法。导致这个现象的原因很明显，是因为这两个变量的实际类型不同，Java虚拟机是如何根据实际类型来分派方法执行版本的呢？
使用javap命令输出这段代码的字节码，输出结果如下：

D:\Program Files\Java\jdk1.8.0_40\bin>javap -c -l D:\workspace\Test\bin\com\test\DynamicDispatch.class
Compiled from "DynamicDispatch.java"
public class com.test.DynamicDispatch {
  public com.test.DynamicDispatch();
    Code:
       0: aload_0
       1: invokespecial #8                  // Method java/lang/Object."<init>":()V
       4: return
    LineNumberTable:
      line 8: 0
    LocalVariableTable:
      Start  Length  Slot  Name   Signature
          0       5     0  this   Lcom/test/DynamicDispatch;

  public static void main(java.lang.String[]);
    Code:
       0: new           #16                 // class com/test/DynamicDispatch$Man
       3: dup
       4: invokespecial #18                 // Method com/test/DynamicDispatch$Man."<init>":()V
       7: astore_1
       8: new           #19                 // class com/test/DynamicDispatch$Woman
      11: dup
      12: invokespecial #21                 // Method com/test/DynamicDispatch$Woman."<init>":()V
      15: astore_2
      16: aload_1
      17: invokevirtual #22                 // Method com/test/DynamicDispatch$Human.sayHello:()V
      20: aload_2
      21: invokevirtual #22                 // Method com/test/DynamicDispatch$Human.sayHello:()V
      24: new           #19                 // class com/test/DynamicDispatch$Woman
      27: dup
      28: invokespecial #21                 // Method com/test/DynamicDispatch$Woman."<init>":()V
      31: astore_1
      32: aload_1
      33: invokevirtual #22                 // Method com/test/DynamicDispatch$Human.sayHello:()V
      36: return
    LineNumberTable:
      line 27: 0
      line 28: 8
      line 29: 16
      line 30: 20
      line 31: 24
      line 32: 32
      line 33: 36
    LocalVariableTable:
      Start  Length  Slot  Name   Signature
          0      37     0  args   [Ljava/lang/String;
          8      29     1   man   Lcom/test/DynamicDispatch$Human;
         16      21     2 woman   Lcom/test/DynamicDispatch$Human;
}

• 0-15行的字节码时准备动作，作用是建立man和woman的内存空间、调用Man和Woman类型的实例构造器，将这两个实例的引用存放在第1、2个局部变量表的变量槽中，这些动作实际对应了Java源码中的：

Human man = new Man();
Human woman = new Woman();

• 16-21行是关键部分，16和20行的aload指令分别把刚刚创建的两个对象的引用压到栈顶，这两个对象是将执行的sayHello()方法的所有者，称为接收者（Receiver）；17和21行是方法调用指令，这两条调用指令单从字节码角度来看，无论是指令（invokevirtual）还是参数（都是常量池中第22项的常量，注释显示了这个常量时Human.sayHello()的符号引用）都完全一样，但是这两句指令最终执行的目标方法并不相同。解释问题的关键还必须从invokevirtual指令本身入手，要弄清楚它是如何确定调用方法版本、如何实现多台查找来着手分析才行。

根据《Java虚拟机规范》,invokevirtual指令的运行时解析过程大致如下几步：
1.找到操作数栈顶的第一个元素所指向的对象的实际类型，记作C。
2.如果在类型C中找到与常量中的描述符合简单名称都相符的方法，则进行访问权限校验，如果通过则返回这个方法的直接引用，查找过程结束；不通过则返回java.lang.IllegalAccessError异常。
3.否则，按照继承关系从下往上依次对C的各个父类进行第二步的搜索和验证过程。
4.如果始终没有找到合适的方法，则抛出java.lang.AbstractMethodError异常。

正是因为invokevirtual指令执行的第一步就是在运行期确定接收者的实际类型，所以两次调用中的invokevirtual指令并不是把常量池中方法的符号引用解析到直接引用上就结束了，还会根据方法接收者的实际类型来选择方法版本，这个过程就是Java语言中方法重写的本质，我们把这种在运行期根据实际类型确定方法执行版本的分派过程称为动态分派。

既然这种多态性的根源在于虚方法调用指令invokevirtual的执行逻辑，那结论就是只会对方法有效，对字段是无效的，因为字段不适用这条指令。事实上，在Java里面只有虚方法存在，字段永远不可能是虚的，换句话说，字段永远不参与多态，哪个类的方法访问某个名字的字段时，该名字指的就是这个类能看到的那个字段。当子类声明了与父类同名的字段时，虽然在子类的内存中两个字段都会存在，但是子类的字段会遮蔽父类的同名字段。

内容来源于《深入理解Java虚拟机》第三版