Gradle插件开发详解

官方文档描述，Gradle插件打包用于可重用的构建逻辑片段，可用于许多不同的项目和构建。

Gradle官方提供了很多插件，常见的就是apply plugin: 'com.android.application'和apply plugin: 'com.android.library'，分别用于构建application和library。

除了官方提供的插件，Gradle也提供了自定义插件的机制，让我们可以通过插件来实现特定的构建逻辑，并可以打包分享给其他人使用。
实现语言：Groovy、Java、Kotlin等都可以用于实现插件，本文使用Groovy语言实现。
打包方式：Gradle的插件有三种打包方式

• 构建脚本
  插件逻辑写在build.gradle中，适用于逻辑简单的任务，但是该方式实现的插件在该构建脚本之外是不可见的，只能用于当前脚本。
• buildSrc项目
  根据语言插件代码放在rootProjectDir/buildSrc/src/main/groovy目录中或者rootProjectDir/buildSrc/src/main/java或者rootProjectDir/buildSrc/src/main/kotlin，该插件对于该项目中构建使用的每个构建脚本都是可见的，适用于逻辑复杂但又不需要对外可见的插件
• 独立项目
  一个独立的Groovy/Java/Kotlin项目，该项目生成并发布一个jar然后可以在多个版本中使用它并与他人共享，并且此jar包可能包含一些插件，或者将多个相关的任务类捆绑到单个库中
  接下来我们先从基本的构建脚本中的插件开始

构建脚本

创建Gradle插件，需要创建一个实现Plugin接口的类，当插件应用于项目时，Gradle会创建插件类的实例并调用实例的apply()方法，如果需要的话，插件还可以用于配置项目

//插件入口
class PluginTest implements Plugin<Project> {
    @Override
    void apply(Project target) {
        //do something
        target.task('pluginTest'){
            doLast {
                println('hello from PluginTest')
            }
        }
    }
}
apply plugin: PluginTest

以上代码创建了一个简单的插件，创建完成后，同步下Gradle，会发现在Gradle面板中出现了一个pluginTest的task，执行该task，会在Run面板中输出我们定义的内容“hello from PluginTest”

pluginTest.jpg

我们也可以在控制台输入如下命令来执行：

./gradlew -q pluginTest

关于命令行中的-q详见官方文档

扩展插件

多数插件需要从构建脚本中获取一些配置来实现更多功能，执行此操作的一种方法是使用扩展对象，我们可以向目标对象添加“命名空间”DSL扩展，可以实现动态传参，并在DSL作用域中重新赋值，扩展对象只是一个Java Bean兼容类。

基本使用如下：
定义一个简单的扩展对象：

class PluginExtension{
    String msg = 'Hello from PluginExtension'
}

有关Extension的相关信息详见官方文档

添加扩展对象

def extension = target.extensions.create("pluginExtension",PluginExtension)

完整代码如下：

class PluginExtension {
    String msg = 'Hello from PluginExtension'
}

//插件入口
class PluginTest implements Plugin<Project> {
    @Override
    void apply(Project target) {
        //do something
        def extension = target.extensions.create("pluginExtension", PluginExtension)
        target.task('pluginTest') {
            doLast {
                println("新内容是:${extension.msg}")
            }
        }
    }
}
apply plugin: PluginTest

使用：

pluginExtension.msg = 'Hello from Gradle'
//或
pluginExtension {
    msg 'Hello from Gradle'
}

注意，以上代码中构建脚本(pluginExtension)中的闭包块名称需要与扩展对象名称匹配，当执行闭包时，扩展对象上的字段将根据标准Groovy闭包委托功能映射到闭包内的变量，且以上代码只能放在apply plugin: PluginTest之后

同时，以上代码块是不是感觉很熟悉？没错，当我们构建Android项目时，会出现如下配置

android {
    compileSdkVersion 28
    defaultConfig {
        applicationId "com.ywd.demo.plugindemo"
        minSdkVersion 19
        targetSdkVersion 28
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
    }
}

该配置也是Android DSL 闭包的一种实现，关于DSL格式详见官方文档

buildSrc

复杂的构建逻辑通常是封装为自定义任务或二进制插件插件的良好候选者，自定义任务和插件实现不应该存在于脚本中。只要代码不需要在多个独立项目之间共享，就可以非常方便地将buildSrc用于此目的。

对buildSrc方式感兴趣的同学可以查看官方文档

独立项目

使用独立项目形式通常会经过以下几步：

• 1、新建module，名称可根据实际情况声明
• 2、删除module里的内容，只保留build.gradle和src/main目录
• 3、由于gradle是基于Groovy，所以main目录下创建groovy目录，并在groovy目录下新建包
• 4、删除build.gradle中的配置，并改为如下配置

apply plugin: 'groovy'

dependencies {
    //gradle sdk
    implementation gradleApi()
    //groovy sdk
    implementation localGroovy()
}

//以下内容主要用于发布插件
apply plugin: 'maven'
repositories {
    mavenCentral()
}
group = 'com.ywd.pluginlibrary'
version = '1.0.0'

uploadArchives {
    repositories {
        mavenDeployer {
            repository(url: uri('./../repo'))
        }
    }
}

• 5、编写Groovy脚本
  在我们上面建好的src/main/groovy/com.ywd.pluginlibrary中创建并编写Groovy脚本，在这里我们继续使用我们上面建好的类，类文件以.groovy文件名结尾：

package com.ywd.pluginlibrary

import org.gradle.api.Plugin
import org.gradle.api.Project

class PublishPluginTest implements Plugin<Project> {
    @Override
    void apply(Project project) {
        def extension = project.extensions.create("publishPluginExtension", PublishPluginExtension)
        project.task("publishPluginTest"){
            doLast {
                println("新内容是：${extension.msg}")
            }
        }
    }
}

• 6、添加资源文件，存放用于标识gradle插件的元数据，路径如下：resources/META-INF/gradle-plugins/com.ywd.pluginlibrary.properties，其中properties这个文件名可以随意起，但是在其他build.gradle中使用的时候要根据文件名匹配，例如：

apply plugin: 'com.ywd.pluginlibrary'

Gradle使用此文件来确定哪个类实现了该Plugin接口，文件配置如下：

implementation-class = com.ywd.pluginlibrary.PublishPluginTest

最终module结构如下

module.jpg

• 7、打包发布
  此处我们发布到本地，由于我们刚刚已经重新配置了gradle，此时我们可以在Gradle面板中发现一个uploadArchives task，执行该task，会将刚刚的插件发布到本地目录：

  
  发布.jpg
• 8、使用
  在主项目中进行如下配置

buildscript {
    repositories {
        maven {
            url uri('./../repo')
        }
    }
    dependencies {
        classpath 'com.ywd.pluginlibrary:pluginlibrary:1.0.0'
    }
}
apply plugin: 'com.ywd.pluginlibrary'
publishPluginExtension{
    msg 'Hello Publish'
}

本文代码详见Demo
本篇为原创文章，转载请注明出处：https://www.jianshu.com/p/75bf31149a53

参考：
Writing Custom Plugins
Writing Gradle Plugins
在AndroidStudio中自定义Gradle插件