Shader学习——描边外拓（物体空间外拓，视角空间外拓，裁剪空

核心

新建Pass对物体的顶点进行偏移上色

Shader "Unlit/019"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _Diffuse ("漫反射", Color) = (1,1,1,1)
        _Outline ("外廓粗细", Range(0,0.05)) = 0.02
        _OutlineColor ("外廓颜色", Color) = (0,0,0,0)
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            //定义Pass名，用于重复使用该Pass
            Name "Outline"
            //渲染前面
            Cull Front
            
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            float _Outline;
            fixed4 _OutlineColor;

            struct v2f
            {
                float4 vertex :SV_POSITION;
            };

            v2f vert(appdata_base v)
            {
                v2f o;
                //描边=顶点在法线上偏移 * 颜色
                
                //物体空间法线外拓
                //v.vertex.xyz += v.normal * _Outline;
                //o.vertex = UnityObjectToClipPos(v.vertex);

                //视角空间法线外拓
                //float4 pos = mul(UNITY_MATRIX_V,mul(unity_ObjectToWorld,v.vertex));
                //float3 normal = normalize (mul((float3x3)UNITY_MATRIX_IT_MV,v.normal));
                //pos = pos + float4(normal,0) * _Outline;
                //o.vertex = mul(UNITY_MATRIX_P,pos);

                //裁剪空间法线外拓
                o.vertex = UnityObjectToClipPos(v.vertex);
                float3 normal = normalize (mul((float3x3)UNITY_MATRIX_IT_MV,v.normal));
                float2 viewNoraml = TransformViewToProjection(normal.xy);
                o.vertex.xy += viewNoraml * _Outline;

                return o;
            }

            float4 frag(v2f i):SV_Target
            {
                return _OutlineColor;
            }

            ENDCG
        }

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
        //引入光照
        #include "Lighting.cginc" 
             
            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
                fixed3 worldNormal : TEXCOORD1;
                float3 worldPos : TEXCOORD2;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
        float4 _Diffuse;

            v2f vert (appdata_base v)
            {
                v2f o;
                //顶点位置
                o.vertex = UnityObjectToClipPos(v.vertex);
                //法线方向
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                //世界坐标
                o.worldPos = mul(unity_ObjectToWorld,v.vertex);
                //纹理坐标缩放偏移
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
              
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // 纹理采样
                fixed4 albedo = tex2D(_MainTex, i.uv);

                //光源方向
                fixed3 worldLightDir = UnityWorldSpaceLightDir (i.worldPos);

                //漫反射光=入射光线强度*纹素值*材质的漫反射系数* 映射值为正数(表面法线方向 · 光源方向)
                fixed3 diffuse = _LightColor0.rgb * albedo * _Diffuse.rgb * (dot(worldLightDir,i.worldNormal)*0.5+0.5);

                //环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                fixed3 color = ambient + diffuse;
                return fixed4(color,1);
            }
            ENDCG
        }
    }
}