Arduino制作简易音乐节拍器(三) 消除BPM抖动

今天来解决上一篇文章末尾留下的新需求。

1. 目前节拍器不能表现出节奏型，比如当前的拍子是3拍的还是4拍的？如何切换节奏型？
2. 每小节第一拍的声音要有所区别。
3. 节拍器没有开始和停止功能。
4. BPM的值会因为电位器而抖动，即便没有拧动电位器。

---

首先在之前的电路上加一个按钮开关。下面电路中元件的位置仅供参考，接线保持一致即可。
开关左边引脚要接一个10K到地的下拉电阻，因为当按钮没有按下时候，Arduino的2号引脚就是悬空状态了，取值不是0，而是1和0来回随机乱跳，加入下拉电阻后，2号引脚默认取值是0（因为接地了么，电压是0）.按钮按下后，2号引脚和5V供电连接，取值为1.

接着来解决BPM数字抖动的问题

BPM数字之所以会偶尔轻微抖动，是因为电位器是模拟器件，本身机械结构和外在影响会让它在转换电压为数字的时候会有些许误差和抖动。

解决这个问题其实直接把电位器替换成一个EC11封装的旋转编码器即可，它们外观和操作上是一样的。
编码器要更加精准，不会出现抖动的情况。不过用它的话编程上的难度要增加，不适合萌新。

还有一个消除抖动的方法就是外接一个位数更高的AD转换模块，比如ADS1115(16位)。这样从电位器取值的精度更高。

本文不打算用相对复杂的编码器，也不想增加外设模块，所以我打算用更简单的方法来实现。

修正思路：增加一个按钮，当按钮按下不松开的时候，旋转电位器来改变BPM。松开按钮，代码中的BPM值不再跟着电位器变化，以此达到锁定BPM数值，不再抖动。代码如下：

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#include <SCoop.h>

//define---------------------------------------------------

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 32 // OLED display height, in pixels  
#define OLED_RESET     4 // Reset pin # (or -1 if sharing Arduino reset pin)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

#define BPM_MIN 20
#define BPM_MAX 240
#define PIN_BPM A0
#define PIN_BEEP 9
#define PIN_BTN1 2 //ver1.3 增加按钮状态监听引脚
 

//end define---------------------------------------------------


//---------------------------------------------------
 
int bpm = 0;
char strBPM[3];

int isInit_OLED = 1;    //ver1.3 OLED的内容是否是第一次运行
int isBTN1_Pressed = 0; //ver1.3 按钮是否被按下（不松手）
 

defineTask(Task1);//定义线程1 OLED显示
defineTask(Task2);//定义线程2 节拍器发音
defineTask(Task3);////ver1.3 定义线程3 监测按钮状态


//Task1线程自己的的setup和loop
void Task1::setup()
{   
}

void Task1::loop()
{  
  if(isInit_OLED==1 || isBTN1_Pressed==1) //如果按钮被按下的时候执行
  {
    isInit_OLED = 0; //这个变量其实就用一次作废，因为代码第一次执行的时候没有按下按钮，它仍然要显示BPM。
    
    bpm = map(analogRead(A0), 0, 1023, BPM_MIN, BPM_MAX);
  
    itoa(bpm, strBPM, 10); //把数字转成字符串
   
    display.clearDisplay();
    display.setTextColor(SSD1306_WHITE);
   
    display.setTextSize(2);    
    display.setCursor(0, 10); //显示的坐标位置
    display.println(F("BPM: "));
   
    display.setTextSize(3); 
    display.setCursor(60, 10); //显示的坐标位置
    display.println(strBPM);
    display.display();      // Show text
  
    //稍作停顿，按理说这里不用停顿
    //不过好像是这款OLED驱动代码的问题
    //不停顿会有异常，下次换块OLED试试看
    sleep(100);    
  }
  
}


//Task2线程自己的的setup和loop
void Task2::setup()
{ 
}
void Task2::loop()
{
  //BPM即每分钟有多少拍，那么一分钟(60000毫秒)除以BPM就是每拍的时间
  //再除以4，就是四分之一拍的时间长度
  float tick = 60000 / bpm /4;  
    
  tone(PIN_BEEP, 440);  //播放440Hz的声音        
  sleep(tick);          //播放时为四分之一拍
    
  noTone(PIN_BEEP); //停止播放声音
  sleep(tick*3);    //空四分之三拍的时间
}


//v1.3 不停的监测按钮状态
void Task3::setup()
{ 
}
void Task3::loop()
{
  isBTN1_Pressed = digitalRead(PIN_BTN1); 
}

//---------------------------------------------------



void setup() {
  Serial.begin(9600);

  // SSD1306_SWITCHCAPVCC = generate display voltage from 3.3V internally
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { // Address 0x3C for 128x32
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  } 
  // Clear the buffer 这里如果不清理buffer，默认的显示内容为Adafruit类库的LOGO
  display.clearDisplay();
  
  pinMode(PIN_BPM, INPUT);
  pinMode(PIN_BEEP, OUTPUT);
  pinMode(PIN_BTN1, INPUT); //ver1.3

  delay(1000);
  
  mySCoop.start();
}

void loop() {

  //这里什么都不写，不然影响节拍准确度  
  yield();  

} 

---