Linux文本处理工具三剑客：
grep：文本过滤器
sed：流编辑器
awk：报告生成器（格式化以后，显示）
awk基本使用格式：
awk [options] 'script' file1 file2 ...
awk [options] 'pattern {action}' file1 file2 ...
一、print
print的使用格式：
print item1,item2,...
要点：
（1）各项目之间使用逗号隔开，而输出时则以空白字符分割；
（2）输出的item可以为字符串或数值、当前记录的字段（如$1）、变量或awk的表达式；（数值会先转换为字符串，而后再输出；）
（3）print命令后面的item可以省略，此时其功能相当于print $0；如果想输出空白行，则需要使用print ""；
例子：
awk 'BEGIN { print "line one\nline two\nline three" }'
awk -F: '{ print $1,$3 }' /etc/passwd
二、printf
printf命令的使用格式：
printf format,item1,item2,...
要点：
（1）其与print命令的最大不同是：printf需要指定format；
（2）format用于指定后面的每个item的输出格式；
（3）printf语句不会自动打印换行符：\n
注意：在format格式中，格式与格式之间、字符串与字符串之间不需要使用逗号“，”进行隔开。
format格式的指示符都以%开头，后跟一个字符，如下：
%c：显示字符的ASCII码
%d,%i：十进制整数
%e,%E：科学计数法显示数值
%f：显示浮点数
%g,%G：以科学计数法的格式或浮点数的格式显示数值
%s：显示字符串
%u：无符号整数
%%：显示%自身
修饰符：
N：显示宽度
-：左对齐
+：显示数值符号
例子：
awk -F: '{printf "%-5d\n",$3}' /etc/passwd
awk -F: '{printf "%-15s %i\n",$1,$3}' /etc/passwd
三、awk变量
3.1 awk内置变量之记录变量
FS：Field separator，默认是空白字符，指定输入字段分隔符，读取文本时所使用字段分隔符；
RS：Record separator，默认是换行符，指定输入行分隔符，输入文本信息所使用的换行符；
OFS：Output Field Separator，默认是空白字符，指定输出字段分隔符
ORS：Out Record Separator，默认是换行符，指定输出行分隔符
3.2 awk内置变量之数据变量
NR：The number of input records,awk命令所处理的记录数；如果有多个文件，这个数目会把处理的多个文件中行统一计数；
FNR：与NR不同的是，FNR用于记录正在处理的行是当前这一文件中被总共处理的行数；
NF：Number of field,当前记录的field个数；
ARGV：数组，保存命令行本身这个字符串，如：awk '{print $0}' a.txt b.txt这个命令中，ARGV[0]保存awk，ARGV[1]保存a.txt；
ARGC：awk命令的参数的个数；
FILENAME：awk命令所处理的文件的名称；
ENVIRON：当前shell环境变量及其值的关联数组；如：awk 'BEGIN{print ENVIRON["PATH"]}'
3.3用户自定义变量
gawk允许用户自定义自己的变量以便在程序代码中使用，变量名命名规则与大多数编程语言相同，只能使用字母、数字和下划线，且不能以数字开头，gawk变量名称区分字符大小写。
3.3.1在脚本中赋值变量
在awk中给变量赋值使用赋值语句进行，例如：
awk 'BEGIN {var="variable testing";print var}'
注意：在action中如果有多个语句，语句之间用分号隔开。
3.3.2在命令行中使用赋值变量
gawk命令也可以在“脚本”外为变量赋值，并在脚本中进行引用，例如，上述的例子还可以改写为：
awk -v var="variable testing" 'BEGIN{print var}'
注意：在awk中打印变量值，变量值前是不需要加$的，这与shell是不同的。如果后面不加文件，一般都使用BEGIN模式。
四、awk操作符
4.1算术操作符
-x：
+x：
x^y：
x**y：
x*y：
x/y：
x+y：
x-y：
x%y：
4.2字符串操作符：
用于实现字符串连接
4.3赋值操作符
=
+=
-=
*=
/=
%=
^=
**=
++
--
注意：如果某模式为*号，此时使用/*/可能会有语法错误，应以/[*]/替代。
4.4布尔值
awk中，任何非0值或非空字符串都为真，反之就为假。
4.5比较操作符
x<y True if x is less than y.
x<=y True if x is less than or equal to y.
x>y True if x is greater than y.
x>=y True if x is greater than or equal to y.
x==y True if x is equal to y.
x!=y True if x is not equal to y.
x~y True if the string x matches the regexp denoted by y.
x!~y True if the string x does not match the regexp denoted by y.
subscript in array True if the array array has an element with the subscript subscript.
注意：awk中的比较操作符与shell中的比较操作符不一样，使用时注意区分。
例子：
awk -F: '$3+1>=500{print $1,$3}' /etc/passwd
4.6表达式间的逻辑关系符
$$
||
！
4.7条件表达式
selector?if-true-exp:if-false-exp
等价于：
if selector; then
if-true-exp
else
if-false-exp
fi
4.8函数调用
function_name(para1,para2)
五、awk模式
awk 'program' input-file1 input-file2 ...
其中的program为：
pattern {action}
pattern {action}
...
5.1常见的模式类型
（1）Regexp：正则表达式，格式为/regular expression/
（2）Expression：表达式，其值非0或为非空字符时满足条件，$1~/foo/或$1=="magedu"，用运算符~（匹配）和！~（不匹配）
（3）Ranges：指定的匹配范围（最好使用模式作为匹配），格式为pat1,pat2
（4）BEGIN/END：特殊模式，仅在awk命令执行前运行一次或结束前运行一次
（5）Empty：空模式，匹配任意输入行
/正则表达式/：使用通配符的扩展集。
关系表达式：可以用下面运算符表中的关系运算符进行操作，可以是字符串或数字的比较，如$2>$1选择第二个字段比第一个字段长的行。
模式匹配表达式：模式，模式（指定一个行的范围，该语法不能包括BEGIN和END模式。）
BEGIN：让用户指定在第一条输入记录被处理之前所发生的动作，通常可在这里设置全局变量。
END：让用户在最后一条输入记录被读取之后发生的动作。
例子：
awk -F: '/^r/{print $1}' /etc/passwd
//正则表达式：取出以r开头的行的第一个字段（显示以r开头的用户的用户名）
awk -F: '$7~"bash$"{print $1,$7}' /etc/passwd
//表达式：取出默认shell是bash shell的用户
awk -F: '$3==0,$7~"nologin"{print $1,$3,$7}' /etc/passwd
awk -F: '/^r/,/^m/{print $1,$7}' /etc/passwd
//模式匹配：匹配以r开头的行，到以m开头的行之间的所有行，并取出用户名和shell。
awk -F: 'BEGIN {print "Username ID Shell"} $3==0,$7~"nologin" {printf "%-10s%-10s%-20s\n",$1,$3,$7}END{print "End of report."}' /etc/passwd
//BEGIN/END
awk -F: '{printf "%-10s%-10s%-20s\n",$1,$3,$7}' /etc/passwd
//Empty
5.2常见的action
（1）Expressions：表达式，如赋值表达式、判断表达式
（2）Control statements：控制语句，如if、case、for、while、do-while
（3）Compound statements：复合语句
（4）Input statements：输入语句
（5）Output statements：输出语句
六、控制语句
6.1 if-else
语法：if (condition) {then-body} else {[else-body]}
例子：
awk -F: '{if ($1=="root") print $1,"Admin"; else print $1,"Common User"}' /etc/passwd
awk -F: '{if ($1=="root") printf "%-15s: %s\n",$1,"Admin"; else printf "%-15s: %s\n",$1,"Common User"}' /etc/passwd
awk -F: -v sum=0 '{if ($3>=500) sum++}END{print sum}' /etc/passwd
注意：格式与shell不同，但是逻辑相同。
6.2 while
语法：while (condition){statement1;statement2;...}
例子：
awk -F: '{i=1;while (i<=NF) {if (length($i)>=4) print $i; i++}}' /etc/passwd
awk -F: '{i=1;while (i<=3){print $i; i++}}' /etc/passwd
6.3 do-while
语法：do {statements1;statements2;...}while (condition)
例子：
awk -F: '{i=1;do {print $i; i++}while (i<=3)}' /etc/passwd
注意：shell中没有do-while,类似于C语言风格的循环。
6.4 for
语法：for (variable assignment; condition; iteration process) {statement1;statement2;...}
例子：
awk -F: '{for (i=1;i<=NF;i++) {if (length($i)>=4) print $i}}' /etc/passwd
awk -F: '{for(i=1;i<=3;i++) print $i}' /etc/passwd
6.5 case
语法：switch (expression) {case VALUE or /REGEXP/: statement1,statement2,... default: statement1,...}
6.6 break和continue
常用于循环或case语句中
6.7 next
提前结束对本行文本的处理，并接着处理下一行。例如，下面的命令将显示其ID号为奇数的用户：
awk -F: '{if ($3%2==0) next;print $1,$3}' /etc/passwd
七、awk中使用数组
7.1数组
array[index-expression]
index-expression可以使用任意字符串。需要注意的是，如果某数组元素事先不存在，那么在引用其时，awk会自动创建此元素并初始化为空串；因此，要判断某数组中是否存在某元素，需要使用index in array。
awk中数组下标是从1开始的，shell中数组下标是从0开始。
要遍历数组中的每一个元素，需要使用如下的特殊结构：
for (var in array) {statement1, ...}
其中，var用于引用数组下标，而不是元素值。
例子：
awk -F: '{shell[$NF]++}END{for (A in shell) {print A,shell[A]}}' /etc/passwd
在awk中，变量在第一次引用的初始值为0。
netstat -ant | awk '/^tcp/{STATE[$NF]++}END{for (S in STATE) {print S,STATE[S]}}'
统计tcp连接：每出现一被/^tcp/模式匹配到的行，数组STATE[$NF]就加1，NF为当前匹配到的行的最后一个字段，此处用其值作为数组STATE的元素索引。
awk '{counts[$1]++} END {for (ip in counts) print counts[ip],ip}' /var/log/httpd/access_log
用于统计某日志文件中IP地址的访问量
7.2删除数组变量
从关系数组中删除数组索引需要使用delete命令，使用格式为：
delete array[index]
八、输出重定向
print items > output-file
print items >> output-file
print items | command
特殊文件描述符：
/dev/stdin：标准输入
/dev/stdout：标准输出
/dev/stdeer：错误输出
/dev/fd/N：某特定文件描述符，如/dev/stdin就相当于/dev/fd/0；
例子：
awk -F: '{printf "%-15s %i\n",$1,$3 > "/dev/stderr"}' /etc/passwd
网友评论