美文网首页
万有引(斥)力

万有引(斥)力

作者: 大龙10 | 来源:发表于2022-04-22 06:27 被阅读0次

书名:代码本色:用编程模拟自然系统
作者:Daniel Shiffman
译者:周晗彬
ISBN:978-7-115-36947-5
目录

2.10 万有引(斥)力

  我们从最简单的例子开始,也就是一个物体吸引另一个物体的模型,之后扩展到一个物体吸引多个物体的模型。
  下面,我们将研究更复杂的模型:多个物体相互吸引。换句话说,在新的系统中,每个对象对其他任何对象(系统本身除外)都有吸引作用。

1、draw()函数的逻辑变化

  我们已经完成了其中的大部分工作。请思考下面的场景,有一个由Mover对象组成的数组:

Mover[] movers = new Mover[10];
void setup() {
    size(400,400);
    for (int i = 0; i < movers.length; i++) {
      movers[i] = new Mover(random(0.1,2),random(width),random(height));
    }
}

void draw() {
    background(255);
    for (int i = 0; i < movers.length; i++) {
      movers[i].update();
      movers[i].display();
    }
}

我们需要在draw()函数上做些修改,

  • 之前,我们的实现逻辑是:
    对每个Mover i,先更新其位置,并在屏幕上绘制出来。
  • 现在我们要把它实现成:
    对每个Mover i,都受到其他Mover j的吸引,更新i的位置,并在屏幕上绘制出来。

2、嵌套一个循环

为了实现这个逻辑,我们需要再嵌套一个循环。

for (int i = 0; i < movers.length; i++) {
  for (int j = 0; j < movers.length; j++) { 每个Mover对象都要检查所有其他Mover对象
    PVector force = movers[j].attract(movers[i]);
    movers[i].applyForce(force);
  }
    movers[i].update();
    movers[i].display();
}

3、attract()函数

  • 在前面的例子中,Attractor对象有一个attract()函数。
  • 在这里,Mover对象也能产生引力,因此我们需要将attract()函数复制到Mover类中。
class Mover {
//此处加上前面写过的代码
PVector attract(Mover m) { 现在,Mover对象知道如何吸引其他Mover对象
    PVector force = PVector.sub(location,m.location);
    float distance = force.mag();
    distance = constrain(distance,5.0,25.0);
    force.normalize();
    float strength = (G mass m.mass) / (distance * distance);
    force.mult(strength);
    return force;
    }
}

4、小问题

  当然,这里还有一个小问题。

  • 用i和j遍历Mover数组时,碰到i等于j的情况该怎么办?
  • 比如,Mover3对Mover3是否有吸引作用?
    当然,Mover对自身是没有引力的。
  • 如果同时有5个Mover,Mover3只对0、1、2、4有吸引作用,对自身并没有吸引作用。
  • 因此,为了完成这个模型,我们需要加入一个简单的条件判断语句,在遍历时跳过i等于j的场景。

5、示例代码

示例代码2-8 万有引力

Mover[] movers = new Mover[20];

float g = 0.4;

void setup() {
  size(640,360);
  for (int i = 0; i < movers.length; i++) {
    movers[i] = new Mover(random(0.1,2),random(width),random(height)); 
  }
}

void draw() {
  background(255);


  for (int i = 0; i < movers.length; i++) {
    for (int j = 0; j < movers.length; j++) {
      if (i != j) {
        PVector force = movers[j].attract(movers[i]);
        movers[i].applyForce(force);
      }
    }

    movers[i].update();
    movers[i].display();
  }

}

mover.pde

class Mover {

  PVector position;
  PVector velocity;
  PVector acceleration;
  float mass;
  color c;

  Mover(float m, float x, float y) {
    mass = m;
    position = new PVector(x, y);
    velocity = new PVector(0, 0);
    acceleration = new PVector(0, 0);
    c = color(random(255),random(255),random(255));
  }

  void applyForce(PVector force) {
    PVector f = PVector.div(force, mass);
    acceleration.add(f);
  }

  void update() {
    velocity.add(acceleration);
    position.add(velocity);
    acceleration.mult(0);
  }

  void display() {
    stroke(0);
    strokeWeight(2);
    //fill(0, 100);
    fill(c);
    ellipse(position.x, position.y, mass*24, mass*24);
  }

  PVector attract(Mover m) {
    PVector force = PVector.sub(position, m.position);             // Calculate direction of force
    float distance = force.mag();                                 // Distance between objects
    distance = constrain(distance, 5.0, 25.0);                             // Limiting the distance to eliminate "extreme" results for very close or very far objects
    force.normalize();                                            // Normalize vector (distance doesn't matter here, we just want this vector for direction

    float strength = (g * mass * m.mass) / (distance * distance); // Calculate gravitional force magnitude
    force.mult(strength);                                         // Get force vector --> magnitude * direction
    return force;
  }


}

6、运行结果

相关文章

  • 万有引(斥)力

    书名:代码本色:用编程模拟自然系统作者:Daniel Shiffman译者:周晗彬ISBN:978-7-115-3...

  • 随记

    每每有了需要才有行动的可能,而需要的产生无外乎两种可能,一引一斥,引是内在的渴望,斥是外在的压力。或者说渴...

  • 《100个精美短章》

    1 那怕是 美丽 对人 也并非 万有 引 力 2 世界 是真实的 必须 注意的是 它有许多 幻 象 3 只有梦想 ...

  • 引斥效应/厚生168

    . 引斥效应是现象。‘引力’和‘斥力’一样,都是结点周期效应的正反过程描述。点是本系,结是性系。此点,彼点来结;此...

  • 基础物理学有缺陷,我希望修正并带来意义

    基础物理学有缺陷,我希望修正并带来意义 万有散力 宇宙万有散力和引力就是可以解释为一种吸收与释放,其实证实万有散力...

  • 人生效率手册

    我是阿拉丁,万有美力文化传播公司创始人,牛顿发现了万有引力,我发现了万有美力!未来要在美学的道路上越走越远!世间不...

  • 小偷家族的万有引力

    小偷家族的日语名字是万引家族,万引在日语中是特指在便利店里小偷小摸的人,但我更喜欢他中文的意思,万引——万有引力—...

  • 第三节、三力律则

    三力分别为阴之力、阳之力、中和之力,三力是万有意志的显化,祂们是三位一体,不可分割的绝对整体。万有运用三力的分...

  • 天体间为什么没被万有引力吸引成“完全一坨”?

    宇宙间的物质之间产生相互吸引的现象,是牛顿在1687年发现的,叫做万有引力,发表在《自然哲学之数学原理》中。万有引...

  • 二月复盘——慵懒的一个月

    接纳现状是很重要的,所有来到你面前的安排,可能比你原来设定的还要好。 ——万有引历...

网友评论

      本文标题:万有引(斥)力

      本文链接:https://www.haomeiwen.com/subject/lozdertx.html