文章内容截取于SAS编程：Fopen系列函数介绍。
之前SAS宏程序：批量获取文件的修改时间介绍了，SAS如何通过调用本机电脑CMD语句的返回结果，批量获取文件的修改时间。
我在公司服务器系统上，使用这个方法时发现，SAS访问CMD结果被拒绝了，可能是SAS系统选项的原因，也可能公司设定的权限问题，我没去深究。
这篇文章通过SAS自身语句获取单个文件的修改时间，后续介绍如何批量获取修改时间。
我使用以下路径文件进行演示，路径中有4个.sas文件、4个.log文件，以及1个文件夹，共9个文件。
Directory
过程涉及以下3个函数：
- FOPEN
- FOPTNAME
- FINFO
1. FOPEN(fileref <, open-mode <, record-length <, record-format>>>)
FOPEN函数的作用是，打开一个外部文件，并返回一个文件标识值 (Opens an external file and returns a file identifier value.)。
这可以理解为，在一次SAS会话中，给外部文件发放身份证明，这个证明与外部文件是一一对应的，就像人的身份证一样。人有了身份证，可以进行诸如乘高铁、坐飞机的活动；在SAS会话中，外部文件有了“身份证”，也可以进行一些“特定活动”，例如获取一些文件属性信息。
FEOPEN函数的主要参数值是一个文件引用(fileref)，这个文件引用必须在调用函数前与特定文件路径进行关联，常用的文件关联方式有两种：
第1种，全局filename语句：
filename filepath "E:\99_Test\Test\test1\ae.sas";
第2种，filename函数：
data test;
fileres = filename("filepath", "E:\99_Test\Test\test1\ae.sas");
run;
如果关联成功，filename函数会返回0；如果关联失败，filename函数会返回非0值。
文件引用关联成功后，就可以使用FOPEN函数打开，函数在该SAS会话中，返回外部文件对应的“身份证号”。
**fopen;
%let filepath = E:\99_Test\Test\test1\ae.sas;
data tmp;
fileres = filename("filepath","&filepath.");
fileid= fopen("filepath");
run;
Fopen
Filename函数返回0值，说明文件引用关联成功。Fopen函数返回的路径“身份证号”的值为1。
其他信息可以参考SAS文档：SAS Help Center: FOPEN Function。
2. FOPTNAME(file-id, nval)
FOPTNAME函数的作用是，返回外部文件的属性名称(Returns the name of an item of information about an external file)。
FOPTNAME函数有2个参数，一个是FOPEN返回的外部文件的“身份证号”，另一个是外部文件具体属性的次序，每一个次序对应一个外部文件的属性名称。在不同的电脑操作系统中，SAS读取到的属性是不同的。
在Windows操作系统中，外部文件属性有6个：
- Filename
- RECFM
- LRECL
- File Size (bytes)
- Last Modified
- Create Time
在UNIX操作系统中，外部属性也有6个：
- Filename
- Owner Name
- Group Name
- Access Permission
- Last Modified
- File size (bytes)
不同的SAS系统语言，返回的结果也不同。以Windows系统为例，举例如下：
**doptname;
%let dirpath = E:\99_Test\Test\test1;
data tmp;
fileres = filename("filepath", "&filepath.");
fileid = fopen("filepath");
length optname $200;
optnum = 1; optname = foptname(fileid, 1); output;
optnum = 2; optname = foptname(fileid, 2); output;
optnum = 3; optname = foptname(fileid, 3); output;
optnum = 4; optname = foptname(fileid, 4); output;
optnum = 5; optname = foptname(fileid, 5); output;
optnum = 6; optname = foptname(fileid, 6); output;
optnum = 7; optname = foptname(fileid, 7); output;
run;
不同的SAS系统语言，返回的属性名称也不同：
中文环境
英文环境
因为Windows系统中，FOPTNAME函数只能返回6个外部文件的属性。当次序值取7时，函数返回值就为空，同时Log中也会输出错误信息描述。
Log
其他信息可以参考SAS文档：SAS Help Center: FOPTNAME Function。
3. FINFO(file-id, information-item)
FINFO函数的作用是，返回外部文件属性的具体信息(Returns information about a directory)。
这个函数是获取文件修改时间的主要步骤。
FINFO函数有2个参数，一个是外部文件的“身份证号”，另一个是外部文件的属性名称，名称因SAS系统语言的不同而不同。属性名称可以参考FOPTNAME函数的返回值。
中文环境：
**dinfo-Chinese;
%let filepath = E:\99_Test\Test\test1\ae.sas;
data tmp;
fileres = filename("filepath", "&filepath.");
fileid = fopen("filepath");
length optname optvalue $200;
optname = "文件名"; optvalue = finfo(fileid, "文件名"); output;
optname = "RECFM"; optvalue = finfo(fileid, "RECFM"); output;
optname = "LRECL"; optvalue = finfo(fileid, "LRECL"); output;
optname = "文件大小（字节）"; optvalue = finfo(fileid, "文件大小（字节）"); output;
optname = "上次修改时间"; optvalue = finfo(fileid, "上次修改时间"); output;
optname = "创建时间"; optvalue = finfo(fileid, "创建时间"); output;
run;
Fino-Chinese
英文环境：
**dinfo-English;
%let filepath = E:\99_Test\Test\test1\ae.sas;
data tmp;
fileres = filename("filepath", "&filepath.");
fileid = fopen("filepath");
length optname optvalue $200;
optname = "Filename"; optvalue = finfo(fileid, "Filename"); output;
optname = "RECFM"; optvalue = finfo(fileid, "RECFM"); output;
optname = "LRECL"; optvalue = finfo(fileid, "LRECL"); output;
optname = "File Size (bytes)"; optvalue = finfo(fileid, "File Size (bytes)"); output;
optname = "Last Modified"; optvalue = finfo(fileid, "Last Modified"); output;
optname = "Create Time"; optvalue = finfo(fileid, "Create Time"); output;
run;
Fino-English
获取文件修改时间，只需要单单读取上次修改时间或Last Modified就可以。
其他信息可以参考SAS文档：SAS Help Center: FINFO Function。
相关阅读：
SAS编程：Fopen系列函数介绍
SAS编程：Dopen系列函数介绍
SAS编程：如何获取某路径下文件的名称？
感谢阅读， 欢迎关注！
若有疑问，欢迎评论交流！
网友评论