Unity Shader 纹理动画-无限滚动的背景

Unity Shader系列文章：Unity Shader目录-初级篇

Unity Shader系列文章：Unity Shader目录-中级篇

效果：

无限滚动的背景

原图：

背景1 背景2

Shader代码：

// 无限滚动的背景
Shader "Custom/ScrollingBackground"
{
    Properties
    {
        _MainTex ("Base Layer", 2D) = "white" { }// 第一张图片
        _DetailTex ("2nd Layer", 2D) = "white" { }// 第二张图片
        _ScrollX ("Base Layer Scroll Speed", Float) = 1.0 // 第一张图片滚动速度
        _Scroll2X ("2nd Layer Scroll Speed", Float) = 1.0 // 第二张图片滚动速度
        _Multiplier ("Layer Multiplier", Float) = 1 // 亮度
    }
    SubShader
    {
        Tags { "RenderType" = "Opaque" "Queue" = "Geometry" }

        pass
        {
            Tags { "LightMode" = "ForwardBase" }

            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            sampler2D _MainTex;
            // _MainTex纹理的缩放和偏移系数
            float4 _MainTex_ST;
            sampler2D _DetailTex;
            // _DetailTex纹理的缩放和偏移系数
            float4 _DetailTex_ST;
            float _ScrollX;
            float _Scroll2X;
            float _Multiplier;

            // 应用传递给顶点着色器的数据
            struct a2v
            {
                float4 vertex: POSITION; // 语义：模型顶点坐标
                float4 texcoord: TEXCOORD0; // 语义：模型第一组纹理坐标
            };

            // 顶点着色器传递给片元着色器的数据
            struct v2f
            {
                float4 pos: SV_POSITION; // 语义：裁剪空间顶点坐标
                float4 uv: TEXCOORD0;
            };

            // 顶点着色器函数
            v2f vert(a2v v)
            {
                v2f o;

                o.pos = UnityObjectToClipPos(v.vertex);

                // 水平方向对纹理坐标进行偏移
                o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex) + frac(float2(_ScrollX, 0.0) * _Time.y);
                o.uv.zw = TRANSFORM_TEX(v.texcoord, _DetailTex) + frac(float2(_Scroll2X, 0.0) * _Time.y);

                return o;
            }

            // 片元着色器函数
            fixed4 frag(v2f i): SV_TARGET
            {
                fixed4 firstLayer = tex2D(_MainTex, i.uv.xy);
                fixed4 secondLayer = tex2D(_DetailTex, i.uv.zw);

                fixed4 color = lerp(firstLayer, secondLayer, secondLayer.a);
                color.rgb *= _Multiplier;

                return color;
            }
            
            ENDCG

        }
    }

    FallBack "VertexLit"
}