我想获取特定路径下文件的末次修改时间，例如，.sas和.log的末次修改时间，两者比较判断程序更新后，是否重新Run过；例如，Source侧 (Production)的.log文件与QC侧 (Validation)的.log的末次修改时间，判断V侧程序是否在P侧程序之后Run过。
利用Dopen系列以及Fopen系列函数，可以实现上述功能。
为了方便读者更好的理解，我先介绍这两个系列中的一些函数。这篇文章介绍Dopen系列函数，涉及的函数如下：
- DOPEN
- DCLOSE
- DNUM
- DREAD
- DOPTNAME
- DINFO
我使用以下路径文件进行演示，路径中有4个.sas文件、4个.log文件，以及1个文件夹，共9个文件。
Directory
1. DOPEN(fileref)
DOPEN函数的作用是，打开一个路径，并返回一个路径标识值 (Opens a directory, and returns a directory identifier value)。
这可以理解为，在一次SAS会话中，给路径发放身份证明，这个证明与路径是一一对应的，就像人的身份证一样。人有了身份证，可以进行诸如乘高铁、坐飞机的活动；在SAS会话中，路径有了“身份证”，也可以进行一些“特定活动”。
DEOPEN函数的参数值是一个文件引用(fileref)，这个文件引用必须在调用函数前与特定的路径进行关联，常用的文件关联方式有两种：
第1种，全局filename语句：
filename dirpath "E:\99_Test\Test\test1";
第2种，filename函数：
data test;
fileres = filename("dirpath", "E:\99_Test\Test\test1");
run;
如果关联成功，filename函数会返回0；如果关联失败，filename函数会返回非0值。
文件引用关联成功后，就可以使用DOPEN函数打开，函数在该SAS会话中，返回路径对应的“身份证号”。
**dopen;
%let dirpath = E:\99_Test\Test\test1;
data tmp;
fileres = filename("dirpath","&dirpath");
dirid = dopen("dirpath");
run;
Dopen
Filename函数返回0值，说明文件引用关联成功。Dopen函数返回的路径“身份证号”的值为1。
其他信息可以参考SAS文档：SAS Help Center: DOPEN Function。
2. DCLOSE(directory-id)
DCLOSE函数的作用是，关闭DOPEN函数打开的路径(Closes a directory that was opened by the DOPEN function)。
DCLOSE函数的参数为，DOPEN返回的“身份证号”。DCLOSE函数可以类比，注销身份证号。路径的“身份证号”一旦被注销，一些基于“身份证号”的活动就没办法进行。
**dclose;
%let dirpath = E:\99_Test\Test\test1;
data tmp;
fileres = filename("dirpath","&dirpath.");
dirid = dopen("dirpath");
dclose = dclose(dirid);
run;
Dclose
“身份证号”注销成功，返回0值；注销不成功，返回非0值。
其他信息可以参考SAS文档：SAS Help Center: DCLOSE Function
3. DNUM(directory-id)
DNUM函数的作用是，返回路径内文件数量(Returns the number of members in a directory)。
例如，演示路径下有9个文件，DNUM函数对该路径的“身份证号”进行处理，返回值应该是9。
**dnum;
%let dirpath = E:\99_Test\Test\test1;
data tmp;
fileres = filename("dirpath","&dirpath.");
dirid = dopen("dirpath");
num = dnum(dirid);
run;
dnum
其他信息可以参考SAS文档：SAS Help Center: DNUM Function
4. DREAD(directory-id, nval)
DREAD函数的作用是，读取路径下文件的名称(Returns the name of a directory member)。
DREAD函数有2个参数，一个是路径的“身份证号”，一个是路径内文件的位序，文件位序的排序为文件名的字符排序。
演示路径下有9个文件，对应的，也就是可以读取到9个文件的名称。
**dread;
%let dirpath = E:\99_Test\Test\test1;
data tmp;
fileres = filename("dirpath","&dirpath.");
dirid = dopen("dirpath.");
length direct filename filepath $200;
direct = "&dirpath";
ord = 1;
filename =dread(dirid, 1);
filepath = catx("\", direct, filename);
output;
ord = 2;
filename =dread(dirid, 2);
filepath = catx("\", direct, filename);
output;
……
ord = 9;
filename =dread(dirid, 9);
filepath = catx("\", direct, filename);
output;
run;
Dread
一一读取文件比较繁琐，由于DNUM函数可以获取路径内文件数目，基于此可以使用Do循环进行读取文件名称，路径名称与文件名拼接可以获得文件路径。
**dread;
%let dirpath = E:\99_Test\Test\test1;
data tmp;
fileres = filename("dirpath","&dirpath.");
dirid = dopen("dirpath");
num = dnum(dirid);
length direct filename filepath $200;
direct = "&dirpath.";
if dirid > 0 then do;
do i = 1 to num;
filename = dread(driid, i);
filepath = catx("\", direct,filename);
ord = i;
output;
end;
end;
drop i;
run;
循环读入结果与上面相同。
其他信息可以参考SAS文档：SAS Help Center: DREAD Function。
5. DOPTNAME(directory-id, nval)
DOPTNAME函数的作用是，返回路径的属性名称(Returns directory attribute information)。
DOPTNAME函数有2个参数，一个是路径的“身份证号”，一个是路径具体属性的次序。在不同的电脑操作系统中，SAS读取到的属性是不同的。
在Windows操作系统中，路径属性只有1个：
- Directory
在UNIX操作系统中，路径属性有5个：
- Directory
- Owner Name
- Group Name
- Access Permission
- Last Modified
不同的SAS系统语言，返回的结果也不同。以Windows系统为例，举例如下：
**doptname;
%let dirpath = E:\99_Test\Test\test1;
data tmp;
fileres=filename("dirpath","&dirpath.");
dirid=dopen("dirpath");
length info_it $200;
info_it = doptname(dirid, 1); output;
info_it = doptname(dirid, 2); output;
run;
不同的SAS系统语言，返回的属性名称也不同：
中文环境
英文环境
因为Windows系统中，DOPTNAME函数只能返回一个路径属性。当次序值取2时，函数返回值就为空，同时Log中也会输出错误信息描述。
Log
其他信息可以参考SAS文档：SAS Help Center: DOPTNAME Function。
6. DINFO(directory-id, information-item)
DINFO函数的作用是，返回路径属性的具体信息(Returns information about a directory)。
DINFO函数有2个参数，一个是路径的“身份证号”，一个是路径的属性名称，名称因SAS系统语言的不同而不同。属性名称可以参考DOPTNAME函数的返回值。
中文环境：
**dinfo-Chinese;
%let dirpath = E:\99_Test\Test\test1;
data tmp;
fileres=filename("dirpath","&dirpath.");
dirid=dopen("dirpath");
length attr $200;
attr= dinfo(dirid, "目录");
run;
Dinfo-Chinese
英文环境：
**dinfo-English;
%let dirpath = E:\99_Test\Test\test1;
data tmp;
fileres=filename("dirpath","&dirpath.");
dirid=dopen("dirpath");
length attr $200;
attr= dinfo(dirid, "Directory");
run;
Dinfo-English
在Windows环境下，这个函数显得很鸡肋。只能读取一个路径的“路径”信息，有点脱裤子放屁的意味。。。
其他信息可以参考SAS文档：SAS Help Center: DINFO Function。
相关阅读：
SAS编程：如何获取某路径下文件的名称？
SAS编程：Fopen系列函数介绍
感谢阅读， 欢迎关注！
若有疑问，欢迎评论交流！
网友评论