OpenGL ES光照公式及GLSL实现

1.光照特性

1. 发射光:由物体自身发光
2. 环境光:就是在环境中充分散射的光，而且无法分辨它的方向
3. 漫反射光:光线来自某个方向，但在物体上各个方向反射。
4. 镜面高光:光线来自一个特定的方向，然后在物体表面上以一个特定的
   方向反射出去

2.材质特性

1. 泛射材质
2. 漫反射材质
3. 镜面反射材质
4. 发射材质

3. 光照计算公式

1. 环境光 = 光源的环境光颜色 * 物体的材质颜色

2. 发射光 = 物体的反射材质颜色

3. 漫反射颜色 = 光源的漫反射颜⾊ * 物体的漫发射材质颜色 * DiffuseFactor DiffuseFactor = max(0,dot(N,L)) -->漫反射因子

4. 镜⾯反射颜色 = 光源的镜⾯光的颜色 * 物体的镜⾯材质颜⾊ * SpecularFactor SpecularFactor = power(max(0,dot(N,H)),shininess)
   H :视线向量E 与 光线向量L 的半向量 dot(N,H):H,N的点积⼏何意义,平方线与法线夹角的cos值
   shiniess : ⾼高光的反光度;

5.光照颜⾊ =(环境颜色 + 漫反射颜色 + 镜⾯反射颜色)* 衰减因⼦

6.衰减因⼦ = 1.0/(距离衰减常量 + 线性衰减常量 * 距离 + 二次衰减常量 * 距离的平⽅)
距离衰减常量,线性衰减常量和⼆次衰减常量均为常量值
环境光，漫反射光和镜面光的强度都会受距离的增⼤而衰减，只有发射光和全局环境光的强度不会受影响

7.聚光灯因子
聚光灯夹⻆cos值 = power(max(0,dot(单位光源位置，单位光线向量)),聚光灯指数);
单位光线向量是从光源指向顶点的单位向量 聚光灯指数，表示聚光灯的亮度
公式解读:单位光源位置 * 单位光线向量 点积 的 聚光灯指数次⽅
聚光灯因子 = clamp((外环的聚光灯⻆度cos值 - 当前顶点的聚光灯⻆度cos值)/ (外环的聚光灯角度cos值- 内环聚光灯的⻆度的cos值),0,1);

8.光照计算终极公式
光照颜⾊ = 发射颜色 + 全局环境颜色 + (环境颜⾊ + 漫反射颜色 + 镜⾯反射颜色) * 聚光灯效果 * 衰减因⼦

4.GLSL 光照计算

1.顶点着色器

#version 300 es

layout(location = 0) in vec3 position;  //顶点
layout(location = 1) in vec3 normal;    //法向量
layout(location = 2) in vec2 texCoord;  //纹理坐标

uniform mat4 view; // 模型视图矩阵
uniform mat4 projection; // 投影矩阵

out vec3 outNormal; //法向量
out vec3 FragPo;    //顶点在世界坐标位置
out vec2 outTexCoord;//纹理坐标

void main()
{

    FragPo = position;
    outNormal = normal;
    outTexCoord = texCoord;
    gl_Position = projection * view * vec4(position,1.0);
    
}

2.片元着色器

#version 300 es

precision mediump float;
out vec4 FragColor;

uniform vec3 lightColor;    //光源颜色
uniform vec3 lightPo;       //光源位置
uniform vec3 viewPo;        //视角位置
uniform sampler2D Texture;          //物体纹理
uniform sampler2D specularTexture;  //镜面纹理

in vec2 outTexCoord;    //纹理坐标
in vec3 outNormal;      //顶点法向量
in vec3 FragPo;         //顶点坐标

//点光源版本
void pointLight(){
    
    float ambientStrength = 0.3;    //环境因子
    float specularStrength = 2.0;   //镜面强度
    float reflectance = 256.0;      //反射率

    float constantPara = 1.0f;     //距离衰减常量
    float linearPara = 0.09f;      //线性衰减常量
    float quadraticPara = 0.032f;  //二次衰减常量

    //环境光 = 环境因子 * 物体的材质颜色
    vec3 ambient = ambientStrength * texture(Texture,outTexCoord).rgb;

    //漫反射
    vec3 norm = normalize(outNormal);
    //当前顶点 至 光源的的单位向量
    vec3 lightDir = normalize(lightPo - FragPo);
    //DiffuseFactor=光源与法线夹角 max(0,dot(N,L))
    float diff = max(dot(norm,lightDir),0.0);
    //漫反射光颜色计算 = 光源的漫反射颜色 * 物体的漫发射材质颜色 * DiffuseFactor
    vec3 diffuse = diff * lightColor*texture(Texture,outTexCoord).rgb;

    //镜面反射
    vec3 viewDir = normalize(viewPo - FragPo);
    // reflect (genType I, genType N),返回反射向量
    vec3 reflectDir = reflect(-lightDir,outNormal);
    //SpecularFactor = power(max(0,dot(N,H)),shininess)
    float spec = pow(max(dot(viewDir, reflectDir),0.0),reflectance);
    //镜面反射颜色 = 光源的镜面光的颜色 * 物体的镜面材质颜色 * SpecularFactor
    vec3 specular = specularStrength * spec * texture(specularTexture,outTexCoord).rgb;

    //衰减因子计算
    float LFDistance = length(lightPo - FragPo);
    //衰减因子 =  1.0/(距离衰减常量 + 线性衰减常量 * 距离 + 二次衰减常量 * 距离的平方)
    float lightWeakPara = 1.0/(constantPara + linearPara * LFDistance + quadraticPara * (LFDistance*LFDistance));
    
    //光照颜色 =(环境颜色 + 漫反射颜色 + 镜面反射颜色)* 衰减因子
    vec3 res = (ambient + diffuse + specular)*lightWeakPara;

    //最终输出的颜色
    FragColor = vec4(res,1.0);

}

// 平行光版本
void parallelLight(){
  
    float ambientStrength = 0.3;    //环境因子
    float specularStrength = 2.0;   //镜面强度
    float reflectance = 256.0;      //反射率

    //平行光方向
    //vec3 paraLightDir = normalize(vec3(-0.2,-1.0,-0.3));
    vec3 paraLightDir =normalize(vec3(-1,-1,1));

    //环境光 = 环境因子 * 物体的材质颜色
    vec3 ambient = ambientStrength * texture(Texture,outTexCoord).rgb;

    //漫反射
    vec3 norm = normalize(outNormal);
    //当前顶点至光源的的单位向量
    vec3 lightDir = normalize(lightPo - FragPo);
    //DiffuseFactor=光源与paraLightDir 平行光夹角 max(0,dot(N,L))
    float diff = max(dot(norm,paraLightDir),0.0);
    //漫反射光颜色计算 = 光源的漫反射颜色 * 物体的漫发射材质颜色 * DiffuseFactor
    vec3 diffuse = diff * lightColor * texture(Texture,outTexCoord).rgb;

    //镜面反射
    vec3 viewDir = normalize(viewPo - FragPo);
    // reflect (genType I, genType N),返回反射向量 -paraLightDir平行光
    vec3 reflectDir = reflect(-paraLightDir,outNormal);
    //SpecularFactor = power(max(0,dot(N,H)),shininess)
    float spec = pow(max(dot(viewDir, reflectDir),0.0),reflectance);
    //镜面反射颜色 = 光源的镜面光的颜色 * 物体的镜面材质颜色 * SpecularFactor
    vec3 specular = specularStrength * spec * texture(specularTexture,outTexCoord).rgb;

    //距离衰减常量
    float constantPara = 1.0f;
    //线性衰减常量
    float linearPara = 0.09f;
    //二次衰减常量
    float quadraticPara = 0.032f;
    //衰减因子计算
    float LFDistance = length(lightPo - FragPo);
    //衰减因子 =  1.0/(距离衰减常量 + 线性衰减常量 * 距离 + 二次衰减常量 * 距离的平方)
    float lightWeakPara = 1.0/(constantPara + linearPara * LFDistance + quadraticPara * (LFDistance*LFDistance));

    //光照颜色 =(环境颜色 + 漫反射颜色 + 镜面反射颜色)* 衰减因子
    vec3 res = (ambient + diffuse + specular)*lightWeakPara;
    
    //最终输出的颜色
    FragColor = vec4(res,1.0);
}

//聚光版本
void Spotlight(){
   
    float ambientStrength = 0.3;    //环境因子
    float specularStrength = 2.0;   //镜面强度
    float reflectance = 256.0;      //反射率

    //环境光 = 环境因子 * 物体的材质颜色
    vec3 ambient = ambientStrength * texture(Texture,outTexCoord).rgb;

    //漫反射
    vec3 norm = normalize(outNormal);
    vec3 lightDir = normalize(lightPo - FragPo);    //当前顶点 至 光源的的单位向量
    //DiffuseFactor=光源与paraLightDir lightDir夹角 max(0,dot(N,L))
    float diff = max(dot(norm,lightDir),0.0);   //光源与法线夹角
    //漫反射光颜色计算 = 光源的漫反射颜色 * 物体的漫发射材质颜色 * DiffuseFactor
    vec3 diffuse = diff * lightColor*texture(Texture,outTexCoord).rgb;

    //镜面反射
    vec3 viewDir = normalize(viewPo - FragPo);
     // reflect (genType I, genType N),返回反射向量
    vec3 reflectDir = reflect(-lightDir,outNormal);
    //SpecularFactor = power(max(0,dot(N,H)),shininess)
    float spec = pow(max(dot(viewDir, reflectDir),0.0),reflectance);
    //镜面反射颜色 = 光源的镜面光的颜色 * 物体的镜面材质颜色 * SpecularFactor
    vec3 specular = specularStrength * spec * texture(specularTexture,outTexCoord).rgb;

    float constantPara = 1.0f;    //距离衰减常量
    float linearPara = 0.09f;     //线性衰减常量
    float quadraticPara = 0.032f; //二次衰减常量
    
    //衰减因子计算
    float LFDistance = length(lightPo - FragPo);
    //衰减因子 =  1.0/(距离衰减常量 + 线性衰减常量 * 距离 + 二次衰减常量 * 距离的平方)
    float lightWeakPara = 1.0/(constantPara + linearPara * LFDistance + quadraticPara * (LFDistance*LFDistance));

    //聚光灯切角 (一些复杂的计算操作 应该让CPU做,提高效率,不变的量也建议外部传输,避免重复计算)
    float inCutOff = cos(radians(10.0f));
    float outCutOff = cos(radians(15.0f));
    vec3 spotDir = vec3(-1.2f,-1.0f,-2.0f);
    
    //聚光灯因子 = clamp((外环的聚光灯角度cos值 - 当前顶点的聚光灯角度cos值)/(外环的聚光灯角度cos值- 内环聚光灯的角度的cos值),0,1)；
    float theta = dot(lightDir,normalize(-spotDir));
    //(外环的聚光灯角度cos值- 内环聚光灯的角度的cos值)
    float epsilon  = inCutOff - outCutOff;
    //(外环的聚光灯角度cos值 - 当前顶点的聚光灯角度cos值) / (外环的聚光灯角度cos值- 内环聚光灯的角度的cos值)
    float intensity = clamp((theta - outCutOff)/epsilon,0.0,1.0);
    vec3 res = (ambient + diffuse + specular)*intensity*lightWeakPara;

    FragColor = vec4(res,1.0);
}

void DiffultLight(){
    
    float ambientStrength = 0.3;    //环境因子
    //环境光 = 环境因子 * 物体的材质颜色
    vec3 ambient = ambientStrength * texture(Texture,outTexCoord).rgb;
    
    //光源方向
    //vec3 paraLightDir =normalize(vec3(0,1,0));

    //漫反射
    vec3 norm = normalize(outNormal);
    vec3 lightDir = normalize(lightPo - FragPo);    //当前顶点 至 光源的的单位向量
    //DiffuseFactor=光源与paraLightDir lightDir夹角 max(0,dot(N,L))
    float diff = max(dot(norm,lightDir),0.0);   //光源与法线夹角
    //漫反射光颜色计算 = 光源的漫反射颜色 * 物体的漫反射材质颜色 * DiffuseFactor
    vec3 diffuse = diff * lightColor * texture(Texture,outTexCoord).rgb;
    
     vec3 res = ambient + diffuse;
     FragColor = vec4(res,1.0);
}


void main()
{
    //聚光版本
    //Spotlight();
    //点光源版本
    //pointLight();
    //平行光版本
    parallelLight();
//     DiffultLight();
    
}