iOS底层系列12 -- 消息流程的快速查找

首先我们来了解一下应用程序的编译与运行，在 iOS App底层编译流程 和 iOS App运行加载 这两篇文章中对编译与运行都做了非常详尽的阐述。

编译：是指编译器将应用程序源码经过词法分析，语法分析，生成抽象语法树，生成汇编，最终生成为机器所能识别的机器码，最终得到是一个静态的Mach-O可执行文件；

运行：将编译生成的静态Mach-O文件，装载进入内存，dyld链接所有的运行时动态库，然后RunTime初始化，加载工程中的所有类文件即调用所有类的load类方法。

本篇分析的消息流程，与RunTime运行时密切相关；我们知道给对象发送一条消息，其本质是调用RunTime运行时的objc_msgSend函数。

通过下面的实例代码验证消息发送，本质是调用RunTime运行时的objc_msgSend函数。
main.m文件源码如下：

int main(int argc, const char * argv[]) {
    @autoreleasepool {
        YYPerson *person = [YYPerson alloc];
        Class cls = [YYPerson class];
        [person code1];
        
        NSLog(@" class = %@",NSStringFromClass(cls));
    }
    return 0;
}

• 终端输入 clang -rewrite-objc main.m -o main.cpp 将main.m文件编译成main.cpp文件，main.cpp文件如下所示：

Snip20210223_46.png

• 看到person调用code1方法，在底层被转化成调用objc_msgSend函数，传入实例对象与方法名称两个参数。

• 再者我们直接调用objc_msgSend函数，验证是否与[persong code1]调用，查看其打印是否是一致。

1、直接调用objc_msgSend，需要导入头文件#import <objc/message.h>
2、需要将target --> Build Setting -->搜索msg -- 将enable strict checking of obc_msgSend calls由YES 改为NO，将严厉的检查机制关掉，否则objc_msgSend的参数会报错。

#import <Foundation/Foundation.h>
#import "YYPerson.h"
#import "YYStudent.h"
#import <objc/runtime.h>
#import <objc/message.h>

int main(int argc, const char * argv[]) {
    @autoreleasepool {
        YYPerson *person = [YYPerson alloc];
        [person code1];
        objc_msgSend(person,sel_registerName("code1"));
    }
    return 0;
}

控制台结果如下所示：

Snip20210223_48.png

• [person code1]与objc_msgSend(person,"code1")等价。

objc_msgSend源码分析

在objc4-781源码工程中全局搜索 objc_msgSend( 看到如下所示：

Snip20210223_50.png

• 可以看到objc_msgSend是以汇编语言实现的，且分不同的架构实现，我们只需要关注真机arm64架构实现即可，在objc-msg-arm64.s文件中；

objc_msgSend的汇编代码主流程如下所示：

    ENTRY _objc_msgSend
    UNWIND _objc_msgSend, NoFrame

    cmp p0, #0          // nil check and tagged pointer check
#if SUPPORT_TAGGED_POINTERS
    b.le    LNilOrTagged        //  (MSB tagged pointer looks negative)
#else
    b.eq    LReturnZero
#endif
    ldr p13, [x0]       // p13 = isa
    GetClassFromIsa_p16 p13, 1, x0  // p16 = class
LGetIsaDone:
    // calls imp or objc_msgSend_uncached
    CacheLookup NORMAL, _objc_msgSend, __objc_msgSend_uncached

#if SUPPORT_TAGGED_POINTERS
LNilOrTagged:
    b.eq    LReturnZero     // nil check
    GetTaggedClass
    b   LGetIsaDone
// SUPPORT_TAGGED_POINTERS
#endif

LReturnZero:
    // x0 is already zero
    mov x1, #0
    movi    d0, #0
    movi    d1, #0
    movi    d2, #0
    movi    d3, #0
    ret

    END_ENTRY _objc_msgSend

• ENTRY _objc_msgSend 消息发送的汇编入口；
• END_ENTRY _objc_msgSend是函数结束的地方；
• cmp p0, #0 这里的p0是指消息的接收者receiver，将receiver与0进行比较即判断receiver是否为空；
  • 当receiver不为空，且支持tagged pointer特性时，走LNilOrTagged流程；在LNilOrTagged中会对isa进行一些操作，最终会执行LGetIsaDone：CacheLookup
  • 当receiver不为空，不支持tagged pointer特性时，ldr p13, [x0]取出isa,然后通过GetClassFromIsa_p16 p13，获取class；接着也会执行LGetIsaDone：CacheLookup;
  • 当receiver为空时，走LReturnZero,直接返回为空；

objc_msgSend的汇编分支流程 -- GetClassFromIsa_p16 p13获取class类信息

汇编代码如下：

.macro GetClassFromIsa_p16 /* src */

#if SUPPORT_INDEXED_ISA
    // Indexed isa
    mov p16, $0         // optimistically set dst = src
    tbz p16, #ISA_INDEX_IS_NPI_BIT, 1f  // done if not non-pointer isa
    // isa in p16 is indexed
    adrp    x10, _objc_indexed_classes@PAGE
    add x10, x10, _objc_indexed_classes@PAGEOFF
    ubfx    p16, p16, #ISA_INDEX_SHIFT, #ISA_INDEX_BITS  // extract index
    ldr p16, [x10, p16, UXTP #PTRSHIFT] // load class from array
1:

#elif __LP64__
    // 64-bit packed isa
    and p16, $0, #ISA_MASK
#else
    // 32-bit raw isa
    mov p16, $0
#endif

.endmacro

• 只关注arm64真机架构，and p16, $0, #ISA_MASK，其中$0是指实例对象的isa，将isa和掩码ISA_MASK做位与运算，最终得到类的地址信息，也就是isa中shiftcls位域信息 详情可见 iOS底层系列09 -- isa的底层探索 将获取的class地址信息写入p16寄存器中

objc_msgSend的汇编分支流程 -- CacheLookup 正式进入消息的快速查找流程

汇编代码如下：

.macro CacheLookup
    //   GETIMP:
    //     The cache-miss is just returning NULL (setting x0 to 0)
    //
    //   NORMAL and LOOKUP:
    //   - x0 contains the receiver
    //   - x1 contains the selector
    //   - x16 contains the isa
    //   - other registers are set as per calling conventions
LLookupStart$1:
    // p1 = SEL, p16 = isa
    ldr p11, [x16, #CACHE]              // p11 = mask|buckets

#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16
    and p10, p11, #0x0000ffffffffffff   // p10 = buckets
    and p12, p1, p11, LSR #48       // x12 = _cmd & mask
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4
    and p10, p11, #~0xf         // p10 = buckets
    and p11, p11, #0xf          // p11 = maskShift
    mov p12, #0xffff
    lsr p11, p12, p11               // p11 = mask = 0xffff >> p11
    and p12, p1, p11                // x12 = _cmd & mask
#else
#error Unsupported cache mask storage for ARM64.
#endif
    add p12, p10, p12, LSL #(1+PTRSHIFT)
    // p12 = buckets + ((_cmd & mask) << (1+PTRSHIFT))

    ldp p17, p9, [x12]      // {imp, sel} = *bucket
1:  cmp p9, p1          // if (bucket->sel != _cmd)
    b.ne    2f          //     scan more
    CacheHit $0         // call or return imp
    
2:  // not hit: p12 = not-hit bucket
    CheckMiss $0            // miss if bucket->sel == 0
    cmp p12, p10        // wrap if bucket == buckets
    b.eq    3f
    ldp p17, p9, [x12, #-BUCKET_SIZE]!  // {imp, sel} = *--bucket
    b   1b          // loop

3:  // wrap: p12 = first bucket, w11 = mask
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16
    add p12, p12, p11, LSR #(48 - (1+PTRSHIFT))
                    // p12 = buckets + (mask << 1+PTRSHIFT)
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4
    add p12, p12, p11, LSL #(1+PTRSHIFT)
                    // p12 = buckets + (mask << 1+PTRSHIFT)
#else
#error Unsupported cache mask storage for ARM64.
#endif

    ldp p17, p9, [x12]      // {imp, sel} = *bucket
1:  cmp p9, p1          // if (bucket->sel != _cmd)
    b.ne    2f          //     scan more
    CacheHit $0         // call or return imp
    
2:  // not hit: p12 = not-hit bucket
    CheckMiss $0            // miss if bucket->sel == 0
    cmp p12, p10        // wrap if bucket == buckets
    b.eq    3f
    ldp p17, p9, [x12, #-BUCKET_SIZE]!  // {imp, sel} = *--bucket
    b   1b          // loop

LLookupEnd$1:
LLookupRecover$1:
3:  // double wrap
    JumpMiss $0

.endmacro

• 根据上面的注释知道x0 --> 实例对象，消息的接受者，x1 --> selector，x16 --> isa

1> ldr p11, [x16, #CACHE] 其中#CACHE = (2 * SIZEOF_POINTER) = 2*8=16，x16时isa，将(isa+16)即偏移16个字节得到cache存入p11寄存器中；

2> and p10, p11, #0x0000ffffffffffff首先CACHE_MASK_STORAGE_HIGH_16表示64位真机 ,p11与立即数#0x0000ffffffffffff做位与运算，将cache的高16为置为0，在 iOS底层系列11 -- 类的cache成员分析中我们知道cache的结构分布，mask与buckets是在一起的占8个字节64位，其中高16位表示mask，低48位表示buckets；那么现在将cache的高16为置为0，剩下的就表示buckets，然后将buckets写入p10寄存器中；

3> and p12, p1, p11, LSR #48，首先 p11, LSR #48即p11右移48位得到mask并且p11存储mask(根据cache结构结合位运算原理分析如下图所示)

Snip20210226_108.png

然后mask再与p1=selector做位与运算，得到sel-imp的下标index(这里是搜索index)其与 在iOS底层系列11 -- 类的cache成员分析中cache_hash(sel, m)哈希函数，根据sel与mask计算出insert的下标index是一致的，这也说明了存与取用的是同一个index，最后将index存入p12寄存器中；

4> add p12, p10, p12, LSL #(1+PTRSHIFT)其中PTRSHIFT=3，首先p12，LSL #(1+PTRSHIFT)即p12<<4，p12下标值扩大了16倍，其本质是index * 一个bucket的内存大小，然后再与p10(buckets)做位与运算，综合而言其本质是获取指定index的bucket = buckets的首地址 + index * 单个bucket的内存大小，将获取的指定index的bucket存入p12寄存器中；

5> ldp p17, p9, [x12] 读取x12中的bucket的imp与sel，然后分别存入p17与p9寄存器中；

6> 1: cmp p9, p1 p1表示传参sel，p9表示获取的指定index的sel，判断两者是否相等，如果相等，进入CacheHit $0；如果不相等进入2中执行；
6.1> 两者相等进入CacheHit $0顾名思义缓存命中，直接返回imp；
6.2> 两者不相等进入2，先判断如果一直不相等，则进入CheckMiss $0,然后执行cmp p12, p10指令，即判断p12当前的bucket是否是集合buckets的第一个元素；
6.2.1> 若p12是第一个元素，执行3中的add p12, p12, p11, LSR #(48 - (1+PTRSHIFT))，首先p11是存储的mask，mask向右移动44位，等价于mask左移4位；在iOS底层系列11 -- 类的cache成员分析中我们知道 mask = buckets集合的空间大小 - 1，p12 = p12 + mask * 16，即将p12设置成buckets中的最后一个元素；
6.2.1.1> ldp p17, p9, [x12] 将x12的imp-sel分别赋值给p17和p9；
6.2.1.2> 接下来的查找逻辑与6.2.2类似，都是向前查找，遍历完成都没有找到，就会进入JumpMiss $0

6.2.2> 若p12不是第一个元素，执行ldp p17, p9, [x12, #-BUCKET_SIZE]! 首先[x12, #-BUCKET_SIZE]!等价于x12 = x12 - 16；即当前bucket向前移动一个单位，得到前面一个bucket且赋值给x12，然后将x12的imp-sel分别赋值给p17和p9，再跳转到1中执行。