介绍
jvm字节码指令就是由一组带有特定操作含义的数字并且后面跟上操作参数组成。
加载和存储指令
将数据从栈桢中的局部变量表和操作数栈之间来回传输。
局部变量表：存放编译期就已经知道的各种基本数据类型、对象引用类型；注意：在编译期间完成对所需的内存空间的分配。
操作数栈：就是一个先进后出的栈，在方法执行的时候会将各种字节码指令操作栈（譬如入栈和出栈等）。
- 局部变量加载到操作数栈
iload 、 iload_<n> 、lload 、lload_<n> 、fload 、 fload_<n> 、 dload dload_<n>、 aload 、 aload_<n>
- 从操作数栈存储到局部变量表
istore 、istore_<n> 、 lstore 、 lstore_<n>、 fstore 、fstore_<n> dstore 、 dstore_<n> 、astore 、 astore_<n>
- 常量加载到操作数栈
bipush、 sipush 、 ldc、 ldc_w、 ldc2_w 、aconst_null 、 iconst_null iconst_<i>、 lconst_<l> 、 fconst_<f> 、dconst_<d>
运算指令
就是对操作数栈中栈顶上的值进行运算，然后将结果入栈。
- 加法指令
iadd、 ladd、 fadd、 dadd
- 减法指令
isub、 lsub 、 fusb、 dsub
- 乘法指令
imul 、 lmul 、fmul 、 dmul
- 除法指令
idiv、 ldiv、 fdiv 、 ddiv
- 求余指令
irem、 lrem、 frem、 drem
- 取反指令
ineg、 lneg 、 fneg 、 dneg
- 位移指令
ishl、 ishr、 iushr、 lshl 、 lshr 、 lushr
- 按位或指令
ior、 lor
- 按位与指令
iand 、 land
- 按位异或指令
ixor 、 lxor
- 局部变量自增指令
iinc
- 比较指令
dcmpg 、 dcmpl 、fcmpg 、 fcmpl、 lcmp
类型转换指令
- 宽化类型转换
譬如：int类型到long、float或者double类型；float类型到double类型；long类型到float、double类型。
i2l、f2b、l2f、l2d、f2d
- 窄化类型转换
i2b、i2c、i2s、l2i、f2i、f2l、d2i、d2l、d2f
对象创建与访问指令
- 创建类实例的指令
new
- 创建数组的指令
newarray、anewarray、multianewarray
- 访问static类型的字段
getstatic、putstatic
- 访问非static类型的字段
getfield、putfield
- 把一个数组元素加载到操作数栈
baload、caload、saload、iaload、laload、faload、daload、aaload
- 将一个操作数栈的值存储到数组元素中的指令
bastore、castore、sastore、iastore、fastore、dastore、aastore
- 取数组长度的指令
arraylength
- 检查类实例类型的指令
instanceof、checkcast
操作数栈管理指令
- 将操作数栈顶的元素一个或两个出栈
pop、pop2
- 复制一个栈顶元素或者两个栈顶元素重新入栈
dup、dup2、dup_x1、dup2_x1、dup_x2、dup2_x2
- 将栈最顶端的两个元素互换
swap
控制转移指令
- 条件分支
ifeq、iflt、ifle、ifne、ifgt、ifge、ifnull、ifnonnull、if_icmpeq、if_icmpne、if_icmplt、if_icmpgt、if_icmple、if_icmpge、if_acmpeq、if_acmpne
- 复合条件分支
tableswitch、lookupswitch
- 无条件分支
goto、goto_w、jsr、jsr_w、ret
方法调用和返回指令
- 调用对象的实例方法
**invokevirtual **
- 用于调用接口方法
invokeinterface
- 用于调用一些需要特殊处理的实例方法，包括实例初始化（＜init＞）方法、私有方法和父类方法
invokespecial
- 调用静态方法
invokestatic
- 运行时动态解析引用方法，动态调用
invokedynamic 指令用于在运行时动态解析出调用点限定符所引用的方法，并执行该方法
异常处理指令
athrow
同步指令
Java虚拟机的指令集中有monitorenter、monitorexit两条指令来支持synchronized关键字的语义
例子
求和功能例子：
public class MyByteCodeTest {
public static void main(String[] args) {
int sum = 0;
for (int i = 0 ; i <= 10 ; i++) {
sum += i;
}
System.out.println(sum);
}
}
javap -verbose MyByteCodeTest.class查看：
C:\Users\Administrator\Desktop>javap -verbose MyByteCodeTest.class
Classfile /C:/Users/Administrator/Desktop/MyByteCodeTest.class
Last modified 2018-9-25; size 648 bytes
MD5 checksum 757fc39abe1522912132c7aaf462a0bb
Compiled from "MyByteCodeTest.java"
public class cn.spy.spring.test.MyByteCodeTest
minor version: 0
major version: 51
flags: ACC_PUBLIC, ACC_SUPER
Constant pool:
#1 = Class #2 // cn/spy/spring/test/MyByteCodeTest
#2 = Utf8 cn/spy/spring/test/MyByteCodeTest
#3 = Class #4 // java/lang/Object
#4 = Utf8 java/lang/Object
#5 = Utf8 <init>
#6 = Utf8 ()V
#7 = Utf8 Code
#8 = Methodref #3.#9 // java/lang/Object."<init>":()V
#9 = NameAndType #5:#6 // "<init>":()V
#10 = Utf8 LineNumberTable
#11 = Utf8 LocalVariableTable
#12 = Utf8 this
#13 = Utf8 Lcn/spy/spring/test/MyByteCodeTest;
#14 = Utf8 main
#15 = Utf8 ([Ljava/lang/String;)V
#16 = Fieldref #17.#19 // java/lang/System.out:Ljava/io/Print
Stream;
#17 = Class #18 // java/lang/System
#18 = Utf8 java/lang/System
#19 = NameAndType #20:#21 // out:Ljava/io/PrintStream;
#20 = Utf8 out
#21 = Utf8 Ljava/io/PrintStream;
#22 = Methodref #23.#25 // java/io/PrintStream.println:(I)V
#23 = Class #24 // java/io/PrintStream
#24 = Utf8 java/io/PrintStream
#25 = NameAndType #26:#27 // println:(I)V
#26 = Utf8 println
#27 = Utf8 (I)V
#28 = Utf8 args
#29 = Utf8 [Ljava/lang/String;
#30 = Utf8 sum
#31 = Utf8 I
#32 = Utf8 i
#33 = Utf8 StackMapTable
#34 = Utf8 SourceFile
#35 = Utf8 MyByteCodeTest.java
{
public cn.spy.spring.test.MyByteCodeTest();
descriptor: ()V
flags: ACC_PUBLIC
Code:
stack=1, locals=1, args_size=1
0: aload_0
1: invokespecial #8 // Method java/lang/Object."<init>
":()V
4: return
LineNumberTable:
line 3: 0
LocalVariableTable:
Start Length Slot Name Signature
0 5 0 this Lcn/spy/spring/test/MyByteCodeTest;
public static void main(java.lang.String[]);
descriptor: ([Ljava/lang/String;)V
flags: ACC_PUBLIC, ACC_STATIC
Code:
stack=2, locals=3, args_size=1
0: iconst_0
1: istore_1
2: iconst_0
3: istore_2
4: goto 14
7: iload_1
8: iload_2
9: iadd
10: istore_1
11: iinc 2, 1
14: iload_2
15: bipush 10
17: if_icmple 7
20: getstatic #16 // Field java/lang/System.out:Ljav
a/io/PrintStream;
23: iload_1
24: invokevirtual #22 // Method java/io/PrintStream.prin
tln:(I)V
27: return
LineNumberTable:
line 7: 0
line 9: 2
line 10: 7
line 9: 11
line 13: 20
line 14: 27
LocalVariableTable:
Start Length Slot Name Signature
0 28 0 args [Ljava/lang/String;
2 26 1 sum I
4 16 2 i I
StackMapTable: number_of_entries = 2
frame_type = 253 /* append */
offset_delta = 7
locals = [ int, int ]
frame_type = 6 /* same */
}
SourceFile: "MyByteCodeTest.java"
分析main函数中的字节码指令：
0: iconst_0 // 简单的数值类型int(0)送到栈顶 -- int sum = 0;将sum=0这个int值压入栈顶
1: istore_1 // 将栈顶int型数值存入第1个本地变量 -- 将sum=0这个int值存入第1个本地变量中
2: iconst_0 // 简单的数值类型int(0)送到栈顶 -- int i = 0;将i=0这个int值压入栈顶
3: istore_2 // 将栈顶int型数值存入第2个本地变量 -- 将i=0这个int值存入第2个本地变量中
4: goto 14 // 无条件跳转到14行 -- 无条件跳转到14行代码
7: iload_1 // 将第1个int型本地变量推送至栈顶
8: iload_2 // 将第2个int型本地变量推送至栈顶
9: iadd // 将栈顶两int型数值相加并将结果压入栈顶
10: istore_1 // 将栈顶int型数值存入第1个本地变量
11: iinc 2, 1 // 将int型的局部变量自增
14: iload_2 // 将第2个int型本地变量推送至栈顶
15: bipush 10 // 将单字节的常量值（-128~127）推送至栈顶
17: if_icmple 7 // 比较栈顶两int型数值的大小，当结果小于等于0时跳转
20: getstatic #16 // Field java/lang/System.out:Ljava/io/PrintStream;
23: iload_1 // 将第1个int型本地变量推送至栈顶
24: invokevirtual #22 // Method java/io/PrintStream.println:(I)V
27: return //方法返回指令
分析结果：
1. int sum = 0;将sum=0这个int值压入栈顶
2. 将sum=0这个int值存入第1个本地变量中
3. int i = 0;将i=0这个int值压入栈顶
4. 将i=0这个int值存入第2个本地变量中
5. 跳转到14行代码
6. 将第2个本地变量中i=0压入栈顶
7. 将常量值10压入栈顶
8. 栈顶值i=0小于栈顶常量10，将跳转至第7行代码
9. 将第1个本地变量中sum=0压入栈顶
10. 将第2个本地变量中i=0压入栈顶
11. 将栈顶sum=0和i=0两个值相加，结果再次压入栈顶
12. 将上次相加结果值存入第1个本地变量中
13. 将第2个本地变量自增
14. 将第2个本地变量压入栈顶
15. 然后又继续执行第7步，步骤7到步骤15开始循环直到i自增到不小于10
16. 获取类变量（PrintStream）
17. 将第1个本地变量中的值sum压入栈中
18. 调用对象的实例方法println
19. 返回值为void的函数返回指令
总结
可以发现jvm中的字节码指令对于for循环的实现采用if_icmple指令来实现的。而函数的处理采用操作数栈和本地变量表来进行实现的。
网友评论