Value Types

值类型是指当传递这些类型时，传递的是类型的取值。

bool

bool类型的取值位true,false,其用法和主流的语言类似。

int/uint

int 表示256位整形和无符号整形，还可以使用int8，int16...uint256* 表示8位，16位。。。256位整形。

uint8,uint16...uint256类似的使用方法类似。

fixed/ufixed

fixed 和其他语言中的 float,double表示的含义类似，代码中使用方法如下：

 fixedMxN decimal;

其中M表示位宽，必须位8的整数倍，N表示十进制小数部分的位数。

address

address类型位的位宽位20个字节（160 bits)，和区块链上的地址长度一致。 address 类型还包含几个成员可以被访问：

• balance - 获取该地址的余额
• transfer - 向该地址发送ether(以wei位单位）
• send - 和transfer功能类似，区别在于如果发送失败send方法返回false，transfer方法会发生错误
• call/delegatecall/callcode - 这几个函数较为底层，后续章节单独介绍

下面是一个例子：

pragma solidity ^0.4.23;

contract AddressTest {
    
    event Transfered(address to, uint amount);
    event Sent(address to, uint amount, bool successed);

    //Get the ether balance of a certian address
    function getBalanceOf(address _addr) public view returns(uint) {
        return _addr.balance;
    }
    
    //Get the ether balance of this very contract
    function getBalance() public view returns(uint) {
        return address(this).balance;
    }

    //Transfer to a specific address from this contract
    function transferTo(address to, uint amount) public payable {
        to.transfer(amount);
        emit Transfered(to,amount);
    }
    
    //Send to a specific address from this contract
    function sendTo(address to, uint amount) public  payable {
        bool result = to.send(amount);
        emit Sent(to,amount,result);
    }
    
    //Fallback function used to accept ether
    function () payable public {  
    }
}

代码执行结果这里不贴出，有兴趣的同学可以自行通过remix-ide做相应实验。

bytesN

固定长度字节可以使用bytes1, bytes2, bytes3, …, bytes32 分别表示，其中bytes1 可以使用byte代替。

Literals

Address Literals

任何十六进制的字符串，凡是能通过地址合法性检查(address checksum test)，就会被认为是地址，例如：

0xdCad3a6d3569DF655070DEd06cb7A1b2Ccd1D3AF

Rational and Integer Literals

整形字量可以使用十进制整数表示，例如：50，999等，solidity中不支持八进制数据表示。solidity支持十进制小数，例如3.5，99.9都是合法的有理数字面量，科学计数法也同样支持，例如2e10，2e-2,2.5e2也是合法的。

String Literals

String Literals 和多数语言类似，solidity中‘’和“”都可以用于表示String Literals.

Hexadecimal Literals

Solidity 通过hex前缀表示16进制字面量，16进制字面量可以作为字符串使用，例如hex''4142434445"表示“ABCDE”.

下面是一个关于字面量的例子：

pragma solidity ^0.4.23;

contract LiteralTest {
    
    event IntValue(int value);
    event StringValue(string value);

    function testRationalLiteral() public {
        // Next line compiles even the 2**8 - 2**6 - 2**6 is 127 whitch is greater than the biggest positive number of int8 
        int8 x = (2**8 - 2**6 - 2**6 -1); 
        //Next line should get a error since the final result is greater than 127
        //int8 x = (2**8 - 2**6 - 2**6); 
        emit IntValue(x);
    }

    function testHexLiteral() public  {
        //Value of the event is "ABCDE..."
        emit StringValue(hex"414243444546474849");
    }
}

Enum

Enum和java中的Enum类似，可以用于定义取值范围有限的类型。Solidity 中Enum可以和整形显式的相互转换，整形再转换成enum时，编译器/EVM会检查取值范围，如果范围有误则会产生一个错误。 下面是一个例子：

pragma solidity ^0.4.23;

contract EnumTest {
    
    event UintValue(uint value);
    event EnumValue(Status status);
    
    enum Status {ACTIVE,SUSPENDED}
    
    function enumTest() public {
        Status s1 = Status.ACTIVE;
        //0 will be emited
        emit UintValue(uint(s1));
        
        Status s2 = Status(1);
        //1 will be emited
        emit EnumValue(s2);
        
        //Next line will get an compile time error for 2 is out of range
        //Status s2 = Status(2);
        
        uint x = 4 - 4;
        Status s3 = Status(x);
        //0 will be emited
        emit EnumValue(s3);

        // x = 4 - 2;
        //The next line will get an run time error for x is out of range
        // Status s4 = Status(x);
    }  
}

Function Types

函数类型也是值类型的一种，和C语言中的函数指针类似，用于指向一个函数，可以用于实现回掉等功能。函数类型的细节会在后续文章中单独描述。

参考资料

solidity官方文档
参考代码