光照模型中法线纹理的使用

其实就是让法线纹理中的法线替代了原模型的顶点法线

切线空间中计算

将世界空间转换到切线空间
其实一直有一个疑问，就是既然是法线纹理了，必定至少需要（r,g,b）三个值，为什么还需要在另算Z方向上的值，为什么不直接存储呢？难道是值少了一个值，是为了做压缩？
再回来看的时候发现确实只需要存XY，因为Z的方向是固定的，最后可以通过X,Y,算出来，(X,Y,Z)是单位向量

Shader "Unlit/NormalMapping_WorldToTangent"
{
    Properties
    {
        _Color("Color",Color)=(1.0,1.0,1.0,1.0)
        _MainTex("Main Tex",2D)="white"{}
        _BumpTex("Bump Tex",2D)="Bump"{}
        _Specular("Specular",Color)=(1.0,1.0,1.0,1.0)
        _Gloss("Gloss",Range(30.0,100.0))=30.0
        _BumpScale("Bump Scale",float)=1.0
    }

    SubShader
    {
        Pass
        {
            Tags{"LightModel"="ForwardBase"}
            CGPROGRAM
            #include "Lighting.cginc"
            #include "UnityCG.cginc"

            #pragma vertex vert
            #pragma fragment frag

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _BumpTex;
            float4 _BumpTex_ST;
            fixed4 _Specular;
            float _Gloss;
            float _BumpScale;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
                float4 tangent:TANGENT;
                float4 texcoord:TEXCOORD0;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float3 tangentViewDir:TEXCOORD0;
                float3 tangentLightDir:TEXCOORD1;
                float4 uv:TEXCOORD2;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);

                o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
                o.uv.zw = v.texcoord.xy * _BumpTex_ST.xy + _BumpTex_ST.zw;

                float3 worldNormal = UnityObjectToWorldNormal(v.normal);
                float3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
                float3 binormal = cross(worldNormal,worldTangent) * v.tangent.w;

                float3x3 rotation = float3x3(worldTangent,binormal,worldNormal);

                o.tangentLightDir = mul(rotation,WorldSpaceLightDir(v.vertex));
                o.tangentViewDir = mul(rotation,WorldSpaceViewDir(v.vertex));

                return o;
            }

            fixed4 frag(v2f i):SV_TARGET
            {
                float3 tangentViewDir = normalize(i.tangentViewDir);
                float3 tangentLightDir = normalize(i.tangentLightDir);

                ///采样法线纹理
                fixed4 packedNormal = tex2D(_BumpTex,i.uv.zw);
                float3 tangentNormal = UnpackNormal(packedNormal);
                tangentNormal.xy *= _BumpScale;
                tangentNormal.z = sqrt(1-saturate(dot(tangentNormal.xy,tangentNormal.xy)));

                fixed3 albedo = tex2D(_MainTex,i.uv.xy).rgb * _Color.rgb;

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

                fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(tangentNormal,tangentLightDir));

                fixed3 halfNormal = normalize(tangentLightDir+tangentViewDir);
                fixed3 specular = _LightColor0.rgb * _Specular * pow(saturate(dot(tangentNormal,halfNormal)),_Gloss);

                return fixed4(ambient+diffuse+specular,1.0);
            }

            ENDCG
        }
    }

    Fallback "Specular"
}