CH8.7 查看编译器优化结果

作者: 磊宝万岁 | 来源:发表于2019-05-19 22:09 被阅读0次

CH8.7 查看编译器优化结果
LLVM
c++如何避免编译优化
编写调试Pass
Linux 下如何绕过编译器优化
JMM造成指令重排的原因
iOS逆向之OC反汇编（上）
编译器常用优化方法
编译优化算法
内联函数（Inline Function）

8.7 查看编译的结果

编译器形成汇编代码做了很多事情，但是有些情况下他做的并不是很好，如果我们能够查看汇编代码并且有目的的优化那是最好不过了。
在gcc中可以使用-fsource-asm选项来查看c代码与汇编代码的对应关系，因为只加-S参数的话在.s文件中不会显示源代码只会显示行数。

gcc xx.c -S -fsource-asm

注意如果你想看看编译器完全优化之后的样子，就不要开启-fsource-asm选项。

下面的例子展示了如何通过汇编代码来优化我们的程序：加入我们有这个一个程序：

void Func(int a[], int & r) {
  int i;
  for (i = 0; i < 100; i++) {
    a[i] = r + i/2;
  }
}

编译后该部分代码是这样的：

ALIGN 4 ; align by 4
PUBLIC ?Func@@YAXQAHAAH@Z ; mangled function name
?Func@@YAXQAHAAH@Z PROC NEAR ; start of Func
; parameter 1: 8 + esp ; a
; parameter 2: 12 + esp ; r
    $B1$1:                        ; unused label
    push ebx                      ; save ebx on stack
    mov ecx, DWORD PTR [esp+8]    ; ecx = a
    xor eax, eax                  ; eax = i = 0
    mov edx, DWORD PTR [esp+12]   ; edx = r
$B1$2:                            ; top of loop
    mov ebx, eax                  ; compute i/2 in ebx
    shr ebx, 31                   ; shift down sign bit of i
    add ebx, eax                  ; i + sign(i)  ;; == i + 1 ,because of division operation
    sar ebx, 1                    ; shift right = divide by 2
    add ebx, DWORD PTR [edx]      ; add what r points to
    mov DWORD PTR[ecx+eax*4],ebx  ; store result in array
    add eax, 1                    ; i++
    cmp eax, 100                  ; check if i < 100
    jl $B1$2                      ; repeat loop if true
$B1$3:                            ; unused label
    pop ebx                       ; restore ebx from stack
    ret                           ; return
    ALIGN 4                       ; align
?Func@@YAXQAHAAH@Z ENDP           ; mark end of procedure

上面代码比较好懂，但是有个一个部分我是看了好久然后跟实验室同学讨论过后才明白，就是shr ebx, eax \n add ebx, eax这两步为什么要有i + sign(i)操作呢？
CSAPP上有详细的讲计算机补码的除法运算那一部分有讲：除法的补救部分，对于除数是2的指数可以用以为操作来计算，但是当被除数是负数的时候(第一位是1)，单纯的移位不能得到正确的结果，但是有一个技巧就是对被除数加上一个“偏置”然后移位，比如说a / (2^k) 在计算机里面a是用a的补码表示的，计算方法就是： (a_补 + 2^k-1) >> k; 如果a是正数就直接a>>k;
对应于上面汇编，因为除数是2（源代码里对应 "i / 2"）所以如果i<0要对i进行"+2^1-1 = +1"操作，如果i>0就+0，正好对应+sign(i) 操作，不得不说编译器还真TM智能。

上面代码我们可能我们每天都会写，但是仔细阅读上面汇编我们可能发现如下问题：
1. i+sign(i)然后移位的操作虽然很秀，但是根本没必要，因为通过代码我们知道i是loop counter，不可能会小于0，所以除2操作直接移位就可以了；
2. add ebx, DWORD PTR [edx] ; add what r points to 这一步在循环中反复被执行，而我们知道这对应着一步访存操作，因为函数里面我们传的是&r,我们不知道r会不会在某一时刻改变，所以只能每次loop都重新从内存中load一遍，非常的耗时。
3. 由于r + i/2 是i的阶跃函数，所以我们可以把这个循环给展开来。

针对以上三点，我们修改后的代码如下：

void Func(int a[], int & r) {
  unsigned int i;
  int Induction = r;
  for (i = 0; i < 100; i += 2) {
    a[i] = Induction;
    a[i+1] = Induction;
    Induction++;
  }
}

编译后的代码如下：

ALIGN 4 ; align by 4
PUBLIC ?Func@@YAXQAHAAH@Z ; mangled function name
?Func@@YAXQAHAAH@Z PROC NEAR ; start of Func
; parameter 1: 4 + esp ; a
; parameter 2: 8 + esp ; r
$B1$1: ; unused label
    mov eax, DWORD PTR [esp+4]    ; eax = address of a
    mov edx, DWORD PTR [esp+8]    ; edx = address in r
    mov ecx, DWORD PTR [edx]      ; ecx = Induction
    lea edx, DWORD PTR [eax+400]  ; edx = point to end of a
$B2$2:                            ; top of loop
    mov DWORD PTR [eax], ecx      ; a[i] = Induction;
    mov DWORD PTR [eax+4], ecx    ; a[i+1] = Induction;
    add ecx, 1                    ; Induction++;
    add eax, 8                    ; point to a[i+2]
    cmp edx, eax                  ; compare with end of array
    ja $B2$2                      ; jump to top of loop
$B2$3:                            ; unused label
    ret                           ; return from Func
    ALIGN 4
; mark_end;