光照模型中法线纹理的使用

其实就是让法线纹理中的法线替代了原模型的顶点法线

切线空间中计算

切线到模型空间

Shader "Unlit/NormalMapping_TangentSpace"
{
    Properties
    {
        _Color("Color",Color)=(1.0,1.0,1.0,1.0)
        _MainTex("Main Texture",2D)="white"{}
        _BumpTex("Normal Texture",2D)="bump"{}
        _BumpScale("Bump Scale",float)=1.0
        _Specular("Spcular",Color)=(1.0,1.0,1.0,1.0)
        _Gloss("Gloss",Range(30.0,100.0))=30.0
    }

    SubShader
    {
        Pass
        {
            Tags{"LightModel"="ForwardBase"}
            CGPROGRAM
            #include "Lighting.cginc"
            #include "UnityCG.cginc"

            #pragma vertex vert
            #pragma fragment frag

            float _BumpScale;
            float _Gloss;

            fixed4 _Color;
            fixed4 _Specular;

            sampler2D _MainTex;
            sampler2D _BumpTex;

            float4 _MainTex_ST;
            float4 _BumpTex_ST;

            struct a2v
            {
                float4 pos:POSITION;
                float3 normal:NORMAL;
                float4 tangent:TANGENT;//因为需要用w分量确定y的方向，就是副切线的方向，w分量不是1就是-1
                float4 texcoord:TEXCOORD0;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float3 tangentLightDir:TEXCOORD0;
                float3 tangentViewDir:TEXCOORD1;
                float4 uv:TEXCOORD2;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.pos);

                //先将顶点纹理坐标转换到普通纹理和法线纹理中，其中xy存储普通纹理坐标，zw存储法线纹理坐标
                o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
                o.uv.zw = v.texcoord.xy * _BumpTex_ST.xy + _BumpTex_ST.zw;

                //求取副法线，注意向量的叉乘不具有交换律
                float3 binormal = cross(normalize(v.normal),normalize(v.tangent.xyz)) * v.tangent.w;
                //构建从模型空间转换到切线空间的矩阵
                //已知A空间在B空间的X,Y,Z轴的向量表达式，则A到B的转换矩阵就是M=[X,Y,Z]
                //B到A的矩阵就是M的转置
                //(正交矩阵，也就是A到B的逆矩阵，只包含旋转和平移)
                float3x3 rotation = float3x3(v.tangent.xyz,binormal,v.normal);
                //注意：以上的代码和直接使用宏TANGENT_SPACE_ROTATION是等价的
                //使用TANGENT_SPACE_ROTATION宏相当于嵌入了求取副法线和变换矩阵的两句代码
                //这个宏包含在 UnityCG.cginc中
                /*
                Declares 3x3 matrix 'rotation', filled with tangent space basis
                #define TANGENT_SPACE_ROTATION \
                    float3 binormal = cross( normalize(v.normal), normalize(v.tangent.xyz) ) * v.tangent.w; \
                    float3x3 rotation = float3x3( v.tangent.xyz, binormal, v.normal )
                }
                */

                //如果想使用这个宏就需要将输入的变量名称统一使用“v”，并且含有对应的变量名字
                //TANGENT_SPACE_ROTATION;

                //将光照方向和视线方向转换到切线空间,先转换到模型空间，然后由模型空间转换切线空间
                o.tangentLightDir = mul(rotation,normalize(ObjSpaceLightDir(v.pos))).xyz;
                o.tangentViewDir = mul(rotation,normalize(ObjSpaceViewDir(v.pos))).xyz;

                return o;
            }


            fixed4 frag(v2f i):SV_TARGET
            {
                fixed3 tangentLightDir = normalize(i.tangentLightDir);
                fixed3 tangentViewDir = normalize(i.tangentViewDir);

                //根据法线纹理坐标在法线纹理中采样
                fixed4 packedNormal = tex2D(_BumpTex,i.uv.zw);
                //算出切线空间下的用到的法线
                //采样出来的纹理法线是经过变换的：（normal+1）/ 2
                //所以我们还需要把采样到的法线*2-1转换一遍
                fixed3 tangentNormal;
                //tangentNormal.xy = (packedNormal.xy*2-1)*_BumpScale;
                //然后根据xy算出z的值，因为（x,y,z）是单位向量，所以它们的模==1，根据这个可以算出z的值
                //tangentNormal.z = sqrt(1-saturate(dot(tangentNormal.xy,tangentNormal.xy)));
                //如果我们将纹理的类型在导入时修改为normalmapping类型（Texture Type）
                //那么我们就可以使用下面的代码（推荐），因为Unity会为纹理做一些优化
                tangentNormal = UnpackNormal(packedNormal);
                tangentNormal.xy *= _BumpScale;
                tangentNormal.z = sqrt(1-saturate(dot(tangentNormal.xy,tangentNormal.xy)));
                

                //采样普通纹理上的颜色作为漫反射颜色使用
                fixed3 albedo = tex2D(_MainTex,i.uv.xy);

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

                //diffuse使用的法线换成法线纹理中的法线
                fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(tangentNormal,tangentLightDir));
                
                fixed3 halfNormal = normalize(tangentLightDir+tangentViewDir);
                //specualr中的顶点法线换成了法线纹理中的法线
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(tangentNormal,halfNormal)),_Gloss);

                return fixed4(ambient + diffuse + specular,1.0);
            }

            ENDCG
        }
    }
}