【例1】查找个人信息
=VLOOKUP($B18,$C$7:$H$15,COLUMN(B1),0)
注：Colum(b1)的结果是2，当公式向右复制时可以生成3，4，5，..
笔记1：COLUMN 函数：返回指定单元格引用的列号。 例如，公式 =COLUMN(D10) 返回 4，因为列 D 为第四列。
笔记2：默认情况下，单元格引用是相对的。例如，当您引用单元格 A2 单元格 C2，实际上引用的单元格是左边 (C A 减)，和 (2) 的同一行中的两个列。公式包含相对单元格引用更改复制时它从一个单元格到另一个。
举一个例子，如果您复制公式= A2 + B2单元格 C2 到 D2，D2 中的公式调整向右按某一列并成为= B2 + C2。如果您想要保持在此示例中的原始单元格引用，复制时，所做的单元格引用绝对通过在前面加一个美元符号 （$） 第 (2) 行和列 （A 和 B）。这样，当您将公式= $A $ 2 + $B$ 2从 C2 复制到 D2时，公式保持完全相同。
【例2】合并两个表格
F2单元格公式
=VLOOKUP(B2,$B$14:$F$22,MATCH(F$1,$B$13:$F$13,0))
=VLOOKUP($C2,$B$14:$F$22,MATCH(F$1,$B$13:$F$13,0))
公式说明：用Match函数查找表1的标题在表2中的位置
笔记1：使用 MATCH 函数在 范围 单元格中搜索特定的项，然后返回该项在此区域中的相对位置。例如，如果 A1:A3 区域中包含值 5、25 和 38，那么公式 =MATCH(25,A1:A3,0) 返回数字 2，因为 25 是该区域中的第二项。
【例3】让两个表格同类商品排序完全一样
F2单元格公式
=IFERROR(VLOOKUP($B2,$B$12:$D$16,COLUMN(A1),),"")
公式说明：IFERROR函数用来屏蔽错误值
【例4】制作工资条
=VLOOKUP($G96,$A$96:$E$104,COLUMN(B1),)
公式说明：根据序号从工资表中查找对应的信息
【例5】计算个人所得税
=(G28-3500)VLOOKUP(G28-3500,C28:E34,2)-VLOOKUP(G28-3500,C28:E34,3)
公式说明：当Vlookup最后一个参数为1或省略时，查找为近似匹配。即查找比指定值小且最接近的值。
【例6】模糊查找产品名称（包含查找）
=VLOOKUP(""&F41&"",$B$41:$D$47,3,0)
注：是通配符，代表任意多个字符
【例7】带特殊符合的字符查找
=VLOOKUP(SUBSTITUTE(F52,"","~"),B$52:C$56,2,0)
注：由于~ * ？在公式中有通配符用法，遇到被查找的字符串中含有这3个字符就用Substitute替换为~、*和~？
【例8】逆向查找
=VLOOKUP(G61,IF({1,0},C61:C69,B61:B69),2,)
公式说明: 本公式只做了解，遇到逆向查找，建议使用Index+Match函数。
=INDEX(B60:B69,MATCH(G61,C60:C69,0))
【例9】16年与17年单价核对，表格核对（带通配符），结果显示多N 或 少N
=TEXT(VLOOKUP(SUBSTITUTE(B73,"","~"),$F$73:$G$92,2,)-C73,"少0.00;多0.00;")
公式说明:Text可以设置数字显示的格式
【例10】Vlookup多条件查找
A112 =B112&C112
H112 =VLOOKUP(F112&G112,A112:D120,4,0)
公式说明：Vlookup也可以使用IF({1,0}的数组形式实现多条件查找，但运行效率太慢，所以建议使用辅助列连接再查找的方法。
【例11】库存单价的监控。销售单价>库存单价时填充红色背景
设置方法：选取区域 - 条件格式 - 新建规则 - 使用公式确定... - 在下面框中输入公式：
=H2>VLOOKUP(F2,A:C,3,0)
最后点“格式”按钮设置填充色为红色
【例12】银行存款最近30天到期提醒。表中要有某天汇总金额，也要有明细金额。
设置方法：
步骤1 添加辅助列，根据到期日生成 到期日+序列（目的是对同一个日期编序号，方便Vlookup一对多查找）
=D2&"-"&COUNTIF(D$2:D2,D2)
步骤2 设置到期日公式，H2单元格输入=Today() ,H3=H2+1,然后H3公式向下复制
步骤3 设置求和公式，用来统计每个到期时需要还款的总金额
=SUMIF(D:D,H2,C:C)
步骤4 用Vlookup查找各行明细数据
J2单元格公式
=IFERROR(VLOOKUP($H2&"-"&J$1,$A:$D,2,0)&":"&VLOOKUP($H2&"-"&J$1,$A:$D,3,0),"")
公式说明： 这里把H列日期&第1行的数字作为查找内容，在A列中进行查找，然后返回 B列 & C列的数据，
示例下载百度网盘：https://pan.baidu.com/s/1qXAgV7m** **
网友评论