alloc实现流程
每次创建对象的时候都会写 [[xx alloc] init] ，但是 alloc 和 init 都具体做了什么呢？通过查看和跟踪源码，了解了 alloc 的底层实现流程是什么样的。梳理了一下 alloc 实现大概流程是什么样。
alloc流程图
从流程图中能看出来 alloc 都做了那些内容:
- cls->instanceSize(extraBytes) : 计算该类内存所占大小
- calloc(1, size) : 开辟内存，返回地址指针
- obj->initInstanceIsa(cls, hasCxxDtor) : 地址指针绑定到相应的类(isa)
现把部分源码实现摘录出来
+ (id)alloc {
return _objc_rootAlloc(self);
}
// Base class implementation of +alloc. cls is not nil.
// Calls [cls allocWithZone:nil].
id _objc_rootAlloc(Class cls) {
return callAlloc(cls, false/*checkNil*/, true/*allocWithZone*/);
}
// Call [cls alloc] or [cls allocWithZone:nil], with appropriate
// shortcutting optimizations.
static ALWAYS_INLINE id
callAlloc(Class cls, bool checkNil, bool allocWithZone=false) {
#if __OBJC2__
if (slowpath(checkNil && !cls)) return nil;
if (fastpath(!cls->ISA()->hasCustomAWZ())) {
return _objc_rootAllocWithZone(cls, nil);
}
#endif
// No shortcuts available.
if (allocWithZone) {
return ((id(*)(id, SEL, struct _NSZone *))objc_msgSend)(cls, @selector(allocWithZone:), nil);
}
return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc));
}
id
_objc_rootAllocWithZone(Class cls, malloc_zone_t *zone __unused) {
// allocWithZone under __OBJC2__ ignores the zone parameter
return _class_createInstanceFromZone(cls, 0, nil,
OBJECT_CONSTRUCT_CALL_BADALLOC);
}
/***********************************************************************
* class_createInstance
* fixme
* Locking: none
*
* Note: this function has been carefully written so that the fastpath
* takes no branch.
**********************************************************************/
static ALWAYS_INLINE id
_class_createInstanceFromZone(Class cls, size_t extraBytes, void *zone,
int construct_flags = OBJECT_CONSTRUCT_NONE,
bool cxxConstruct = true,
size_t *outAllocatedSize = nil)
{
ASSERT(cls->isRealized());
// Read class's info bits all at once for performance
bool hasCxxCtor = cxxConstruct && cls->hasCxxCtor();
bool hasCxxDtor = cls->hasCxxDtor();
bool fast = cls->canAllocNonpointer();
size_t size;
// 计算类所在内存大小 size 等于16字节(在没有属性的情况下)
size = cls->instanceSize(extraBytes);
if (outAllocatedSize) *outAllocatedSize = size;
id obj;
if (zone) {
// 最初内存是根据 zone 开辟的 (大略在iOS8之前) MRC
obj = (id)malloc_zone_calloc((malloc_zone_t *)zone, 1, size);
} else {
// 这就是 alloc 开辟内存的地方，返回地址指针，这个阶段只是一个指针
// void *calloc(size_t __count, size_t __size)
// count: 开辟个数 size：每个大小
obj = (id)calloc(1, size);
}
if (slowpath(!obj)) {
if (construct_flags & OBJECT_CONSTRUCT_CALL_BADALLOC) {
return _objc_callBadAllocHandler(cls);
}
return nil;
}
if (!zone && fast) {
// 地址指针绑定到类上 - isa
obj->initInstanceIsa(cls, hasCxxDtor);
} else {
// Use raw pointer isa on the assumption that they might be
// doing something weird with the zone or RR.
obj->initIsa(cls);
}
if (fastpath(!hasCxxCtor)) {
return obj;
}
construct_flags |= OBJECT_CONSTRUCT_FREE_ONFAILURE;
return object_cxxConstructFromClass(obj, cls, construct_flags);
}
相关方法的含义在源码中也有注释，层层剥离开以后，就要看看 cls->instanceSize(extraBytes) 是如何计算内存的
1.内存是如何计算的
#define FAST_CACHE_ALLOC_MASK 0x1ff8
#define FAST_CACHE_ALLOC_DELTA16 0x0008
size_t fastInstanceSize(size_t extra) const
{
// extra = 0
ASSERT(hasFastInstanceSize(extra));
if (__builtin_constant_p(extra) && extra == 0) {
return _flags & FAST_CACHE_ALLOC_MASK16;
} else {
// flags 标识位 isa 指针是否优化 size = 16
size_t size = _flags & FAST_CACHE_ALLOC_MASK;
// remove the FAST_CACHE_ALLOC_DELTA16 that was added
// by setFastInstanceSize
// size + extra - FAST_CACHE_ALLOC_DELTA16 = 16 - 0 - 8 = 8
return align16(size + extra - FAST_CACHE_ALLOC_DELTA16);
}
}
- FAST_CACHE_ALLOC_MASK 和 FAST_CACHE_ALLOC_DELTA16 是掩码
- _flags 可以理解成标识位， isa 指针是否优化过
经过 & 运算以后 ，size 等于16字节，经过计算传入 函数 align16 参数是 8 字节 ，再看看方法 align16 做了什么
static inline size_t align16(size_t x) {
// 16字节对齐
return (x + size_t(15)) & ~size_t(15);
}
实现了一种16字节对齐的算法方式
16字节对齐.png
为什么要16字节对齐呢？早期苹果是8字节对齐，现在改成16字节对齐，首先 isa指针 占用8字节，要是以8字节对齐的方式，那么下面就会是其他类的 isa指针，假如出现了内存访问异常，就会出现类似 野指针 或是 僵尸对象 的问题。16字节对齐可以相对避免类似的问题，系统为类开辟内存空间大了，预留空间大了，自然这些异常也会减少。
系统查找或访问内存是以块的方式，加快访问速度。
8字节读取.png
16字节读取.png
总结一下：
- 对象占用大小 -> 8字节对齐
- 系统分配内存大小 -> 16字节对齐
2.地址指针是如何绑定到类的
之前 objc 为 nil ，开辟完内存就会返回地址指针
这个地址指针就是类 isa 指针
if (!zone && fast) {
obj->initInstanceIsa(cls, hasCxxDtor);
} else {
// Use raw pointer isa on the assumption that they might be
// doing something weird with the zone or RR.
obj->initIsa(cls);
}
inline void
objc_object::initInstanceIsa(Class cls, bool hasCxxDtor)
{
ASSERT(!cls->instancesRequireRawIsa());
ASSERT(hasCxxDtor == cls->hasCxxDtor());
initIsa(cls, true, hasCxxDtor);
}
inline void
objc_object::initIsa(Class cls, bool nonpointer, bool hasCxxDtor)
{
ASSERT(!isTaggedPointer());
if (!nonpointer) {
isa = isa_t((uintptr_t)cls);
} else {
ASSERT(!DisableNonpointerIsa);
ASSERT(!cls->instancesRequireRawIsa());
isa_t newisa(0);
#if SUPPORT_INDEXED_ISA
ASSERT(cls->classArrayIndex() > 0);
newisa.bits = ISA_INDEX_MAGIC_VALUE;
// isa.magic is part of ISA_MAGIC_VALUE
// isa.nonpointer is part of ISA_MAGIC_VALUE
newisa.has_cxx_dtor = hasCxxDtor;
newisa.indexcls = (uintptr_t)cls->classArrayIndex();
#else
newisa.bits = ISA_MAGIC_VALUE;
// isa.magic is part of ISA_MAGIC_VALUE
// isa.nonpointer is part of ISA_MAGIC_VALUE
newisa.has_cxx_dtor = hasCxxDtor;
newisa.shiftcls = (uintptr_t)cls >> 3;
#endif
// This write must be performed in a single store in some cases
// (for example when realizing a class because other threads
// may simultaneously try to use the class).
// fixme use atomics here to guarantee single-store and to
// guarantee memory order w.r.t. the class index table
// ...but not too atomic because we don't want to hurt instantiation
isa = newisa;
}
}
可以看到内部 isa 初始化操作，返回 isa 。
init 又做了什么呢？
- (id)init {
return _objc_rootInit(self);
}
id
_objc_rootInit(id obj)
{
// In practice, it will be hard to rely on this function.
// Many classes do not properly chain -init calls.
return obj;
}
这波操作很666，直接返回 self 。交给子类自己去重写 init 方法。可以看出：
- 工厂设计模式的应用体现
- OC语言特性之一，多态特性
new 是不是 alloc 和 init 的一个综合体呢？
+ (id)new {
return [callAlloc(self, false/*checkNil*/) init];
}
果不其然呀，callAlloc 是 alloc 底层方法，init 就是返回自己。
以上就是对 alloc 和 init 的源码理解。
网友评论