Mojo::DOM

作者: JSON_NULL | 来源:发表于2017-09-26 15:53 被阅读13次

Mojo::DOM 是一个有CSS选择器支持的,简约的HTML/XML DOM解析器。它会尝试解释不正常的HTML和XML,所以你不应该使用它进行HTML和XML语法正确性的验证。

简介

当我们解析HTML/XML片段时,它会变成一个节点树。目前有八种不同类型的节点,它们分别是:cdata、comment、doctype、pi、raw、root、tag、text。元素是类型为tag的节点。

虽然所有节点类型都表示为Mojo::DOM对象,但像"attr"和"namespace"这样的方法只适用于元素操作。

<!DOCTYPE html>
<html>
  <head><title>Hello</title></head>
  <body>World!</body>
</html>         

## 以上html代码会被解析成如下节点树

root
|- doctype (html)
+- tag (html)
   |- tag (head)
   |  +- tag (title)
   |     +- raw (Hello)
   +- tag (body)
      +- text (World!)

大小写敏感

Mojo::DOM 默认为HTML语义,也就是说所有标签和属性名都是小写的,并且选择器也是小写的。

# HTML semantics
my $dom = Mojo::DOM->new('<P ID="greeting">Hi!</P>');
say $dom->at('p[id]')->text;

如果发现代码中有XML声明,解析器将自动切换到XML模式,并且所有内容都会区分大小写。

# XML semantics
my $dom = Mojo::DOM->new('<?xml version="1.0"?><P ID="greeting">Hi!</P>');
say $dom->at('P[ID]')->text;

使用xml方法可以强制使用HTML或XML模式。

# Force HTML semantics
my $dom = Mojo::DOM->new->xml(0)->parse('<P ID="greeting">Hi!</P>');
say $dom->at('p[id]')->text;

# Force XML semantics
my $dom = Mojo::DOM->new->xml(1)->parse('<P ID="greeting">Hi!</P>');
say $dom->at('P[ID]')->text;

方法

Mojo::DOM 模块中实现了以下方法。

all_text

my $text = $dom->all_text;

从此元素的所有后代节点提取文本内容。

# "foo\nbarbaz\n"
$dom->parse("<div>foo\n<p>bar</p>baz\n</div>")->at('div')->all_text;

ancestors

my $collection = $dom->ancestors;
my $collection = $dom->ancestors('div ~ p');

查找与CSS选择器匹配的此节点的所有祖先元素,并将包含这些元素的Mojo::Collection对象返回为Mojo::DOM对象。支持Mojo::DOM::CSS中的SELECTORS介绍的所有选择器。

# List tag names of ancestor elements
say $dom->ancestors->map('tag')->join("\n");

append

$dom = $dom->append('<p>I ♥ Mojolicious!</p>');

此方法可以在除root节点之外的其他所以类型的节点后面添加HTML/XML代码片段。

# "<div><h1>Test</h1><h2>123</h2></div>"
$dom->parse('<div><h1>Test</h1></div>') ->at('h1')->append('<h2>123</h2>')->root;

# "<p>Test 123</p>"
$dom->parse('<p>Test</p>')->at('p') ->child_nodes->first->append(' 123')->root;

append_content

$dom = $dom->append_content('<p>I ♥ Mojolicious!</p>');

在root或tag类型节点的内容后面添加HTML/XML代码片段或“原始内容”。

# "<div><h1>Test123</h1></div>"
$dom->parse('<div><h1>Test</h1></div>') ->at('h1')->append_content('123')->root;

# "<!-- Test 123 --><br>"
$dom->parse('<!-- Test --><br>')->child_nodes->first->append_content('123 ')->root;

# "<p>Test<i>123</i></p>"
$dom->parse('<p>Test</p>')->at('p')->append_content('<i>123</i>')->root;

at

my $result = $dom->at('div ~ p');

查找$dom后代元素中与CSS选择器匹配的元素,并把查找到的第一个符合要求的元素作为Mojo::DOM对象返回。当找不到符合要求的元素时返回undef。支持Mojo::DOM::CSS中所有的选择器(SELECTORS)。

# Find first element with "svg" namespace definition
my $namespace = $dom->at('[xmlns\:svg]')->{'xmlns:svg'};

attr

my $hash = $dom->attr;
my $foo  = $dom->attr('foo');
$dom     = $dom->attr({foo => 'bar'});
$dom     = $dom->attr(foo => 'bar');

对元素属性的操作,可以获取属性值,设置属性值,删除属性值。

# Remove an attribute
delete $dom->attr->{id};

# Attribute without value
$dom->attr(selected => undef);

# List id attributes
say $dom->find('*')->map(attr => 'id')->compact->join("\n");

child_nodes

my $collection = $dom->child_nodes;

返回 Mojo::Collection对象,该对象包含的是以Mojo::DOM对象存在的$dom元素的所有子节点。

# "<p><b>123</b></p>"
$dom->parse('<p>Test<b>123</b></p>')->at('p')->child_nodes->first->remove;

# "<!DOCTYPE html>"
$dom->parse('<!DOCTYPE html><b>123</b>')->child_nodes->first;

# " Test "
$dom->parse('<b>123</b><!-- Test -->')->child_nodes->last->content;

children

my $collection = $dom->children;
my $collection = $dom->children('div ~ p');

查找与CSS选择器匹配的$dom元素的所有子元素。返回一个Mojo::Collection对象,其中包含的是以Mojo::DOM对象表示的符合要求的元素。支持Mojo::DOM::CSS的SELECTORS中介绍的所有选择器。

# Show tag name of random child element
say $dom->children->shuffle->first->tag;

content

my $str = $dom->content;
$dom    = $dom->content('<p>I ♥ Mojolicious!</p>');

返回$dom元素的内容,或将$dom中的内容替换为指定的HTML/XML代码片段或原始内容。仅针对root和tag类型的元素有效。

# "<b>Test</b>"
$dom->parse('<div><b>Test</b></div>')->at('div')->content;

# "<div><h1>123</h1></div>"
$dom->parse('<div><h1>Test</h1></div>')->at('h1')->content('123')->root;

# "<p><i>123</i></p>"
$dom->parse('<p>Test</p>')->at('p')->content('<i>123</i>')->root;

# "<div><h1></h1></div>"
$dom->parse('<div><h1>Test</h1></div>')->at('h1')->content('')->root;

# " Test "
$dom->parse('<!-- Test --><br>')->child_nodes->first->content;

# "<div><!-- 123 -->456</div>"
$dom->parse('<div><!-- Test -->456</div>')->at('div')->child_nodes->first->content(' 123 ')->root;

descendant_nodes

my $collection = $dom->descendant_nodes;

返回一个Mojo::Collection对象,该对象中包含的是以Mojo::DOM对象表示的$dom元素的所有后代节点。

# "<p><b>123</b></p>"
$dom->parse('<p><!-- Test --><b>123<!-- 456 --></b></p>')
->descendant_nodes->grep(sub { $_->type eq 'comment' })
->map('remove')->first;

# "<p><b>test</b>test</p>"
$dom->parse('<p><b>123</b>456</p>')
->at('p')->descendant_nodes->grep(sub { $_->type eq 'text' })
->map(content => 'test')->first->root;

find

my $collection = $dom->find('div ~ p');

查找与CSS选择器匹配的$dom元素的所有后代元素。返回一个Mojo::Collection对象,其中包含的是以Mojo::DOM对象表示的符合要求的元素。支持Mojo::DOM::CSS的SELECTORS中介绍的所有选择器。

# Find a specific element and extract information
my $id = $dom->find('div')->[23]{id};

# Extract information from multiple elements
my @headers = $dom->find('h1, h2, h3')->map('text')->each;

# Count all the different tags
my $hash = $dom->find('*')->reduce(sub { $a->{$b->tag}++; $a }, {});

# Find elements with a class that contains dots
my @divs = $dom->find('div.foo\.bar')->each;

following

my $collection = $dom->following;
my $collection = $dom->following('div ~ p');

查找与CSS选择器匹配的$dom元素之后的所有同级元素。返回一个Mojo::Collection对象,其中包含的是以Mojo::DOM对象表示的符合要求的元素。支持Mojo::DOM::CSS的SELECTORS中介绍的所有选择器。

# List tags of sibling elements after this node
say $dom->following->map('tag')->join("\n");

following_nodes

my $collection = $dom->following_nodes;

返回一个Mojo::Collection对象,其中包含以Mojo::DOM对象表示的$dom节点之后的所有兄弟节点。

# "C"
$dom->parse('<p>A</p><!-- B -->C')->at('p')->following_nodes->last->content;

matches

my $bool = $dom->matches('div ~ p');

查询当前元素是否与CSS选择器匹配。支持Mojo::DOM::CSS的SELECTORS中介绍的所有选择器。

# True
$dom->parse('<p class="a">A</p>')->at('p')->matches('.a');
$dom->parse('<p class="a">A</p>')->at('p')->matches('p[class]');

# False
$dom->parse('<p class="a">A</p>')->at('p')->matches('.b');
$dom->parse('<p class="a">A</p>')->at('p')->matches('p[id]');

namespace

my $namespace = $dom->namespace;

返回当前元素的命名空间,如果找不到则会把undef。

# Find namespace for an element with namespace prefix
my $namespace = $dom->at('svg > svg\:circle')->namespace;

# Find namespace for an element that may or may not have a namespace prefix
my $namespace = $dom->at('svg > circle')->namespace;

new

my $dom = Mojo::DOM->new;
my $dom = Mojo::DOM->new('<foo bar="baz">I ♥ Mojolicious!</foo>');

构建一个新的基于标题的Mojo::DOM对象,并在必要时解析HTML/XML代码片段。

next

my $sibling = $dom->next;

以Mojo::DOM对象的形式返回下一个同级元素,如果没有则返回undef。

# "<h2>123</h2>"
$dom->parse('<div><h1>Test</h1><h2>123</h2></div>')->at('h1')->next;

next_node

my $sibling = $dom->next_node;

为下一个兄弟节点返回Mojo::DOM对象,如果找不到则返回undef。

# "456"
$dom->parse('<p><b>123</b><!-- Test -->456</p>')->at('b')->next_node->next_node;

# " Test "
$dom->parse('<p><b>123</b><!-- Test -->456</p>')->at('b')->next_node->content;

parent

my $parent = $dom->parent;

找到当前节点的父节点,并以Mojo::DOM对象返回,如果没有父节点则返回undef。

# "<b><i>Test</i></b>"
$dom->parse('<p><b><i>Test</i></b></p>')->at('i')->parent;

parse

$dom = $dom->parse('<foo bar="baz">I ♥ Mojolicious!</foo>');

使用Mojo::DOM::HTML解析HTML/XML片段。

# Parse XML
my $dom = Mojo::DOM->new->xml(1)->parse('<foo>I ♥ Mojolicious!</foo>');

prepend

$dom = $dom->prepend('<p>I ♥ Mojolicious!</p>');

在此节点之前添加HTML/XML代码片段(除root节点外,其他所有节点都可以使用些方法)。

# "<div><h1>Test</h1><h2>123</h2></div>"
$dom->parse('<div><h2>123</h2></div>')->at('h2')->prepend('<h1>Test</h1>')->root;

# "<p>Test 123</p>"
$dom->parse('<p>123</p>')->at('p')->child_nodes->first->prepend('Test ')->root;

prepend_content

$dom = $dom->prepend_content('<p>I ♥ Mojolicious!</p>');

将HTML/XML代码片段或原始内容添加到root或tag类型节点内容的前面。

# "<div><h2>Test123</h2></div>"
$dom->parse('<div><h2>123</h2></div>')->at('h2')->prepend_content('Test')->root;

# "<!-- Test 123 --><br>"
$dom->parse('<!-- 123 --><br>')->child_nodes->first->prepend_content(' Test')->root;

# "<p><i>123</i>Test</p>"
$dom->parse('<p>Test</p>')->at('p')->prepend_content('<i>123</i>')->root;

previous

my $sibling = $dom->previous;

以Mojo::DOM形式返回$dom元素前一个同级元素,如果没有则返回undef。

# "<h1>Test</h1>"
$dom->parse('<div><h1>Test</h1><h2>123</h2></div>')->at('h2')->previous;

previous_node

my $sibling = $dom->previous_node;

以Mojo::DOM对象的形式返回$dom节点的前一个同级节点,如果没有则返回undef。

# "123"
$dom->parse('<p>123<!-- Test --><b>456</b></p>')->at('b')->previous_node->previous_node;

# " Test "
$dom->parse('<p>123<!-- Test --><b>456</b></p>')->at('b')->previous_node->content;

remove

my $parent = $dom->remove;

删除当前节点,返回父节点或root节点(如果调用此方法的是root)。

# "<div></div>"
$dom->parse('<div><h1>Test</h1></div>')->at('h1')->remove;

# "<p><b>456</b></p>"
$dom->parse('<p>123<b>456</b></p>')->at('p')->child_nodes->first->remove->root;

replace

my $parent = $dom->replace('<div>I ♥ Mojolicious!</div>');

使用HTML/XML代码片段替换当前节点,以Mojo::DOM的形式返回父结点或返回root结点(如果调用此方法的是root)。

# "<div><h2>123</h2></div>"
$dom->parse('<div><h1>Test</h1></div>')->at('h1')->replace('<h2>123</h2>');

# "<p><b>123</b></p>"
$dom->parse('<p>Test</p>')->at('p')->child_nodes->[0]->replace('<b>123</b>')->root;

root

my $root = $dom->root;

以Mojo::DOM对象的形式返回当前结点的root结节。

strip

my $parent = $dom->strip;

在保留当前元素内容的情况下删除当前元素。就像是给当前元素脱去了衣服一样。以Mojo::DOM对象的形式返回当前元素的父元素。

# "<div>Test</div>"
$dom->parse('<div><h1>Test</h1></div>')->at('h1')->strip;

tag

my $tag = $dom->tag;
$dom    = $dom->tag('div');

设置或返回些元素的标签名。

# List tag names of child elements
say $dom->children->map('tag')->join("\n");

tap

$dom = $dom->tap(sub {...});

Mojo::Base 中 trap 的别名。

text

my $text = $dom->text;

仅从当前元素提取文件,不包含子元素。

# "bar"
$dom->parse("<div>foo<p>bar</p>baz</div>")->at('p')->text;

# "foo\nbaz\n"
$dom->parse("<div>foo\n<p>bar</p>baz\n</div>")->at('div')->text;

to_string

my $str = $dom->to_string;

将此节点及其内容以HTML/XML字符串的形式返回。

# "<b>Test</b>"
$dom->parse('<div><b>Test</b></div>')->at('div b')->to_string;

tree

my $tree = $dom->tree;
$dom     = $dom->tree(['root']);

文档对象模型的内部数据结构,因为这种数据结构非常灵活,所以返回的结果是动态的。

type

my $type = $dom->type;

返回当前节点的类型,可能的类型如下:cdata, comment,doctype,pi, raw, root, tag,text。

# "cdata"
$dom->parse('<![CDATA[Test]]>')->child_nodes->first->type;

# "comment"
$dom->parse('<!-- Test -->')->child_nodes->first->type;

# "doctype"
$dom->parse('<!DOCTYPE html>')->child_nodes->first->type;

# "pi"
$dom->parse('<?xml version="1.0"?>')->child_nodes->first->type;

# "raw"
$dom->parse('<title>Test</title>')->at('title')->child_nodes->first->type;

# "root"
$dom->parse('<p>Test</p>')->type;

# "tag"
$dom->parse('<p>Test</p>')->at('p')->type;

# "text"
$dom->parse('<p>Test</p>')->at('p')->child_nodes->first->type;

val

my $value = $dom->val;

从表单元素(button、input、option、select、textarea)中提取表单的值。如果元素没有值则返回undef。在select中使用multiple属性的情况下,会查找所有具有selected属性的option元素,返回的是一个包含所有找到option元素中值的数组的引用,如果找不到任何selected属性的option元素,则返回undef。

# "a"
$dom->parse('<input name=test value=a>')->at('input')->val;

# "b"
$dom->parse('<textarea>b</textarea>')->at('textarea')->val;

# "c"
$dom->parse('<option value="c">Test</option>')->at('option')->val;

# "d"
$dom->parse('<select><option selected>d</option></select>')->at('select')->val;

# "e"
$dom->parse('<select multiple><option selected>e</option></select>')->at('select')->val->[0];

# "on"
$dom->parse('<input name=test type=checkbox>')->at('input')->val;

with_roles

my $new_class = Mojo::DOM->with_roles('Mojo::DOM::Role::One');
my $new_class = Mojo::DOM->with_roles('+One', '+Two');
$dom          = $dom->with_roles('+One', '+Two');

Mojo::Base中with_roles方法的别名。

wrap

$dom = $dom->wrap('<div></div>');

在当前节点外包装HTML/XML代码片段(除root节点以外的所有节点都可以调用此方法),将当前节点作为“包装器”第一个最内层元素的最后一个子节点。

# "<p>123<b>Test</b></p>"
$dom->parse('<b>Test</b>')->at('b')->wrap('<p>123</p>')->root;

# "<div><p><b>Test</b></p>123</div>"
$dom->parse('<b>Test</b>')->at('b')->wrap('<div><p></p>123</div>')->root;

# "<p><b>Test</b></p><p>123</p>"
$dom->parse('<b>Test</b>')->at('b')->wrap('<p></p><p>123</p>')->root;

# "<p><b>Test</b></p>"
$dom->parse('<p>Test</p>')->at('p')->child_nodes->first->wrap('<b>')->root;

wrap_content

$dom = $dom->wrap_content('<div></div>');

在当前节点的“内容”外包装HTML/XML代码片段(只有root和tag节点可以调用此方法),将当前节点作为“包装器”第一个最内层元素的最后一个子节点。

# "<p><b>123Test</b></p>"
$dom->parse('<p>Test<p>')->at('p')->wrap_content('<b>123</b>')->root;

# "<p><b>Test</b></p><p>123</p>"
$dom->parse('<b>Test</b>')->wrap_content('<p></p><p>123</p>');

xml

my $bool = $dom->xml;
$dom     = $dom->xml($bool);

获取或设置解析器中禁用HTML语义的开关。默认为关闭状态。

重载的操作符

array

my @nodes = @$dom;

相当于调用了 child_nodes,可以理解为child_nodes的别名函数。

bool

my $bool = !!$dom;

总是返回true。

hash

my %attrs = %$dom;

相当于调用了 attr ,可以理解为 attr 的别名函数。

stringify

my $str = "$dom";

相当于调用了 to_string,可以理解为 to_string的别名函数。

相关文章

  • Mojo::DOM

    Mojo::DOM 是一个有CSS选择器支持的,简约的HTML/XML DOM解析器。它会尝试解释不正常的HTML...

  • Mojo::Home

    Mojo::Home为 Mojo程序提供“家目录”服务,它是一个Mojo程序“家目录”的容器。Mojo::Home...

  • mojo是什么?

    What is a Mojo? A mojo is a Maven plain Old Java Object. ...

  • Mojo::Base (不仅仅是对文档的翻译)

    Mojo::Base - Minimal base class for Mojo projects status...

  • Mojo::Reactor

    Mojo::Reactor 是低层事件驱动器的基类。通过子类Mojo::Reactor::EV和Mojo::Rea...

  • Mojo::EventEmitter

    简介 Mojo::EventEmitter - Event emitter base class Mojo::Ev...

  • Mojo::Log

    Mojo::Log模块是Mojo项目的简单日志记录器。并且它是Mojo::EventEmitter的一个子类。 语...

  • Mojo::UserAgent::CookieJar

    简介 Mojo::UserAgent::CookieJar是基于RFC 6265的供Mojo :: UserAge...

  • Mojo::UserAgent::Transactor

    简介 Mojo::UserAgent::Transactor 是Mojo::UserAgent中使用的事务构建和操...

  • Mojo::Asset::File

    简介 Mojo::Asset::File 是HTTP内容的文件存储。 事件 Mojo::Asset::File继承...

网友评论

    本文标题:Mojo::DOM

    本文链接:https://www.haomeiwen.com/subject/fmmrextx.html