弄明白上下文转换时非常重要的，因为DAX的另外一个重要的功能。目前为止，我们都是在函数和计算列的calculate中写表达式，但是，如果你写的表达式包含了度量值，会怎么样？在计算列中使用度量值会怎么样？另外，在存在行上下文的情况下使用度量值会怎么样？
一个例子，我们可以这样定义一个度量值 sumofsalesamount:
[SumOfSalesAmount] := SUM ( Sales[SalesAmount] )
然后你可以定义一个计算列，如下
Product[SalesWithSUMX] =
SUMX (
Customer,
CALCULATE ( [SumOfSalesAmount] )
)
calculate的出现，提示了有上下文发生转换的现象。这里的重点时，当你在一个表达式中使用度量值的时候，DAX自动默认把这个表达式外添加一个calculate。因此，上面这个表达式的结果和下面这个一样：
Product[SalesWithSUMX] =
SUMX (
Customer,
[SumOfSalesAmount]
)
这次没有看到calculate了，但是上下文的转换依然会发生，因为DAX会自动添加一个calculate到计算中。
这就是为什么，你在写计算列和度量值的时候，要用不同的代码写法的原因。DAX书写的规律通常要求我们在写度量值的时候避免添加表的名称，而写计算列的时候，要添加表名做为前缀。事实上，在上面的公式中，表名称的缺失，暗示了 sumofsalesamount时一个度量值，这样你要预料到上下文转换的发生。
自动的上下文转换，使得我们对复杂的迭代计算变得简单化。熟练掌握这个功能需要一些时间。例如，如果你要计算那么买了大于平均值的客户的总销售额，你可以这样写：
[SalesMoreThanAverage] :=
VAR
AverageSales = AVERAGEX ( Customer, [SumOfSalesAmount] )
RETURN
SUMX (
Customer,
IF (
[SumOfSalesAmount] > AverageSales,
[SumOfSalesAmount]
))
上面这个代码，我们使用了sumofsalesamount这个度量值，在行上下文环境中，在变量的定义中，我们使用它啦i计算了客户的平均销售额，而在sumx的迭代中，我们使用它来检测当前客户的销售额与之前计算平均值的对比，平均值存储在变量当中。
重点
基于var的写法阅读起来比较简单且容易维护（实际上运行也快一些）。但是，掌握不同语法使用对于的不同行为是十分重要的，包括不适用var变量，因为有的DAX版本不支持变量。如果你没有很好的掌握上下文的自动转换，那么你很有可能需要大量的时间来明白一个函数的意思。
使用度量值的时候会发生上下文的转换，这个是自动默认的，且没有办法去改变它。也就是说，如果要避免上下文的自动转换，唯一的办法就是把代码展开。举个例子，我们把上面的代码改写一下，不使用变量，我们使用一个averagesales度量值来代替average sales。代码如下
[AverageSales] := AVERAGEX ( Customer, [SumOfSalesAmount] )
[SalesMoreThanAverage] :=
SUMX (
Customer,
IF (
[SumOfSalesAmount] > [AverageSales],
[SumOfSalesAmount]
))
我们使用了[averagesales]来计算客户的平均销售额，这里的问题是，我们在迭代函数sumx中使用度量值，这个会使得上下文转换自动发生。因此，[averagesales]的结果不是多有客户的平均值，而是正在迭代中的这个客户的值。所以结果就是，if的函数返回的全部是false，然后返回blank。如果你要避免上下文转换，你需要把度量值的代码展开写，就像下面这个样子：
[SalesMoreThanAverage] :=
SUMX (
Customer,
IF (
[SumOfSalesAmount] > AVERAGEX ( Customer, [SumOfSalesAmount]
),
[SumOfSalesAmount]
))
把度量值的代码展开写以后，salesmorethanaverage返回了正确的结果。另外，还有一个值得提醒的地方是，这里对customer有两个内嵌的行上下文，以及三个度量值。第一个当前的客户销售额，sumx，另外一个averagex迭代的销售额。
后面的章节里面我们会大量使用这种拓展写法，用来解决一些特殊的场景。
网友评论