八、AWK

一、awk 简介

awk 是一种编程语言，用于在 linux/unix 下对文本和数据进行处理。数据可以来自标准输入、
一个或多个文件，或其它命令的输出。它支持用户自定义函数和动态正则表达式等先进功能，是
linux/unix下的一个强大编程工具。它在命令行中使用，但更多是作为脚本来使用。
awk 的处理文本和数据的方式是这样的，它逐行扫描文件，从第一行到最后一行，寻找匹配
的特定模式的行，并在这些行上进行你想要的操作。如果没有指定处理动作，则把匹配的行显示到
标准输出(屏幕)，如果没有指定模式，则所有被操作所指定的行都被处理。awk 分别代表其作者姓氏的
第一个字母。因为它的作者是三个人，分别是 Alfred Aho、Brian Kernighan、Peter Weinberger。gawk
是 awk 的GNU 版本，它提供了 Bell 实验室和 GNU 的一些扩展。

二、awk 的两种形式语法格式

awk [options] 'commands' filenames
awk [选择] '命令' 文件名
awk [options] -f awk-script-file filenames
awk [选择] -f awk脚本文件 文件名

＝＝options： -F 定义输入字段分隔符，默认的分隔符是空格或制表符(tab)

＝＝command：
BEGIN{} {} END{}
行处理前 行处理 行处理后

[root@biudefor ~]# awk 'BEGIN{print 1/2} {print "ok"} END{print "-----------"}' /etc/hosts
0.5
ok
ok
ok
-----------

BEGIN{} 通常用于定义一些变量，例如 BEGIN{FS=":";OFS="---"}

＝＝awk 命令格式：

awk '{action}' filename 示例：awk -F: '{print $1}' /etc/passwd 

awk 'pattern {action}' filename 示例：awk -F: '/root/{print $1,$3}' /etc/passwd 
示例：awk 'BEGIN{FS=":"} /root/{print $1,$3}' /etc/passwd
command |awk 'pattern {action}' 示例：df -P| grep '/' |awk '$4 > 25000 {print $4}'
================================

三、awk 工作原理

awk -F: '{print $1,$3}' /etc/passwd

(1)awk，会处理文件的每一个行，每次处理时，使用一行作为输入，并将这一行赋给内部变量$0，每一行也可称为一个记录，以换行符结束

(2)然后，行被:（默认为空格或制表符）分解成字段（或称为域），每个字段存储在已编号的变量中，从$1开始，

最多达100个字段

(3)awk如何知道用空白字符来分隔字段的呢？ 因为有一个内部变量FS来确定字段分隔符。初始时，FS赋为空白字符

(4)awk打印字段时，将以内置的方法使用 print 函数打印，awk 在打印出的字段间加上空格。这个空格是内部的一个变量 OFS 输出字段的分隔符, 逗号 , 会和 OFS 进行映射，通过 OFS 可以控制这个输出分隔符的值。

(5)awk输出之后，将从文件中获取另一行，并将其存储在$0中，覆盖原来的内容，然后将新的字符串分隔成字段并进行处理。该过程将持续到所有行处理完毕

四、记录与字段相关内部变量：

$0 ： awk变量 $0 保存当前正在处理的行内容

NR ： 当前正在处理的行是 awk 总共处理的行号。

[root@biudefor ~]# awk 'NR==3 {print $0}' /etc/passwd

FNR： 当前正在处理的行在其文件中的行号。

NF ：每行被处理时的总字段数

FS ： 输入行时的字段分隔符，默认空格

awk 'BEGIN{FS=":"} {print $1,$3}' /etc/passwd

OFS ： 输出字段分隔符,默认是一个 空格

awk 'BEGIN{FS=":"; OFS="+++"} /^root/{print $1,$2,$3,$4}' /etc/passwd

ORS 输出记录分隔符, 默认是换行符.

lab1:
[root@biudefor ~]# awk 'BEGIN{ORS=" "} {print $0}' /etc/passwd #将文件每一行合并为一行
lab2:
[root@biudefor ~]# head -1 /etc/passwd > passwd1
[root@biudefor ~]# cat passwd1 
root:x:0:0:root:/root:/bin/bash
[root@biudefor ~]# 
[root@biudefor ~]# awk 'BEGIN{RS=":"} {print $0}' passwd1 
root
x00
root
/root
/bin/bash
[root@biudefor ~]# awk 'BEGIN{RS=":"} {print $0}' passwd1 |grep -v '^$' > passwd2

五、格式化输出：

printf 函数

awk -F: '{printf "%-15s %-10s %-15s\n", $1,$2,$3}' /etc/passwd
awk -F: '{printf "|%-15s| %-10s| %-15s|\n", $1,$2,$3}' /etc/passwd

• %s 字符类型
• %d 十进制整数
• %f 浮点类型
• %-15s占15字符 - 表示左对齐，默认是右对齐
• printf 默认不会在行尾自动换行，加 \n

六、awk模式和动作

任何 awk 语句都由 模式 和 动作 组成。
模式部分 决定动作语句何时触发及触发事件。
如果省略模式部分，动作将时刻保持执行状态。
模式可以是任何条件语句或复合语句或正则表达式。
模式包括两个特殊字段 BEGIN 和 END。使用 BEGIN 语句设置计数和打印头。BEGIN 语句使用在任何文本浏览动作之前，之后文本浏览动作依据输入文本开始执行。END 语句用来在 awk 完成文本浏览动作后打印输出文本总数和结尾状态。

正则表达式：

• 匹配记录（整行的匹配）：

    awk '/^root/' /etc/passwd
    awk '$0 ~ /^root/' /etc/passwd
    awk '!/root/' /tec/ passwd
    awk '$0 !~ /^root/' /etc/passwd

• 匹配字段：可以使用的匹配操作符（~ 和 !~）

    awk -F: '$1 ~ /^alice/' /etc/passwd
    awk -F: '$NF !~ /bash$/' /etc/passwd

比较表达式：

比较表达式采用对文本进行比较，只有当条件为真，才执行指定的动作。

比较表达式使用关系运算符，用于比较数字与字符串。

关系运算符有

< 小于 例如 x<y
> 大于 x>y
<= 小于或等于 x<=y
== 等于 x==y
!= 不等于 x!=y
>= 大于等于 x>=y

示例

awk -F: '$3 == 0' /etc/passwd
awk -F: '$3 < 10' /etc/passwd
awk -F: '$NF == "/bin/bash"' /etc/passwd
awk -F: '$1 == "root"' /etc/passwd

df -P | grep '/' |awk '$4 > 25000'

条件表达式：

awk -F: '$3>300 {print $0}' /etc/passwd
awk -F: '{ if($3>300) print $0 }' /etc/passwd
awk -F: '{ if($3>300) {print $0} }' /etc/passwd
awk -F: '{ if($3>300) {print $3} else{print $1} }' /etc/passwd

算术运算：+, -, *, /, %(模: 取余), ^(幂：2^3)

可以在模式中执行计算，awk都将按浮点数方式执行算术运算

awk -F: '$3 * 10 > 500' /etc/passwd
awk -F: '{ if($3*10>500){print $0} }' /etc/passwd

逻辑操作符和复合模式

&& 逻辑与, 相当于 并且
||逻辑或，相当于 或者
! 逻辑非 , 取反

awk -F: '$1~/root/ && $3<=15' /etc/passwd
awk -F: '$1~/root/ || $3<=15' /etc/passwd
awk -F: '!($1~/root/ || $3<=15)' /etc/passwd

➜  ~ cat passwd
root:x:0:0:root:/root:/bin/zsh
bin:x:1:1:bin:/bin:/sbin/nologin
daemon:x:20:2:daemon:/sbin:/sbin/nologin
root:x:20:2:daemon:/sbin:/sbin/nologin
➜  ~ awk -F: '!($1~/root/ || $3<=15){print $0}' passwd
daemon:x:20:2:daemon:/sbin:/sbin/nologin
➜  ~ awk -F: '($1~/root/ || $3<=15){print $0}' passwd
root:x:0:0:root:/root:/bin/zsh
bin:x:1:1:bin:/bin:/sbin/nologin
root:x:20:2:daemon:/sbin:/sbin/nologin

范围模式, 模式之间用逗号 , 隔开

使用语法是： 起始表达式, 终止表达式

下面的意思是: 从开头是 bin 的行开始匹配成功一直到含有 adm 的行结束匹配
也就是 开头是 bin 的行到含有 adm 的行 的所有内容都符合匹配条件。

➜  ~ awk -F: '/^bin/,/adm/ {print $0 }' /etc/passwd
bin:x:1:1:bin:/bin:/sbin/nologin
daemon:x:2:2:daemon:/sbin:/sbin/nologin
adm:x:3:4:adm:/var/adm:/sbin/nologin

awk 正则示例：

匹配开头是 bin 的或者开头是 root 的行

➜  ~ awk -F: '/^(bin|root)/' /etc/passwd
root:x:0:0:root:/root:/bin/zsh
bin:x:1:1:bin:/bin:/sbin/nologin

指定多个分隔符：[]

[root@biudefor ~]# echo "a b|c d| ||||e | |" |awk -F'[ |]' '{print $10}'
    e
[root@biudefor ~]#  echo "a b|c d| ||||e | |" |awk -F'[ |]+' '{print $5}'
    e

注意： 正则中，中括号内的任意字符均视为普通字符， 比如 . * 都被看做是 普通字符。

例如：

[root@biudefor ~]#  echo "a.b*c" |awk -F'[.*]' '{print $1, $2,$3}'
    a b c

七、awk 脚本编程

条件判断
if语句

格式 { if (表达式) {语句; 语句; ...}}

awk -F: '{if($3==0) {print $1 " is administrator."}}' /etc/passwd
输出： root is administrator.

# 统计系统级别用户的数量
awk -F: '{if($3>0 && $3<1000){count++;}} END{print count}' /etc/passwd 
输出： 22

if...else语句

格式 {if(表达式)｛语句;语句;...｝else{语句;语句;...}}

awk -F: '{if($3==0){print $1} else {print $7}}' /etc/passwd

awk -F: '{ if($3==0){count++} else{i++} } END{print "管理员个数: "count "系统用户数: "i}' /etc/passwd
输入：
管理员个数: 1系统用户数: 24

awk -F: '{ if($3==0){count++} else{i++} } END{print "管理员个数: "count ; print  "系统用户数: "i}' /etc/passwd
输出：
管理员个数: 1
系统用户数: 24

if...else if...else语句

格式

{if(表达式1) {语句;语句；...} else if (表达式2) {语句;语句；...} else if(表达式3){语句;语句；...} else {语句;语句；...} }

awk -F: '{if($3==0){i++} else if($3>999){k++} else{j++}} END{print i; print k; print j}' /etc/passwd
输出：
1
2
22

awk -F: '{if($3==0){i++} else if($3>999){k++} else{j++}} END{print "管理员个数: "i; print "普通用个数: "k; print "系统用户: "j}' /etc/passwd
输出：
管理员个数: 1
普通用个数: 2
系统用户: 22

awk使用外部变量：

扩展

方法一：awk参数-v（推荐使用，易读）

[root@tianyun ~]# echo "unix script" |awk -v var="bash" 'gsub(/unix/,var)'
bash script

[root@tianyun ~]# awk -v user=root -F: '$1 == **user**' /etc/passwd
root:x:0:0:root:/root:/bin/bash

gsub 使 AWK 中的内置函数，功能使搜索替换
gsub(/unix/,var)中的意思是搜索 unix 字符串，替换为 var 变量对应的值

方法二：在双引号的情况下使用

[root@tianyun ~]# var="bash"
[root@tianyun ~]# echo "unix script" |awk "gsub(/unix/,\"$var\")"
bash script

方法三：在单引号的情况下使用（逼不得已使用）

[root@tianyun ~]# var="bash"
[root@tianyun ~]# echo "unix script" |awk 'gsub(/unix/,"'"$var"'")'
bash script

其他练习

[root@biudefor ~]#  df -h
Filesystem Size Used Avail Use% Mounted on
/dev/mapper/cl-root 2.8T 246G 2.5T 9% /
tmpfs 24G 20K 24G 1% /dev/shm
/dev/sda2 1014M 194M 821M 20% /boot
[root@biudefor ~]#  df -h |awk '{ if(int($5)>5){print $6":"$5} }'
/:9%
/boot:20%
[root@biudefor ~]#  i=10
[root@biudefor ~]#  df -h |awk '{ if(int($5)>'''$i'''){print $6":"$5} }'
/boot:20%