Oracle存储过程中如何使用数组(附范例)

在PL/SQL中是没有数组(Array)概念的,但是如果程序员想用Array的话,可以用TYPE和 Table of Record变通一下,来代替多维数组.

1 单维数组

--单维数组
DECLARE
  TYPE emp_ssn_array IS TABLE OF NUMBER INDEX BY BINARY_INTEGER;
  best_employees  emp_ssn_array;
  worst_employees emp_ssn_array;
BEGIN
  best_employees(1) := '123456';
  best_employees(2) := '888888';
  worst_employees(1) := '222222';
  worst_employees(2) := '666666';
  FOR i IN 1 .. best_employees.count LOOP
    DBMS_OUTPUT.PUT_LINE('i=' || i || ', best_employees= ' ||
                         best_employees(i) || ', worst_employees= ' ||
                         worst_employees(i));
  END LOOP;
END;

2 多维数组

--多维数组
DECLARE
  TYPE emp_type IS RECORD(
    emp_id     employee_table.emp_id%TYPE,
    emp_name   employee_table.emp_name%TYPE,
    emp_gender employee_table.emp_gender%TYPE);
  TYPE emp_type_array IS TABLE OF emp_type INDEX BY BINARY_INTEGER;
  emp_rec_array emp_type_array;
  emp_rec       emp_type;
BEGIN
  emp_rec.emp_id     := 300000000;
  emp_rec.emp_name   := 'Barbara';
  emp_rec.emp_gender := 'Female';
  emp_rec_array(1) := emp_rec;
  emp_rec.emp_id     := 300000008;
  emp_rec.emp_name   := 'Rick';
  emp_rec.emp_gender := 'Male';
  emp_rec_array(2) := emp_rec;
  FOR i IN 1 .. emp_rec_array.count LOOP
    DBMS_OUTPUT.PUT_LINE('i=' || i || ', emp_id =' || emp_rec_array(i)
                         .emp_id || ', emp_name =' || emp_rec_array(i)
                         .emp_name || ', emp_gender = ' || emp_rec_array(i)
                         .emp_gender);
  END LOOP;
END;

3 实例

DECLARE
  -- 声明数组类型
  TYPE ts_varray IS VARRAY(20) OF NUMBER(10); --20是最大的下标
  -- 声明数组变量
  vs_varray ts_varray := ts_varray();
BEGIN
  FOR i IN 1 .. 20 LOOP
    -- 自增数组大小
    vs_varray.extend; --注释该行的话,会报下标越界的错误
    -- 数组赋值
    vs_varray(i) := trunc(dbms_random.value(100, 200));
  END LOOP;

  -- 循环数组
  FOR i IN 1 .. vs_varray.count LOOP
    dbms_output.put_line('i = ' || i || ',value = ' || vs_varray(i));
  END LOOP;
END;