222：为变量重新定义长度；顺便讲讲proc sql中的alte

在国家药监局药审中心2020年发布的《药物临床试验数据递交指导原则（试行）》这份文件中，其中 临床试验数据相关资料的格式 这部分里面有这样一个要求：

每个字符型变量的长度，应该设置为在此研究所有数据集里该变量的最大实际变量值长度，有效控制文件的大小。

image.png

也就是说，我们在创建SPEC的过程中，可能会为变量提前设定好长度，但是在递交的过程中，需要用变量实际的长度进行递交。

所以今天展示一下如何重新为变量设定长度。

proc datasets library = work memtype = data kill nolist;   
run;    
quit;

data template;
  length make $30 model $80 type  $200; 
  make="";
  model="";
  type=""; 
run;

data test;
  set sashelp.cars;
run;

data lengthtest;
  make="今天是一个好日子";output;
  make="SAS Pro length test";output;
  
  model="2574万元奖金今天领了";output;
  type="这仅仅只是一个测试，测试长度的测试，看下实际长度是多少";output;
  DriveTrain="my length is 15";output;


run;

data lengthtest2; 
  set template lengthtest; 
run;


%macro adjlen (dsn=,exc=,dsout=);
 
  proc contents data=&dsn out= tempcont(keep=name length type where=(TYPE eq 2 and NAME not in (&exc)))  noprint;
  run;

  proc sql noprint;
    select 'max (length('||compress(name)||')) as '||compress(name) into: var separated by ', ' from tempcont;
  quit;
  %put &var;

  proc sql noprint; 
    create table max_count as select &var from &dsn; 
  quit; 

  proc transpose data= max_count out= tp;
  run;

  proc sql noprint;
    select compress(_name_)||' character ('||strip(put(col1,best.))||')' into: variable separated by ', ' from tp; 
    alter table &dsn modify &variable;
  quit;
  %put &variable;

  data &dsout;
    set  &dsn;
  run;

/*  proc datasets lib=work memtype=data nolist; delete tempcont chk max_count tp ;*/
/*  quit;*/
%mend;
%adjlen(dsn=lengthtest2,exc=%str("DriveTrain"),dsout=lengthout);

逻辑就是

先通过proc contents获取目标数据集的变量
然后通过proc sql获取每个变量的实际长度，并转换成宏变量
最后通过proc sql的alter和modify语句重新为变量赋值长度。

上面的程序自己看吧，这里顺便讲讲proc sql的alter语句

Syntax:

Adds columns to, drops columns from, and changes column attributes in an existing table. Adds, modifies, and drops integrity constraints from an existing table.

①：增加新变量

data test;
  length subjid $20. x $8 y 8;
  subjid="S001";x="ABC";y=100;output;
  subjid="S002";x="XYZ";y=50;output;
  label x="字母" y="数字";
run;

proc sql;
  alter table test add newvar character,paramn integer,mhstdtc date ;
quit;

image.png

newvar /paramn /mhstdtc 是新变量，后面跟着的是 这个变量是什么类型的，字符型还是数值型。用alter语句生成新变量，变量的值初始时都是空，如果我们要为变量赋值，只能通过proc sql的update语句。
②：update语句赋值

proc sql;
  alter table test add newvar character,paramn integer,mhstdtc date ;
quit;

proc sql;
  update  test set newvar="SAS PRO" ,paramn=7,mhstdtc=23147 ;  /*会对整个变量都填充值，不需要重新创建新的数据集就能查看内容*/
quit;

proc sql;
  update  test set newvar="SAS PRO" ,paramn=7,mhstdtc=23147 where subjid="S001";  /*对指定行添加值；这样需要重新创建一个数据集，需要注意的是添加日期型变量的时候只能是数字*/
quit;

data test2;
  set test;
run;

image.png

③：alter删除变量

proc sql;
  alter table test2 drop newvar  ;
quit;

④：改变变量属性，比如长度或者标签，需要通过alter和modify语句实现，注意的是对数值型变量无效。

proc sql;
  alter table test modify subjid char(4) label="受试者",x char(3)  ;
quit;

image.png