前言：今天在使用注册机时，经云检测发现为恶意软件，但自己又不得不用。想到win10有沙盒功能，但无情的把家庭版排斥了（伤心），经过一番‘百度’，终于还是发现了解决方法：
基本环境：
时间：2020年3月17号
系统版本：win10家庭版 - 18363
1.先确定你的电脑是否符合“Windows沙盒”运行所需的基本条件
① Win10专业版/企业版build 18301预览版及以上版本（呃，略过第一条……）
② AMD64架构
③ 在BIOS中启用固件虚拟化（检测Win10电脑是否支持虚拟化及启用固件虚拟化的方法）
④ 4GB或以上内存
⑤ 至少1 GB可用磁盘空间（建议使用SSD固态硬盘）
⑥ 至少2个CPU核心（建议 4 核心）
2.开始愉快的折腾之旅，永远相信美好的事情即将发生
“众里寻他千百度”，我找到了好的开始，没想到结尾来的这么伤心……(;´༎ຶД༎ຶ`)(ノへ￣、)
网友的“踩坑”经历
好在，我顺着“网线”找到了，该到了该方法的更新版 —— 最近一版[更新于20200305]，有戏！
📲 传送门，请走这里
😀 下载压缩包并解压文件；
😀执行bat文件，请在命令行中弹出的选项中选择第一项立即安装，在安装完成后，会有是否立即启动的选项，请选第一项；
😀 此时Windows Sandbox功能已安装完成，并已启动。
如果你要禁用此功能：
😭你可以再次运行【沙盒安装程序.bat】 用于卸载。
😭使用控制面板 -> 删除程序和功能 -> 添加 Windows 功能。禁用那里的沙盒
下附：bat文件原代码：【如有需要，请复制保存为bat文件】
@echo off
echo Checking for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
echo Permission check result: %errorlevel%
REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
echo Running created temporary "%temp%\getadmin.vbs"
timeout /T 2
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0"
echo Batch was successfully started with admin privileges
echo .
cls
GOTO:menu
:menu
Title Sandbox Installer
echo Backup wird dringend empfohlen!
echo um u.a. die Sandbox spurenlos und sicher zu entfernen.
echo --------------------------------------------------
echo Was soll das Setup tun?
echo 1 Installieren
echo 2 Deinstallieren
echo 3 Beenden
set /p uni= Option in Zahl eintippen:
if %uni% ==1 goto :in
if %uni% ==2 goto :un
if %uni% ==3 goto :ex
:in
cls
Title Install Sandbox
pushd "%~dp0"
dir /b %SystemRoot%\servicing\Packages\*Containers*.mum >sandbox.txt
for /f %%i in ('findstr /i . sandbox.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"
del sandbox.txt
Dism /online /enable-feature /featurename:Containers-DisposableClientVM /LimitAccess /ALL /NoRestart
goto :remenu
:un
cls
Title Uninstall Sandbox
pushd "%~dp0"
Dism /online /disable-feature /featurename:Containers-DisposableClientVM /NoRestart
dir /b %SystemRoot%\servicing\Packages\*Containers*.mum >sandbox.txt
for /f %%i in ('findstr /i . sandbox.txt 2^>nul') do dism /online /norestart /remove-package:"%SystemRoot%\servicing\Packages\%%i"
del sandbox.txt
goto :remenu
:remenu
cls
echo Möchten Sie den Computer jetzt neu starten?
echo 1 Ja
echo 2 Nein
set /p uni= Option in Zahl eintippen:
if %uni% ==1 goto :re
if %uni% ==2 goto :ex
:re
shutdown /r /t 0 /f
goto :ex
:ex
exit
网友评论