一、基础

1. True: 字符串True返回True，运算中等于1，所有非0值都为true。
   False:字符串False返回False，元算中等于0，0=False。
2. 使用 & 连接字符串。
3. Today() 、 Now() 分别返回当前日期和当前日期+时间

---

二、基础函数

left right mid len lenb(汉字算2个字符,英文算1个字符) upper lower Proper(每个单词首字母大写，其余小写)、

int(向下取整) round(四舍五入) roundup(向上入) rounddown(向下舍)、
rank(排名)、

randbetween(声明指定区间的随机整数) rand(声明0-1之间的随机小数)、

find(查找某字符串在另一个字符串中的位置)

if(根据真假，决定结果)

---

三、基础函数2

1. row()函数

返回行号，只有一个参数，省略时参数为公式所在单元格，例如
row(a8) 返回8
当参数为数组时，返回也为数组，例如
row(a1:a8) 返回 12345678(数组)

2. column()函数

返回列号，和row()函数类似

3. choose函数

根据索引值返回参数中相应的值，例如CHOOSE(6,"A","B","C","D","E","F","G") 返回F，因为F的index是6.

4. count函数

统计某区域内单元格内容为数字的数量。

5. counta函数

统计非空单元格的数量。

6. offset函数

引用一个单元格或一个连续的区域，该函数有5个参数，
第1个参数为参照单元格，告诉你从哪里开始，
第2个和第3个参数为偏移n行和m列，
第4个和第5个参数为返回的区域的行高和列宽。

例如=OFFSET(A1,4,3,1,1) 返回D5中的数据。
又例如 =OFFSET(A1,3,2,2,3) 返回一个区域，选中一定的区域后，输入函数后 使用 Ctrl+Shift+回车 ，便可以看到返回区域内的值。

7. match函数

返回要查找的值在区域内的位置，而不是其本身。
他有3个参数，
第1个参数是要查找的值，
第2个参数是查找的区域或数据，
第3个参数是查找的方式。 0表示精确匹配，1或者省略表示按升序排列查找，返回 <=查找值的位置 ；-1表示降序排列查找，返回 >=查找值的值。

如果查找区域内有重复的数据，那么匹配的总是第一个出现的位置，

应用：可以用此来计算某个区域内不重复的单元格的个数:
SUM(--(MATCH(E38:E42,E38:E42,0)=ROW(E38:E42)-37))

应用：引用某一行第一个非空单元格 :
=IF(COUNTA(E49:M49)=0,"",INDEX(E49:M49,1,MATCH(0,0/(E49:M49<>""),0)))

8. index函数

有2种参数形式。

第一种有3个参数

第1个参数数据区域或数据，
第2个参数和第3个参数是区域中的行和列。

第二种有4个参数

第1个参数多个数据区域或数据，
第2个和第3个参数是区域中的行和列，
第4个参数是第几个区域。

---

四、基础函数3

1. And函数 Or函数 Small函数 Large函数

Small函数（返回一串数字中的第几小）
Large函数(于Small相反)、

2. LookUp函数

一般是指定查找值、查找区域、结果区域，
注意使 Lookup(1,0/(布尔值),结果值) 的使用方式，
因为其要求查找区域为升序，返回 <=查找值的结果区域值 。

应用：

(1) =LOOKUP(L14,{0,60,70,80;"不及格","及格","良好","优秀"}) 按分数显示级别
(2) 引用某一行最后一个单元格：
=LOOKUP(1,0/(C27:K27<>""),C27:K27)
(3) =LOOKUP(1,0/($C$58:$C$63=$H58),INDEX($B$58:$E$63,,MATCH(I$57,$B$57:$E$57,0))) 匹配值的同时，匹配列头名称。

3. indirect函数

返回文本字符串所指定的引用，这个函数参数必须是单元格地址，结果是返回这个单元格地址里数据 。
应用：制作2级 数据有效性下拉菜单。

4. substitue函数

替换文本，默认为全部替换，可以指定替换第几次出现的问题。

5. text函数

指定格式 格式化文本，
应用：=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(TEXT(F10*100,"[Dbnum2]0百0拾0元0角0分"),"零百",""),"零拾",""),"零元",""),"零角",""),"零分","") 将小写金额转换为大写金额。

---

五、基础函数4：

1. sumif函数

有3个参数，
第1个参数指定区域，
第2个参数指定匹配值，
第3个参数为实际取和区域。

2. counta 、count

counta（统计非空单元格）
count（统计数字单元格）

3. countif

按条件统计单元格

4. HLookup & VLookup

5. isError

检查一个公式的返回值是否有错误。

---

六、数组公式：

说明：

数组公式不能删除一个，要全部选中后才能删除；
修改公式不能退出时，记得按ESC键。

数组分为一维和二维数组；
查看数组结果就按 F9 ；
横向数组中的元素用 逗号, 隔开，纵向数组中的元素用 分号; 隔开。

同时按 Ctrl+Shift+Enter 输入。

row() 函数在数组函数中的应用。

应用1：

从文本里提取数字：
=--MID(D7,MIN(FIND(ROW($A$1:$A$10)-1,D7&5/19,1)),LEN(D7)-(LENB(D7)-LEN(D7))) 数组公式。

应用2：

去重复值：=IF(SUM(1/COUNTIF($C$13:$C$25,$C$13:$C$25))>=ROW(A1),INDEX($C$13:$C$25,SMALL(IF(MATCH($C$13:$C$25,$C$13:$C$25,0)=ROW($C$13:$C$25)-12,ROW($C$13:$C$25)-12,""),ROW(A1))),"")

应用3

查找有重复名字的所有数据：=IF(COUNTIF($A$6:$A$20,$G$6)>=ROW(A1),INDEX($A$6:$D$20,SMALL(IF($A$6:$A$20=$G$6,ROW($A$6:$A$20)-5,2^20),ROW(A1)),COLUMN(B1)),"")

应用4

工资条制作：

---

七、自己翻帮助学习的函数

1. 信息类函数：

1.1 Cell函数：

返回有关单元格格式、位置或内容的信息。
例子：
=CELL("format",E4)

1.2. Error.Type函数：

返回对应错误类型的数字。
例子
=ERROR.TYPE(D3)=ERROR.TYPE(#VALUE!)

1.3. Info函数：

返回有关当前操作环境的信息
例子：
=INFO("DIRECTORY")

注：这类函数Excel2007中会给出函数提示。不用担心参数名称。

1.4. ISBLANK等判断类函数

ISBLANK函数: 判空
ISERR函数：如果值为除 #N/A 以外的任何错误值，则返回 TRUE。
ISERROR函数：如果值为任何错误值，则返回 TRUE
ISEVEN、ISODD函数：是否为偶数、奇数
ISLOGICAL函数：如果值为逻辑值，则返回 TRUE
ISNA函数：如果值为错误值 #N/A，则返回 TRUE
ISNONTEXT、ISTEXT函数：如果值不是文本，则返回 TRUE
ISNUMBER函数：如果值为数字，则返回 TRUE
ISREF函数：如果值为引用值，则返回 TRUE。 例子：ISREF("1") 返回False，ISREF(a1) 返回true，ISREF(11) 返回False
N函数：返回转换为数字的值，例子 N("2")=0, N("2"+"1")=3
NA函数：返回错误值 #N/A
TYPE函数：返回表示值的数据类型的数字 ，例子：=TYPE(J12)=1 （如果J12是数字）

2. 查找和引用函数

2.1. Address函数

以文本形式将引用值返回到工作表的单个单元格，指定 行号和列号和其他一些参数。

2.2. AreaAS函数：

返回引用中包含的区域个数。区域表示连续的单元格区域或某个单元格。例子：
=AREAS((A1:A2,A3:A4))=2
=AREAS(A1:A5)=1

2.3. Choose函数

2.4. Column函数 Columns函数 Row Rows

2.5. GETPIVOTDATA ：返回存储在数据透视表中的数据

2.6. LOOKUP VLOOKUP HLOOKUP

2.7. HYPERLINK函数：创建快捷方式或跳转。=HYPERLINK("www.baidu.com","BAIDU")

2.8. INDEX MATCH INDIRECT OFFSET

2.9. TRANSPOSE函数：数组转置

3. 文本函数：

3.1. ASC函数

将字符串中的全角（双字节）英文字母或片假名更改为半角（单字节）字符。例子 :=ASC("a，b")=a,b

3.2. CHAR函数

返回由代码数字指定的字符

3.3. CLEAN函数

删除文本中所有非打印字符

3.4. CODE函数

返回文本字符串中第一个字符的数字代码。与CHAR相反。

3.5. CONCATENATE函数

将几个文本项合并为一个文本项

3.6. DOLLAR函数

使用 ￥（人民币）货币格式将数字转换为文本

3.7. EXACT函数

检查两个文本值是否相同

3.8. FIND FINDB函数

3.9. FIXED函数

将数字格式设置为具有固定小数位数的文本，例子：=FIXED("39.115",1,1)=39.1

3.10. LEFT

LEFTB LEN LENB LOWER MID MIDB PROPER REPLACE REPLACEB REPT(重复) RIGHT RIGHTB SUBSTITUE T TEXT TRIM UPPER VALUE(将文本转换为数字)