参考的csdn的一些裁剪算法，这套适配性比较广，就先用这个。
效果如下
image.png
代码比较简单，可以从任意轴和方向开始裁剪，其实就是宏定义判断一下顶点的x或者y或者z的值是否小于设定值。
Shader "Unlit/模型裁剪"
{
Properties{
_MainTex("Main Tex", 2D) = "white"{} // 纹理贴图
_Color("Color", Color) = (1,1,1,1) // 控制纹理贴图的颜色
_NormalMap("Normal Map", 2D) = "bump"{} // 表示当该位置没有指定任何法线贴图时，就使用模型顶点自带的法线
_BumpScale("Bump Scale", Float) = 1 // 法线贴图的凹凸参数。为0表示使用模型原来的发现，为1表示使用法线贴图中的值。大于1则凹凸程度更大。
//裁切的范围(根据实际物体大小而定，通过C#赋值)(国际通用为±0.5)
_DiscardFactor("DiscardFactor",Range(-2,2)) = 0.0
//裁剪方向
[KeywordEnum(LeftRight, UpDown, Around)] _Dir("Dir", Float) = 0
//裁剪顺序-正反
[KeywordEnum(JUST, BACK)] _ORDER("ORDER", Float) = 0
}
SubShader{
Pass {
// 只有定义了正确的LightMode才能得到一些Unity的内置光照变量
Tags { "RenderType"="Opaque" "LightMode"="ForwardBase"}
LOD 200
CGPROGRAM
// 包含unity的内置的文件，才可以使用Unity内置的一些变量
#include "Lighting.cginc" // 取得第一个直射光的颜色_LightColor0 第一个直射光的位置_WorldSpaceLightPos0（即方向）
#pragma vertex vert
#pragma fragment frag
//设定宏定义
#pragma multi_compile _DIR_LEFTRIGHT _DIR_UPDOWN _DIR_AROUND
#pragma multi_compile _ORDER_JUST _ORDER_BACK
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST; // 命名是固定的贴图名+后缀"_ST"，4个值前两个xy表示缩放，后两个zw表示偏移
sampler2D _NormalMap;
float4 _NormalMap_ST; // 命名是固定的贴图名+后缀"_ST"，4个值前两个xy表示缩放，后两个zw表示偏移
float _BumpScale;
float _YFactor;
float _DiscardFactor;
struct a2v
{
float4 vertex : POSITION; // 告诉Unity把模型空间下的顶点坐标填充给vertex属性
float3 normal : NORMAL; // 不再使用模型自带的法线。保留该变量是因为切线空间是通过（模型里的）法线和（模型里的）切线确定的。
float4 tangent : TANGENT; // tangent.w用来确定切线空间中坐标轴的方向的。
float4 texcoord : TEXCOORD0;
};
struct v2f
{
float4 uv : TEXCOORD0; // xy存储MainTex的纹理坐标，zw存储NormalMap的纹理坐标
float4 vertex : SV_POSITION; // 声明用来存储顶点在裁剪空间下的坐标
float3 normal : NORMAL;
float3 lightDir : TEXCOORD1; // 切线空间下，平行光的方向
float3 worldPos:TEXCOORD2;
};
// 计算顶点坐标从模型坐标系转换到裁剪面坐标系
v2f vert(a2v v)
{
v2f o;
//顶点坐标转换
// 该步骤用来把一个坐标从模型空间转换到剪裁空间
o.vertex = UnityObjectToClipPos(v.vertex);
//获取法线（把法线方向从模型空间转换到世界空间）。
o.normal = UnityObjectToWorldNormal(v.normal);
//贴图的纹理坐标
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
//法线贴图的纹理坐标
o.uv.zw = v.texcoord.xy * _NormalMap_ST.xy + _NormalMap_ST.zw;
//调用这个宏会得到一个矩阵rotation，该矩阵用来把模型空间下的方向转换为切线空间下
TANGENT_SPACE_ROTATION;
//切线空间下，平行光的方向
o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex));
o.worldPos= mul(unity_ObjectToWorld, v.vertex).xyz;
return o;
}
// 要把所有跟法线方向有关的运算，都放到切线空间下。因为从法线贴图中取得的法线方向是在切线空间下的。
fixed4 frag(v2f i) : SV_Target
{
/**************************法线贴图处理******************************/
//法线方向。从法线贴图中获取。法线贴图的颜色值 --> 法线方向
fixed4 normalColor = tex2D(_NormalMap, i.uv.zw); // 在法线贴图中的颜色值
fixed3 tangentNormal = UnpackNormal(normalColor); // 使用Unity内置的方法，从颜色值得到法线在切线空间的方向
tangentNormal.xy = tangentNormal.xy * _BumpScale; // 控制凹凸程度
tangentNormal = normalize(tangentNormal);
//切线空间下的光照方向归一化
fixed3 lightDir = normalize(i.lightDir);
//兰伯特
fixed3 diffuse = _LightColor0.rgb * _Color.rgb *saturate(dot(tangentNormal, lightDir)) ; // 颜色融合用乘法
/********************************************************/
/**************************灯光照明******************************/
//获取场景光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
/********************************************************/
/**************************贴图颜色******************************/
//纹理坐标对应的纹理图片上的点的颜色
fixed3 texColor = tex2D(_MainTex, i.uv) ;
/**************************裁剪规则******************************/
float factor =0;
#if defined(_DIR_LEFTRIGHT)
factor = i.worldPos.x;
#elif defined(_DIR_UPDOWN)
factor = i.worldPos.y;
#elif defined(_DIR_AROUND)
factor = i.worldPos.z;
#endif
//factor越小，下面保留的就越多
#if defined(_ORDER_JUST)
if (factor<_DiscardFactor)
#elif defined(_ORDER_BACK)
if (factor*-1<_DiscardFactor)
#endif
{
discard;
}
/********************************************************/
//最终颜色叠加
fixed3 color = (diffuse + ambient)*texColor;
return fixed4(color, 1); //色彩叠加后与贴图颜色相乘
}
ENDCG
}
}
FallBack "Diffuse"
}
直接的裁切不太实用，通常会需要增加一个边缘渐变：
image.png
实现上其实就是加一个条，然后实现渐变，颜色叠加上去就行了。
代码如下：
Shader "Unlit/模型裁剪边缘光"
{
Properties{
_MainTex("Main Tex", 2D) = "white"{} // 纹理贴图
_Color("Color", Color) = (1,1,1,1) // 控制纹理贴图的颜色
_NormalMap("Normal Map", 2D) = "bump"{} // 表示当该位置没有指定任何法线贴图时，就使用模型顶点自带的法线
_BumpScale("Bump Scale", Float) = 1 // 法线贴图的凹凸参数。为0表示使用模型原来的发现，为1表示使用法线贴图中的值。大于1则凹凸程度更大。
//裁切的范围(根据实际物体大小而定，通过C#赋值)(国际通用为±0.5)
_DiscardFactor("DiscardFactor",Range(-2,2)) = 0.0
//裁剪方向
[KeywordEnum(LeftRight, UpDown, Around)] _Dir("Dir", Float) = 0
//裁剪顺序-正反
[KeywordEnum(JUST, BACK)] _ORDER("ORDER", Float) = 0
//切口光的颜色
_LightColor("LightColor",Color) = (1,1,1,1)
//光的宽度
_LightWidth("LightWidth",Range(0.0,0.1))=0.05
}
SubShader{
Pass {
// 只有定义了正确的LightMode才能得到一些Unity的内置光照变量
Tags { "RenderType"="Opaque" "LightMode"="ForwardBase"}
LOD 200
CGPROGRAM
// 包含unity的内置的文件，才可以使用Unity内置的一些变量
#include "Lighting.cginc" // 取得第一个直射光的颜色_LightColor0 第一个直射光的位置_WorldSpaceLightPos0（即方向）
#pragma vertex vert
#pragma fragment frag
//设定宏定义
#pragma multi_compile _DIR_LEFTRIGHT _DIR_UPDOWN _DIR_AROUND
#pragma multi_compile _ORDER_JUST _ORDER_BACK
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST; // 命名是固定的贴图名+后缀"_ST"，4个值前两个xy表示缩放，后两个zw表示偏移
sampler2D _NormalMap;
float4 _NormalMap_ST; // 命名是固定的贴图名+后缀"_ST"，4个值前两个xy表示缩放，后两个zw表示偏移
float _BumpScale;
float _YFactor;
float _DiscardFactor;
float4 _LightColor;
float _LightWidth;
struct a2v
{
float4 vertex : POSITION; // 告诉Unity把模型空间下的顶点坐标填充给vertex属性
float3 normal : NORMAL; // 不再使用模型自带的法线。保留该变量是因为切线空间是通过（模型里的）法线和（模型里的）切线确定的。
float4 tangent : TANGENT; // tangent.w用来确定切线空间中坐标轴的方向的。
float4 texcoord : TEXCOORD0;
};
struct v2f
{
float4 uv : TEXCOORD0; // xy存储MainTex的纹理坐标，zw存储NormalMap的纹理坐标
float4 vertex : SV_POSITION; // 声明用来存储顶点在裁剪空间下的坐标
float3 normal : NORMAL;
float3 lightDir : TEXCOORD1; // 切线空间下，平行光的方向
float3 worldPos:TEXCOORD2;
};
// 计算顶点坐标从模型坐标系转换到裁剪面坐标系
v2f vert(a2v v)
{
v2f o;
//顶点坐标转换
// 该步骤用来把一个坐标从模型空间转换到剪裁空间
o.vertex = UnityObjectToClipPos(v.vertex);
//获取法线（把法线方向从模型空间转换到世界空间）。
o.normal = UnityObjectToWorldNormal(v.normal);
//贴图的纹理坐标
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
//法线贴图的纹理坐标
o.uv.zw = v.texcoord.xy * _NormalMap_ST.xy + _NormalMap_ST.zw;
//调用这个宏会得到一个矩阵rotation，该矩阵用来把模型空间下的方向转换为切线空间下
TANGENT_SPACE_ROTATION;
//切线空间下，平行光的方向
o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex));
o.worldPos= mul(unity_ObjectToWorld, v.vertex).xyz;
return o;
}
// 要把所有跟法线方向有关的运算，都放到切线空间下。因为从法线贴图中取得的法线方向是在切线空间下的。
fixed4 frag(v2f i) : SV_Target
{
/**************************法线贴图处理******************************/
//法线方向。从法线贴图中获取。法线贴图的颜色值 --> 法线方向
fixed4 normalColor = tex2D(_NormalMap, i.uv.zw); // 在法线贴图中的颜色值
fixed3 tangentNormal = UnpackNormal(normalColor); // 使用Unity内置的方法，从颜色值得到法线在切线空间的方向
tangentNormal.xy = tangentNormal.xy * _BumpScale; // 控制凹凸程度
tangentNormal = normalize(tangentNormal);
//切线空间下的光照方向归一化
fixed3 lightDir = normalize(i.lightDir);
//兰伯特
fixed3 diffuse = _LightColor0.rgb * _Color.rgb *saturate(dot(tangentNormal, lightDir)) ; // 颜色融合用乘法
/********************************************************/
/**************************灯光照明******************************/
//获取场景光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
/********************************************************/
/**************************贴图颜色******************************/
//纹理坐标对应的纹理图片上的点的颜色
fixed3 texColor = tex2D(_MainTex, i.uv) ;
/**************************裁剪规则******************************/
float factor =0;
#if defined(_DIR_LEFTRIGHT)
factor = i.worldPos.x;
#elif defined(_DIR_UPDOWN)
factor = i.worldPos.y;
#elif defined(_DIR_AROUND)
factor = i.worldPos.z;
#endif
//factor越小，下面保留的就越多
#if defined(_ORDER_JUST)
if (factor<_DiscardFactor)
#elif defined(_ORDER_BACK)
if (factor*-1<_DiscardFactor)
#endif
{
discard;
}
/********************************************************/
//最终颜色叠加
fixed3 color = (diffuse + ambient)*texColor;
/**************************实现描边******************************/
#if defined(_ORDER_JUST)
//factor<_DiscardFactor的部分已经被裁减，剩下的部分在加个边界做切面的描边
if (factor < _DiscardFactor+_LightWidth)
// return _LightColor;//不过渡直接纯色
//从边界逐渐过度
return fixed4((_LightColor*smoothstep(_DiscardFactor+_LightWidth,_DiscardFactor,factor)).xyz+color,1);
#elif defined(_ORDER_BACK)
if (factor*-1< _DiscardFactor+_LightWidth)
return fixed4((_LightColor*(1-smoothstep(_DiscardFactor,_DiscardFactor+_LightWidth,factor*-1))).xyz+color,1);
#endif
/********************************************************/
return fixed4(color, 1); //色彩叠加后与贴图颜色相乘
}
ENDCG
}
}
FallBack "Diffuse"
}
网友评论