stata结果导入excel-方差分析

前段时间知道stata16可以直接导入SPSS数据，就把stata16安装了

然后，就想了解stata16的新功能，官方介绍：New in Stata 16

最开始，是里面的Reproducible reporting吸引我，毕竟一直在想着怎么写动态分析报告，即分析结果和报告同步更新。

就研究了一下里面提到的dyndoc，putexcel，putword命令

首先，就是研究了putexcel命令，想着把频率分析结果能直接导入excel，尤其是有大量变量的时候

简单尝试了一下，发现还是很好用，尤其是导出来中文不会乱码，而且格式自定义，其他命令如logout，asdoc等都有各种问题的。

接下来，分不同帖子写写不同分析结果如何批量导出结果至excel，

首先是，stata结果导入excel-频率分析

接着是，stata结果导入excel-多重响应

然后是，stata结果导入excel-交叉分析

还有是，stata结果导入excel-描述统计

继续是，方差分析结果导出Excel

第一种形式

F效果1.png

如上图所示，如果有n个因变量，m个自变量，想做n*m个方差分析检验，需要得到F值及相应的显著性，如果是手动粘贴复制的话，实在太累了，而且，万一数据变化，就得又需要重新弄一遍，就很心累了……

基于之前帖子的经验，通过将stata分析结果组成矩阵，利用命令putexcel将结果导出Excel，可以得到以下n*m个描述统计结果和方差分析效果：

anova1.gif

代码

putexcel set result.xlsx,sheet("方差分析",replace) modify

*只需修改自变量和因变量的变量名
local depvar "P2Q1 P2Q2 P2Q3 P2Q4 P2Q5 P2Q6 P2Q7R1 P2Q7R2 P2Q7R3 P2Q7R4 P2Q7R5 P2Q7R6 P2Q7R7"
local indepvar "P4Q6 P4Q10 P4Q6 P4Q10 "

local rownum=1
local colnum=1
local rntable=1
local cntable=1

foreach i of varlist `indepvar' {
// 自变量，分类标题行
quietly fre `i',nov
local ilabel=r(lab_valid)
local inum=r(r)

local lab_row_start=`rownum'

*将自变量的类别导出Excel
forvalues l=1(1)`inum' {
local lab_col=char(`l'+65)
local lab:word `l' of `ilabel'
putexcel `lab_col'`lab_row_start'="`lab'"
}

local rownum=`rownum'+1

// 因变量，分类描述统计结果
foreach d of varlist `depvar' {

local dlabel:var label `d'
local dlabel=subinstr("`dlabel'",":","",.)

tabstat `d',by(`i') save
mat desbytable=r(Stat1)
forvalues n=2(1)`inum' {
mat rowjoin desbytable=desbytable r(Stat`n') 
}
mat desbytable=desbytable'
mat rownames desbytable=`dlabel'

putexcel A`rownum'=matrix(desbytable),rownames nformat(0.00) hcenter vcenter

local rntable:rowsof desbytable
local cntable:colsof desbytable
local colstart_f=char(64+`cntable'+2)

//方差分析结果
quietly anova `d' `i'
*根据自由度和F值得到方差分析的p值
local p=Ftail(`e(df_m)',`e(df_r)',`e(F)')
local F=`e(F)'
local r:dis "F = "%6.2f `F'
*根据p值，修改暂元s
if `p'<0.001{
local s="***"
}
else if `p'<0.01{
local s="**"
}
else if `p'<0.05{
local s="*"
}
else{
local s=""
}
local Fresult="`r'`s'"

putexcel `colstart_f'`rownum'="`Fresult'"

local rownum=`rownum'+`rntable'
}
}

第二种形式

第二种形式其实就是将第一种形式进行转置得到的结果：

anova2.png

代码

putexcel set result.xlsx,sheet("方差分析2",replace) modify

*只需修改自变量和因变量的变量名
local depvar "P2Q1 P2Q2 P2Q3 P2Q4 P2Q5 P2Q6 P2Q7R1 P2Q7R2 P2Q7R3 P2Q7R4 P2Q7R5 P2Q7R6 P2Q7R7"
local indepvar "P4Q6 P4Q10 P4Q11 P4Q19"

local row_st_nu=1

foreach i of varlist `indepvar' {
local col_st_nu=2

// 自变量
quietly fre `i',nov
local ilabel=r(lab_valid)
local inum=r(r)

forvalues l=1(1)`inum' {
local lab_row=`l'+`row_st_nu'
local lab:word `l' of `ilabel'
putexcel A`lab_row'="`lab'",hcenter vcenter
}
local txt=`lab_row'+1
putexcel A`txt'="F值",hcenter vcenter

foreach d of varlist `depvar' {
//分类描述统计结果
local dlabel:var label `d'
local dlabel=subinstr("`dlabel'",":","",.)

tabstat `d',by(`i') save
mat desbytable=r(Stat1)
forvalues n=2(1)`inum' {
mat rowjoin desbytable=desbytable r(Stat`n') 
}
mat colnames desbytable=`dlabel'

local col_st1=char(`col_st_nu'+64)
local col_st2=`row_st_nu'

putexcel `col_st1'`col_st2'=matrix(desbytable),nformat(0.00) colnames left vcenter

//方差分析结果
quietly anova `d' `i'
*根据自由度和F值得到p值
local p=Ftail(`e(df_m)',`e(df_r)',`e(F)')
local F=`e(F)'
local r:dis %6.2f `F'
*根据p值，修改暂元s
if `p'<0.001{
local s="***"
}
else if `p'<0.01{
local s="**"
}
else if `p'<0.05{
local s="*"
}
else{
local s=""
}
local Fresult="`r'`s'"

local f_row=`col_st2'+`inum'+1
putexcel `col_st1'`f_row'="`Fresult'",hcenter vcenter

local col_st_nu=`col_st_nu'+1
}

local row_st_nu=`row_st_nu'+`inum'+2
}

总结

1. 代码解释可以回顾前期帖子，尤其是 stata结果导入excel-描述统计

2. 总的来说：分三部分导出Excel：自变量值标签；分类描述统计结果；F值；

3. 需要捋清楚的就是通过循环更新导入excel的单元格位置；

4. 要实现只需要修改自变量和因变量的变量名的效果，可以先从1个自变量和1个因变量开始尝试；

5. t检验分析与方差分析结果导出是类似的，大家可以自己尝试；

6. stata中统计量获得：

   1. 方差分析：输入anova P2Q1,by(P4Q4)命令后，可通过输入ereturn list得到存储的结果，里面就有组间自由度e(df_m)，残差自由度e(df_r)和F值e(F)，通过函数Ftail（），就可以在stata中得到方差分析的p值啦~~
   2. t检验：在输入ttest P2Q1,by(P4Q3)命令后，可通过输入return list得到存储的结果，里面就有自由度r(df_t)，t值r(t)和p值r(p)~~