内网机器通过代理服务器访问网络

此方法前提是 ，访问网络的A, 和内网机器B 网络互通。

1.找一台可以访问网络的机器A， 下载并安装 WProxy , 百度自行下载
官网下载地址http://www.imfirewall.com/download_trial.htm。
安装完打开配置端口：

无标题.png
2.内网机器B代理地址配置 ：
打开IE 浏览器的 internet 选项 ，配置 代理服务器ip和端口，保存
a.png

此时即可顺利访问互联网了。

自动配置代理方式
由于我的情况是，我用机器A 办公，有时需要远程连接到机器B办公，然而外网机器A 是DHCP动态ip， 所以每次内网机器B都要修改代理服务器ip ， 很麻烦。所以就写了一个自动配置代理服务器的脚本。每次远程到内网B机器需要联网时，就运行一下。脚本如下：

原理是获取远程登录用户的ip地址，修改注册表ie的代理参数。
将下面脚本 保存成 auto_proxy.bat ，以管理员身份运行即可。

::自动获取ip并设置代理上网,获取的ip为远程登录的主机ip,需要管理员权限
@echo off

::判断是否有管理员权限
Rd "%WinDir%\system32\test_permissions" >NUL 2>NUL
Md "%WinDir%\System32\test_permissions" 2>NUL||(Echo 请使用右键管理员身份运行！&&Pause >nul&&Exit)
Rd "%WinDir%\System32\test_permissions" 2>NUL

::此处copy需要管理员权限
copy C:\Windows\System32\winevt\Logs\Security.evtx C:\

::进入到logparser 目录下
cd "C:\Program Files (x86)\Log Parser 2.2"

set sql="SELECT top 1 strings,timewritten FROM C:\Security.evtx where eventid=4648 order by timewritten desc"

echo "获取ipv4..."

for /F "eol= tokens=13 delims=|" %%i in ('Logparser –i:EVT –o:csv %sql%') do ( set ip=%%i)

echo "成功ipv4->"%ip%

echo 开始设置IE代理上网 %ip% 
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 1 /f 
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /d "http=%ip%:808;https=%ip%:808" /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyOverride /t REG_SZ /d "<local>" /f
echo 代理设置完成按任意键关闭 
pause>nul
start www.baidu.com

del C:\Security.evtx

再贴一个每次手动输入ip 的脚本，如下：

@echo off
echo 代理地址, ip地址后两位：
set /p a=
set ip=192.168.%a%
echo 开始设置IE代理上网 %ip% 
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 1 /f 
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /d "http=%ip%:808;https=%ip%:808" /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyOverride /t REG_SZ /d "<local>" /f
echo 代理设置完成按任意键关闭 
pause>nul
start www.baidu.com