Shader学习3——半兰伯特

半兰伯特其实就是把暗的地方提亮了一些，在数值上就是获取到的光源强度* 0.5 + 0.5，也就是原来是0的会变成0.5，原来是1的还是1。
半兰伯特：漫反射颜色 = 光源颜色 x 材质的漫反射颜色 x Max(0,Dot(法线，指向光源的方向)* 0.5 + 0.5)
跟兰伯特相比就是暗部变亮了一些，把环境光设置全黑的时候会更明显：

image.png

代码基本略改即可

Shader "Unlit/半兰伯特"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1,1,1,1)
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" "LightMode"="ForwardBase"}
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float3 normal:NORMAL;
                float4 vertex : SV_POSITION;
            };
            
            fixed4 _Diffuse;
            sampler2D _MainTex;
            float4 _MainTex_ST;

            v2f vert (a2v v)
            {
                v2f o;
                //顶点坐标转换
                o.vertex = UnityObjectToClipPos(v.vertex);
                //获取法线（统一到世界坐标系下）。
                o.normal = UnityObjectToWorldNormal(v.normal);
                //获取UV
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                //获取平行光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                //获取归一化的法线
                fixed3 worldNormal = normalize(i.normal);
                //fixed3 worldNormal = i.normal;
                //获取环境光的方向
                fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
                //半兰伯特：漫反射颜色 = 光源颜色 x 材质的漫反射颜色 x Max(0,Dot(法线，指向光源的方向)* 0.5 + 0.5)
                //计算光照强度
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * (saturate(dot(worldNormal, worldLight))* 0.5 + 0.5);
                //叠加
                fixed3 color = ambient + diffuse;

                //获取贴图颜色
                fixed4 col = tex2D(_MainTex, i.uv);
                //将贴图颜色与顶点计算的颜色相乘 
                col=fixed4(col.rgb*color.rgb,1.0);
                return col;
            }
            ENDCG
        }
    }
    Fallback "Diffuse"
}