环境
Unity 2019.4
URP7.5.2
如何做
1.Unity 编辑器设置部分
支持Unity 内置阴影编辑器设置部分
2.Shader 代码部分
分为两个部分：投射和接收
投射部分：
需要在Shader 中额外添加一个名称为"ShadowCaster" 的Pass。
1.全局变量声明：
float3 _LightDirection;
2.顶点着色器：
分别计算顶点的世界空间坐标和世界空间法线：
float3 worldPos = TransformObjectToWorld(i.vertex.xyz);
float3 normal = TransformObjectToWorldNormal(i.normal);
使用内置的Shadows.hlsl 文件中提供的方法计算阴影偏移（bias）,然后将其转换到裁剪空间中：
float4 positionCS = TransformWorldToHClip(ApplyShadowBias(positionWS, normalWS, _LightDirection));
然后确保阴影偏移后的位置不会超出裁剪空间：
#if UNITY_REVERSED_Z
positionCS.z = min(positionCS.z, positionCS.w * UNITY_NEAR_CLIP_VALUE);
#else
positionCS.z = max(positionCS.z, positionCS.w * UNITY_NEAR_CLIP_VALUE);
#endif
3.片元着色器
最后在片源着色器中，根据需要保留片元：如果投射阴影的网格（mesh）是不透明物体，直接返回0；否则可以根据透明度测试或其他规则来裁剪片元，这里直接返回0；
return 0；
接收部分：
1.关键字声明：
#pragma multi_compile _ _ADDITIONAL_LIGHTS_VERTEX _ADDITIONAL_LIGHTS //开启额外光源
#pragma multi_compile _ _MAIN_LIGHT_SHADOWS //主光源阴影
#pragma multi_compile _ _MAIN_LIGHT_SHADOWS_CASCADE //主光源层级阴影是否开启
#pragma multi_compile _ _ADDITIONAL_LIGHT_SHADOWS //额外光源阴影
#pragma multi_compile _ _SHADOWS_SOFT //软阴影
2.顶点输出（片元输入）结构体：
添加阴影坐标寄存器声明：
#if defined(REQUIRES_VERTEX_SHADOW_COORD_INTERPOLATOR)
float4 shadowCoord : TEXCOORD1;
#endif
3.顶点着色器：
按需计算阴影坐标
#if defined(REQUIRES_VERTEX_SHADOW_COORD_INTERPOLATOR)
o.shadowCoord = TransformWorldToShadowCoord(o.worldPos);
#endif
4.片元着色器：
获取主光源阴影坐标：
#if defined(REQUIRES_VERTEX_SHADOW_COORD_INTERPOLATOR)
float4 shadowCoord = input.shadowCoord;
#elif defined(MAIN_LIGHT_CALCULATE_SHADOWS)
float4 shadowCoord = TransformWorldToShadowCoord(inputData.positionWS);
#else
float4 shadowCoord = float4(0, 0, 0, 0);
endif
获取主光源结构体（计算主光源的阴影衰减）然后混合阴影：
Light main = GetMainLight(shadowCoord);
o *= main.shadowAttenuation;
获取额外光源结构体（计算额外光源阴影衰减）然后混合额外光源阴影：
#ifdef _ADDITIONAL_LIGHTS
uint pixelLightCount = GetAdditionalLightsCount();
for (uint lightIndex = 0u; lightIndex < pixelLightCount; ++lightIndex)
{
Light light = GetAdditionalLight(lightIndex, i.worldPos);//获得额外光源结构体（内部包含阴影衰减）
o *= light.shadowAttenuation;
}
#endif
为什么
投射部分：
1.全局变量声明：
声明_LightDirection 是为了从Unity 中获取当前主光源的方向，在ShadowUtils.cs 文件中可以看到：
UnityURP脚本源码对_LightDirection赋值
2.顶点着色器：
在Shadows.hlsl 文件中ApplyShadowBias 函数定义：
ApplyShadowBias
可以看到其原理就是分别根据法线方向和光照方向偏移顶点，其中偏移量_ShadowBias 就是管线配置文件当中的设置数值：
渲染管线阴影偏移设置
接收部分
1.顶点输出（片元输入）结构体及顶点着色器：
根据是否实时计算主光源阴影和是否开启层级阴影（shadow cascade）来确定是否在顶点着色器中计算阴影坐标然后输出。
在Shadows.hlsl 文件中可以找到相关关键字的声明：
光照和阴影关键字声明
这其中_MAIN_LIGHT_SHADOWS、_MAIN_LIGHT_SHADOWS_CASCADE 、_ADDITIONAL_LIGHT_SHADOWS 这三个关键字就是一开始声明的关键字，声明了这些关键字后，就可以通过Unity 渲染管线配置文件来控制这些关键字是否开启，从而控制shader 的行为：
渲染管线配置文件关键字控制入口
在Shader 中添加属性和关键字声明：
[ToggleOff]_Receive_Shadows("接收阴影", Float) = 1.0
#pragma shader_feature _RECEIVE_SHADOWS_OFF
就可以通过shader 来控制是否接收来自其他mesh 投射的阴影（实际上是否读取阴影贴图数据）：
使用shader_feature + 属性 实现接收阴影关键字开关
因此综合来看，只有在接收阴影并且配置了主光源投射阴影且启用了层级阴影时，才会在顶点着色器中计算阴影坐标；否则如果没有开启层级阴影但是主光源投射阴影时，则直接在片元着色器中计算阴影坐标。
获取阴影坐标的函数TransformWorldToShadowCoord 方法在Shadows.hlsl 中可以找到：
TransformWorldToShadowCoord 方法
源码首先根据是否开启了主光源层级阴影来获取阴影层级，然后将世界坐标转换到主光源的相应层级的阴影图空间下。
2.片元着色器
首先根据不同的设置来获取主光源的阴影坐标。
GetMainLight 方法可以在Unity 内置的Lighting.hlsl 文件中找到其定义：
GetMainLight 方法定义
其中MainLightRealtimeShadow 给出了主光源实时阴影衰减，可以在Shadows.hlsl 文件中找到其定义：
MainLightRealtimeShadow 定义
通过前面计算的阴影坐标来采样阴影图：
SampleShadowmap 定义
首先根据是否开启软阴影来确定阴影图采样方式，如果开启了软阴影（_SHADOWS_SOFT），那么内部将会根据不同的平台使用卷积的方式来采样阴影：
根据不同平台卷积采样阴影图
渲染管线配置中设置软阴影
然后根据Light 控件中设置的阴影强度来调整阴影：
应用阴影强度
Light 控件中设置阴影强度
以上就是主光源实时阴影计算过程。
对于额外光源阴影计算，在Lighting.hlsl 文件中的GetAdditionalLight 方法通过调用Shadows.hlsl 文件当中AdditionalLightRealtimeShadow 方法来计算：
AdditionalLightRealtimeShadow 方法
首先计算了阴影坐标然后使用主光源一样的方式采样额外光源的阴影贴图。
以上就是额外光源的阴影计算过程。
源码
Shader "Custom/Shadow"
{
Properties
{
_Color("基本颜色", color) = (1, 1, 1, 1)
[ToggleOff]_Receive_Shadows("接收阴影", Float) = 1.0
}
SubShader
{
Tags
{
"RenderType"="Opaque"
"Queue"="Geometry"
"RenderPipeline"="UniversalRenderPipeline"
}
HLSLINCLUDE
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Lighting.hlsl"
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Shadows.hlsl"
ENDHLSL
Pass
{
HLSLPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile _ _ADDITIONAL_LIGHTS_VERTEX _ADDITIONAL_LIGHTS
#pragma multi_compile _ _MAIN_LIGHT_SHADOWS
#pragma multi_compile _ _MAIN_LIGHT_SHADOWS_CASCADE
#pragma multi_compile _ _ADDITIONAL_LIGHT_SHADOWS
#pragma multi_compile _ _SHADOWS_SOFT
#pragma shader_feature _RECEIVE_SHADOWS_OFF
struct a2v
{
float4 vertex : POSITION;
};
struct v2f
{
float4 vertex : SV_POSITION;
float3 worldPos : TEXCOORD0;
#if defined(REQUIRES_VERTEX_SHADOW_COORD_INTERPOLATOR)
float4 shadowCoord : TEXCOORD1;
#endif
};
CBUFFER_START(UnityPerMaterial)
real4 _Color;
CBUFFER_END
v2f vert(a2v i)
{
v2f o;
o.worldPos = TransformObjectToWorld(i.vertex.xyz);
o.vertex = TransformWorldToHClip(o.worldPos.xyz);
#if defined(REQUIRES_VERTEX_SHADOW_COORD_INTERPOLATOR)
o.shadowCoord = TransformWorldToShadowCoord(o.worldPos);
#endif
return o;
}
real4 frag(v2f i) : SV_TARGET
{
real4 o = _Color;
////获取主光源阴影坐标
#if defined(REQUIRES_VERTEX_SHADOW_COORD_INTERPOLATOR)
float4 shadowCoord = i.shadowCoord;
#elif defined(MAIN_LIGHT_CALCULATE_SHADOWS)
float4 shadowCoord = TransformWorldToShadowCoord(i.worldPos);
#else
float4 shadowCoord = float4(0, 0, 0, 0);
#endif
Light main = GetMainLight(shadowCoord);//获得主光源结构体（内部包含阴影衰减）
o *= main.shadowAttenuation;
#ifdef _ADDITIONAL_LIGHTS
uint pixelLightCount = GetAdditionalLightsCount();
for (uint lightIndex = 0u; lightIndex < pixelLightCount; ++lightIndex)
{
Light light = GetAdditionalLight(lightIndex, i.worldPos);//获得额外光源结构体（内部包含阴影衰减）
o *= light.shadowAttenuation;
}
#endif
return o;
}
ENDHLSL
}
Pass
{
Name "ShadowCaster"
Tags{"LightMode" = "ShadowCaster"}
ZWrite On
ZTest LEqual
ColorMask 0
Cull[_Cull]
HLSLPROGRAM
#pragma vertex vert
#pragma fragment frag
struct a2v
{
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f
{
float4 vertex : SV_POSITION;
};
float3 _LightDirection; //将会由Unity 完成赋值
float4 GetShadowPositionHClip(float3 positionWS, float3 normalWS)
{
float4 positionCS = TransformWorldToHClip(ApplyShadowBias(positionWS, normalWS, _LightDirection));
#if UNITY_REVERSED_Z
positionCS.z = min(positionCS.z, positionCS.w * UNITY_NEAR_CLIP_VALUE);
#else
positionCS.z = max(positionCS.z, positionCS.w * UNITY_NEAR_CLIP_VALUE);
#endif
return positionCS;
}
v2f vert(a2v i)
{
v2f o;
float3 worldPos = TransformObjectToWorld(i.vertex.xyz);
float3 normal = TransformObjectToWorldNormal(i.normal);
o.vertex = GetShadowPositionHClip(worldPos, normal);
return o;
}
half4 frag(v2f i) : SV_TARGET
{
return 0;
}
ENDHLSL
}
}
}
注意事项
1.Unity URP 源码Shadows.hlsl 文件中提供的计算主光源阴影函数默认主光源是平行光（无透视）、提供的计算额外光源阴影函数默认所有额外光源是有透视的，如果需要额外的平行光，可以自己写一个计算函数。
2.接收和投射并不一定都需要，即可以做只接收不投射或只投射不接收的效果。
3.如果着色器有顶点偏移的效果，注意顶点偏移后对阴影投射的影响，投射时应该将投射Pass 中的顶点做相同的偏移处理。
网友评论