简单理解：
- i++ 是先运算后自增
- ++i 是先自增后运算
虚拟机执行原理
java代码
public static void main(String[] args){
int num = 10;
int a = num++;
System.out.println(" a = "+a+"\n num = "+num);
}
编译后代码
public static void main(String[] args) {
int num = 10;
byte var10000 = num;
int num = num + 1;
int a = var10000;
System.out.println(" a = " + a + "\n num = " + num);
}
jvm指令代码
用下面命令就可以查看 jvm指令
javap -c MainTest.class
看jvm指令代码前，让我们先了解一下几个基本的jvm指令的含义：
-
bipush :
将常数压入操作数栈中 -
istore_n :
从操作数栈中弹出一个整数并把它赋值给局部变量 n（n是几就代表第几个局部变量） -
iload_n :
将第 n 个局部变量压入操作数栈中 -
iinc :
对给定的局部变量自增，第一个数字代表局部变量在局部变量表中的位置，第二个数字代表累加数
这是Jvm指令代码：
public static void main(java.lang.String[]);
Code:
0: bipush 10 //将常量 10 入栈
2: istore_1 //将常量 10 弹出栈并赋值给变量 1 ，也就是变量 num
3: iload_1 //将变量 1 入栈，也就是将 num 入栈，此时栈内的 num = 10，并处于栈顶
4: iinc 1, 1 //将局部变量表中的 num 加 1，此时局部变量表中的 num = 11
7: istore_2 //将栈顶弹出，也就是当前栈中的 num=10 ，并赋值给变量2 ，就是变量 a，这就是为什么变量 a 的值为 10
8: getstatic #2 // Field java/lang/System.out:Ljava/io/PrintStream;
11: new #3 // class java/lang/StringBuilder
14: dup
15: invokespecial #4 // Method java/lang/StringBuilder."<init>":()V
18: ldc #5 // String a =
20: invokevirtual #6 // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
23: iload_2 //从变量表中将 a 入栈，用于打印
24: invokevirtual #7 // Method java/lang/StringBuilder.append:(I)Ljava/lang/StringBuilder;
27: ldc #8 // String \n num =
29: invokevirtual #6 // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
32: iload_1 //从变量表中将 num 入栈，用于打印，这就是为什么打印的 num 为11
33: invokevirtual #7 // Method java/lang/StringBuilder.append:(I)Ljava/lang/StringBuilder;
36: invokevirtual #9 // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
39: invokevirtual #10 // Method java/io/PrintStream.println:(Ljava/lang/String;)V
42: return
下面是将 num++ 替换为 ++num 后的jvm指令代码：
public static void main(java.lang.String[]);
Code:
0: bipush 10
2: istore_1
3: iinc 1, 1
6: iload_1
7: istore_2
8: getstatic #2 // Field java/lang/System.out:Ljava/io/PrintStream;
11: new #3 // class java/lang/StringBuilder
14: dup
15: invokespecial #4 // Method java/lang/StringBuilder."<init>":()V
18: ldc #5 // String a =
20: invokevirtual #6 // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
23: iload_2
24: invokevirtual #7 // Method java/lang/StringBuilder.append:(I)Ljava/lang/StringBuilder;
27: ldc #8 // String \n num =
29: invokevirtual #6 // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
32: iload_1
33: invokevirtual #7 // Method java/lang/StringBuilder.append:(I)Ljava/lang/StringBuilder;
36: invokevirtual #9 // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
39: invokevirtual #10 // Method java/io/PrintStream.println:(Ljava/lang/String;)V
42: return
由此可以看出，num++ 和 ++num 的区别：
-
num++ 是先入栈，后自增，栈中的 num 值并没有受到自增的影响。
-
++num 是先进行 iinc 然后在执行 iload_1 ,也就是先进行自增然后在将变量 num 入栈，所以栈中的 num 的值是自增后的
扩展：
int a = 10;
int varNum = 66;
varNum = varNum++;
System.out.println(varNum);
//打印结果：66
//执行流程
1. 10 入栈
2. 10 出栈并赋值给变量 a
3. 66 入栈
4. 66 出栈并赋值给 varNum
5. varNum 入栈，此时栈顶是 varNum也就是 66
6. varNum 在局部变量表中的值 加1
//注意此时栈中的 varNum 还是 66，因为没有重新读取所以值没有改变
7. varNum 弹栈并赋值给 varNum ,所以varNum又变回 66 了
参考：https://www.zhihu.com/search?type=content&q=java%20i%3Di%2B%2B%3B
网友评论