原文链接：https://docs.unity3d.com/Manual/SL-Stencil.html
stencil buffer通常可以用于作为一个像素的遮罩来保留或者丢弃像素。
stencil buffer通常是每像素的一个8位整数。该值可以写入，增加或减少。后续的draw call可以针对这个值进行测试，在进行像素shader之前来决定一个像素是否该被丢弃。
语法
Ref
Ref referenceValue
这个值将会用来和将要写入Buffer（如果Pass、Fail、ZFail被设为replace）中的值相比较（如果Comp是除了always外的其他值）。0-255的整数。
ReadMask
ReadMask readMask
一个0-255的整数作为8位的掩码，用于当Ref值与buffer中的值进行下面比较运算时使用：(referenceValue & readMask) comparisonFunction (stencilBufferValue & readMask)。默认值255。
WriteMask
WriteMask writeMask
一个0-255的整数作为8位的掩码，在写入buffer的时候使用。请注意，像其他write mask一样，它指定的stencil buffer的位将会受写入影响。（例如，WriteMask 0意味着没有位将会受影响，如果不是0的将会被写入）。默认值:255。
Comp
Comp comparisonFunction
这个值用于比较ref值与目前buff中的值。默认：always。
Pass
Pass stencilOperation
当buffer中的内容通过模板测试（和深度测试）时要做的操作。默认：keep。
ZFail
ZFail stencilOperation
当buffer中的内容通过模板测试（深度测试没有通过）时要做的操作。默认：keep。
Comp,Pass,Fail和ZFail将会应用到几何体的正面，除非指定了Cull Front，在这种情况下将会应用到几何体的背面。你也可以通过定义CompFront,PassFront,FailFront,ZFailFront(对于几何体正面),CompBack,PassBack,FailBack,ZFailBack(对于几何体背面)来明确的指定stencil状态。
Comparison Function
Comparison function是下列中的一种：
Greater 只渲染Ref值比buffer中的Ref值大的像素。
GEqual 只渲染Ref值比buffer中的Ref值大或者相等的像素。
Less 只渲染Ref值比buffer中的Ref值小的像素。
LEqual 只渲染Ref值比buffer中的Ref值小或者相等的像素。
Equal 只渲染Ref值与buffer中的Ref值相等的像素。
NotEqual 只渲染Ref值与buffer中的Ref值不相等的像素。
Always 使模板测试总是通过。
Never 使模板测试总是不通过。
Stencil Operation
Stencil Operation是下列中的一种：
Keep 保持目前buffer中的内容。
Zero 将0写入buffer。
Replace 将Ref值写入buffer。
IncrSat 增加buffer中当前的值，如果已经是255，则保持255。
DecrSat 减少buffer中当前的值，如果已经是0，则保持0。
Invert 将所有位反转。
IncrWrap 增加buffer中当前的值，如果已经是255，则变为0。
DecrWrap 减少buffer中当前的值，如果已经是0，则变为255。
延迟渲染路径
对对象的模板功能在延迟渲染路径中多少会受到限制，因为在基础pass和光照pass，模板buffer被用于其他目的。在这两个阶段在shader中定义的模板状态将会被忽略，并且只在最终pass中被考虑进去。由于不可能通过模板测试屏蔽这些物体，但是它们仍然可以修改这些buffer的内容，用于物体在这一帧后面的渲染。在延迟渲染路径后面的正向渲染路径中渲染的物体（比如透明物体或者没有表面着色器的物体），它们的模板状态会重新被设回正常。
延迟渲染路径使用模板buffer的三个最高位，接近4的比4更大最高位依赖于场景中有多少光照蒙版层。可以使用stencil read和write mask来进行范围内的位清理工作，或者你也可以使用Camera.clearStencilAfterLightingPass来强制摄像机在光照pass后来清理模板buffer。
例子
第一个示例shader当通过深度测试时会将2这个值写入。模板特侧被设为总是通过。
Shader "Red" {
SubShader {
Tags { "RenderType"="Opaque" "Queue"="Geometry"}
Pass {
Stencil {
Ref 2
Comp always
Pass replace
}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
struct appdata {
float4 vertex : POSITION;
};
struct v2f {
float4 pos : SV_POSITION;
};
v2f vert(appdata v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
return o;
}
half4 frag(v2f i) : SV_Target {
return half4(1,0,0,1);
}
ENDCG
}
}
}
第二个shader将只在像素通过第一个shader（红色的）通过以后才通过，因为它在检查Ref值是不是等于2。当深度测试失败时，它也会减少buffer中的Ref值。
Shader "Green" {
SubShader {
Tags { "RenderType"="Opaque" "Queue"="Geometry+1"}
Pass {
Stencil {
Ref 2
Comp equal
Pass keep
ZFail decrWrap
}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
struct appdata {
float4 vertex : POSITION;
};
struct v2f {
float4 pos : SV_POSITION;
};
v2f vert(appdata v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
return o;
}
half4 frag(v2f i) : SV_Target {
return half4(0,1,0,1);
}
ENDCG
}
}
}
第三个shader将只会允许模板值为1的通过，所以符合条件的只有在红色球和绿色球相交处的像素，那里的像素的模板值被红色shader设为2，并且又被绿色shader减少。
Shader "Blue" {
SubShader {
Tags { "RenderType"="Opaque" "Queue"="Geometry+2"}
Pass {
Stencil {
Ref 1
Comp equal
}
CGPROGRAM
#include "UnityCG.cginc"
#pragma vertex vert
#pragma fragment frag
struct appdata {
float4 vertex : POSITION;
};
struct v2f {
float4 pos : SV_POSITION;
};
v2f vert(appdata v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
return o;
}
half4 frag(v2f i) : SV_Target {
return half4(0,0,1,1);
}
ENDCG
}
}
}
结果如下：
（图片见原网页）
另一个更有指导影响的例子。这个球体第一次被这个shader渲染来在模板buffer中增加适当的区域。
Shader "HolePrepare" {
SubShader {
Tags { "RenderType"="Opaque" "Queue"="Geometry+1"}
ColorMask 0
ZWrite off
Stencil {
Ref 1
Comp always
Pass replace
}
CGINCLUDE
struct appdata {
float4 vertex : POSITION;
};
struct v2f {
float4 pos : SV_POSITION;
};
v2f vert(appdata v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
return o;
}
half4 frag(v2f i) : SV_Target {
return half4(1,1,0,1);
}
ENDCG
Pass {
Cull Front
ZTest Less
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
ENDCG
}
Pass {
Cull Back
ZTest Greater
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
ENDCG
}
}
}
然后接下来再使用一个相当标准的表面shader，除了正面剔除，禁用深度测试和模板测试丢弃之前标记的像素：
Shader "Hole" {
Properties {
_Color ("Main Color", Color) = (1,1,1,0)
}
SubShader {
Tags { "RenderType"="Opaque" "Queue"="Geometry+2"}
ColorMask RGB
Cull Front
ZTest Always
Stencil {
Ref 1
Comp notequal
}
CGPROGRAM
#pragma surface surf Lambert
float4 _Color;
struct Input {
float4 color : COLOR;
};
void surf (Input IN, inout SurfaceOutput o) {
o.Albedo = _Color.rgb;
o.Normal = half3(0,0,-1);
o.Alpha = 1;
}
ENDCG
}
}
下面是结果：
（图片见原网页）
网友评论