Unity Shader 单张纹理(九)

Unity Shader系列文章：Unity Shader目录-初级篇

Unity Shader系列文章：Unity Shader目录-中级篇

效果： 单张纹理、凹凸映射(在世界空间计算法线)、凹凸映射(在切线空间计算法线).png 原图： 主贴图.jpg

shader代码：

// 单张纹理
Shader "Custom/Texture/SingleTexture"
{
    Properties
    {
        _Color ("Color", Color) = (1, 1, 1, 1)
        _MainTex ("MainTex", 2D) = "white" { }// 主纹理
        _Specular ("Specular", Color) = (1, 1, 1, 1) // 高光反射颜色
        _Gloss ("Gloss", Range(8, 256)) = 20 // 高光区域大小
    }
    
    SubShader
    {
        Tags { "RenderType" = "Opaque" }
        LOD 100
        
        pass
        {
            Tags { "LightMode" = "ForwardBase" }
            
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag
            
            #include "Lighting.cginc"
            
            fixed4 _Color;
            sampler2D _MainTex;
            // _MainTex_ST(声明方式：name_ST): 声明_MainTex是一张采样图，用于uv运算, 下面2个是等价的
            // o.uv = TRANSFORM_TEX(v.texcoord,_MainTex);
            // o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
            // 如果没有声明是不能进行TRANSFORM_TEX的运算的。_MainTex_ST.xy为纹理图Tiling(缩放), zw为纹理中的offset(偏移)
            // 如果Tiling 和 Offset留的是默认值，即Tiling为（1，1） Offset为（0，0）的时候，可以不用TRANSFORM_TEX运算
            // 即：o.uv = v.texcoord
            float4 _MainTex_ST;
            fixed4 _Specular;
            float _Gloss;
            
            // 应用传递给顶点着色器的数据
            struct a2v
            {
                float4 vertex: POSITION; // 模型空间下的顶点坐标
                float3 normal: NORMAL; // 模型空间下的法线
                float4 texcoord: TEXCOORD0; // 纹理坐标
            };
            
            // 顶点传递给片元着色器的数据
            struct v2f
            {
                float4 pos: SV_POSITION; // 裁剪空间下的顶点坐标
                float3 worldNormal: TEXCOORD0;
                float3 worldPos: TEXCOORD1;
                float2 uv: TEXCOORD2;
            };
            
            // 顶点着色器函数
            v2f vert(a2v v)
            {
                v2f o;
                // 将顶点坐标从模型空间变换到裁剪空间
                // 等价于o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                o.pos = UnityObjectToClipPos(v.vertex);
                
                // 将法线从模型空间变换到世界空间
                // 等价于o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                
                // 将顶点坐标从模型空间变换到世界空间
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
                
                // 计算纹理坐标(缩放和平移)
                // 等价于o.uv = v.texcoord * _MainTex_ST.xy + _MainTex_ST.zw;
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                
                return o;
            }
            
            // 片元着色器函数
            fixed4 frag(v2f i): SV_TARGET
            {
                // 获得单位世界光向量
                // 在 "LightMode" = "ForwardBase"情况下：
                // 等价于fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                // fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                float3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                
                // 对纹理进行采样
                fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
                
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
                
                // 计算漫反射光
                fixed3 diffuse = _LightColor0.rgb * albedo.rgb * saturate(dot(i.worldNormal, worldLightDir));
                
                // 获得单位观察向量
                // 等价于fixed3 viewDir = normalize(_WorldSpaceLightPos0.xyz - i.worldPos);
                fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
                
                // 计算半角向量
                fixed3 halfDir = normalize(worldLightDir + viewDir);
                
                // 计算高光反射光
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(i.worldNormal, halfDir)), _Gloss);
                
                return fixed4(ambient + diffuse + specular, 1);
            }
            
            ENDCG
            
        }
    }
}