1. 安全数学（safe math）

在之前的版本中没有安全数学，数值计算式有溢出的，在Solidity0.8版本中引入了安全数学新特性。

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8.4;


// safe math
contract SafeMath {
    // 默认的带有安全数学检验的方法
    function testUnderflow() public pure returns (uint) {
        uint x = 0;  // revert
        x--;
        return x;
    }

    // 不带安全数学检验的方法
    function testUncheckedUnderflow() public pure returns (uint) {
        uint x = 0;
        unchecked {x--;} // 不使用安全数学，得到uint256最大值
        return x;
    }
}

2. 自定义错误（custom errors）

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8;

contract VendingMachine {
    address payable owner = payable(msg.sender);
    // 自定义错误
    error Unauthorized(address caller);

    function withdraw() public {
        if (msg.sender != owner){
            // revert("error");
            // 使用自定义错误
            revert Unauthorized(msg.sender); //23613
        }
        owner.transfer(address(this).balance);
    }

}

revert信息：

Error provided by the contract:
Unauthorized
Parameters:
{
 "caller": {
  "value": "0xAb8483F64d9C6d1EcF9b849Ae677dD3315835cb2"
 }
}

3. 合约外函数 (fuctions outside contract)

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8;


// 在合约外定义函数
function helper(uint _x) pure  returns (uint) {
    return _x * 2;
}

contract Testhelper {
    // 在合约内调用合约外函数
    function test(uint _x) external pure returns (uint) {
        return helper(_x);
    }
}

4. 导入别名

import {symbol as alias} from "filename";

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8;

import {helper as helper2} from "./1.3 function_out_contract.sol";


function helper(uint _x) pure returns (uint) {
    return _x * 3;
}

contract Import {
    function double(uint _x) external  pure returns (uint) {
        // 使用别名，调用引入的helper
        return helper2(_x);
    }
    function triple(uint _x) external  pure returns (uint) {
        // 调用自己的helper
        return helper(_x);
    }
}

5. 加盐合约创建（salted contract creations）：create2

在之前的create合约创建方法中，合约地址是通过msg.sender和nounce进行计算的，无法提前得到部署后合约的地址。

新添加的create2合约创建方法，合约地址通过盐（salt）进行计算，这样就可以提前获得部署后的合约地址。

// SPDX-License-Identifier: MIT
pragma solidity ^0.8;

contract D {
    uint public x;
    constructor(uint a) {
        x = a;
    }
}

contract create2 {
    function getBytes32(uint _salt) external pure returns (bytes32) {
        return bytes32(_salt);
    }

    function getAddress(bytes32 salt, uint arg) external view returns (address) {
        address addr = address(uint160(uint(keccak256((abi.encodePacked(
            bytes1(0xff),
            address(this),
            salt,
            keccak256(abi.encodePacked(
                type(D).creationCode,
                arg
            ))
        ))))));
        return addr;
    }

    address public deployedAddr;

    function createdSalted(bytes32 salt,uint arg) public {
        D d = new D{salt:salt}(arg);
        deployedAddr = address(d);
    }
}