仿动森球形弯曲地表

作者: duanoldfive | 来源:发表于2022-06-17 15:14 被阅读0次

仿动森球形弯曲地表
仿动森海岸线生成
动森
仿动森服装设计DIY功能
佝偻
曼荼罗——春意·森动
移民火星？先确定你能忍受没有窗户的生活再说吧
移民火星? 先确定你能忍受没有窗户的生活再说吧
呷哺世界杯套餐送的杯子真是反人类设计
生活

图片来自于网络，如有侵权请联系作者删除

老师:
"注意观察这张图片..."
小明:
"嗯，我看到了，它一脸嫌弃的看着我..."
老师:
"不是让你看这个小精灵，你看到后面的房子没有，只能看到一个房顶，研究一下，看看怎么实现"
小明:
"好的老师，这两个苹果真不错..."

弯曲地表

大家玩动森的时候都发现了，角色移动，地表会有一个弯曲的视差效果，看起来很酷，我们一起来分析一下实现原理。

平视(图1)

假设一个人前面有一个平板，他看过去就是我们的正常视角，如果想让它变成曲面，就得把平板做弯曲，如下图所示:

弯曲(图2)
看到平板弯曲的形状，是不是想起了高中学过的一元二次多项式曲线？

一元二次多项式曲线

当a=-1,b=c=0的时候，就是我们要的曲线了。也可以看做平板弯曲的程度(Y坐标位移值)和距离你操纵的角色(蓝框选中的小人)的距离的平方成正比。

DeltaY = curvature * Distance * Distance，其中curvature是一个常量。

好了，数学公式有了，下面我们就可以动手改写VertexShader了，首先要动态的把你操纵的角色的世界坐标传给Shader,然后在顶点Shader里面计算当前顶点到角色的距离的平方(因为向量求距离平方更高效,所以不用求出距离来再相乘), 然后乘上常量curvature，这个常量也开放给用户设置，以便控制弯曲的程度。封装一个函数给VertexShader调用:

//实现球面地形添加的代码
#if defined(_SPHERE_TERRAIN_ON)
uniform float _Curvature;   //曲率
uniform float3 _AnchorPosWS;    //地形的锚点

// 对外接口，得到弯曲后的裁切空间坐标
inline float4 GetFixedClipPos(float4 objVertex) 
{
    // 《动森》中只考虑z轴距离的弯曲
#ifdef _SPHERE_TERRAIN_ONLY_Z
    //顶点由本地坐标转换到世界坐标
    float3 worldPos = mul(unity_ObjectToWorld, objVertex);
    //摄像机的方向向量
    float3 viewDir = GetViewForwardDir();
    viewDir.y = 0.0f;
    float dist2Player = pow(dot(worldPos - _AnchorPosWS, normalize(viewDir)), 2);
    //根据离着玩家的远近，向下弯曲不同的坐标
    worldPos.y -= dist2Player * _Curvature;

    return mul(UNITY_MATRIX_VP, float4(worldPos, 1));
#else
    float3 worldPos = mul(unity_ObjectToWorld, objVertex);

    // 没有必要得到精确的距离，因此不计算开方
    float2 tempFloat2 = pow(worldPos.xz - _AnchorPosWS.xz, 2);
    float dist2Player = tempFloat2.x + tempFloat2.y;

    // 根据系数降低顶点"高度"，实现视差效果
    worldPos.y -= dist2Player * _Curvature;
    // 世界空间到剪裁空间
    return mul(UNITY_MATRIX_VP, float4(worldPos, 1));
#endif
}
#endif

这里提供了一个可选项 _SPHERE_TERRAIN_ONLY_Z，指明是仅仅弯曲摄像机向前的方向(摄像机空间Z轴方向在世界空间xz平面的投影方向),还是真的弯曲成一个球形。
然后修改VertexShader:

#if defined(_SPHERE_TERRAIN_ON)
    output.positionCS = GetFixedClipPos(input.positionOS);
#else
    output.positionCS = vertexInput.positionCS;
#endif

用_SPHERE_TERRAIN_ON宏区分开是否受弯曲参数影响。到此，Shader就准备好了，下面就要写脚本动态设置角色的位置到Shader了。

using System.Collections;
using System.Collections.Generic;
using UnityEngine;

public class SphereTerrainSetting : MonoBehaviour
{
    public Transform anchor;
    public float curvature;
    public bool sphereTerrainOnlyZ;
    
    private static int AnchorPosKeyId = Shader.PropertyToID("_AnchorPosWS");

    // Update is called once per frame
    void Update()
    {
        if (anchor != null)
        {
            Shader.SetGlobalVector(AnchorPosKeyId, anchor.position);
        }
    }

#if UNITY_EDITOR
    void OnValidate()
    {   
        if (Application.isPlaying)
        {
            Shader.SetGlobalFloat("_Curvature", curvature);
            if (sphereTerrainOnlyZ)
                Shader.EnableKeyword("_SPHERE_TERRAIN_ONLY_Z");
            else
                Shader.DisableKeyword("_SPHERE_TERRAIN_ONLY_Z");
        }
        else
        {
            Shader.SetGlobalFloat("_Curvature", 0.0f);
        }
    }
#endif
}

其中anchor就是你操纵的角色，curvature是你希望的曲率(弯曲程度),sphereTerrainOnlyZ是球形还是单向弯曲。把脚本挂载到任意GameObject上，勾选材质的选项以便打开_SPHERE_TERRAIN_ON宏。运行看看效果吧: