七、objc_msgSend快速流程分析

在上一章节的cache_t::insert,分析了写入流程,这一章节我们来进行分析objc_msgSend看看它的读取流程.
在探究之前,我们先了解什么是Runtime

Runtime

runtime和编译时:

• 运行时是代码跑起来,被装载到内存中的过程,如果此时出错,程序会崩溃,是一个动态阶段
• 编译时是源代码翻译成机器能识别的代码的过程,主要对余温进行最基本的检查报错,即语法分析、语法分析等,是一个静态的阶段

Objective 分为 Objective-C 1.0,使用的是Legacy;Objective-C 2.0,使用的是Modern

runtime 交互三种方式

runtime三种调用方法.png

• Objective-C Code 直接调用方法、@selector()
• Framework&Serivce 使用的NSSelectorFromString()、isKindeofClass、isMemberOfClass等方法
• runtime API sel_registerName、class_getInstanceSize等底层方法。

探究方法的本质

准备环境

int main(int argc, const char * argv[]) {
    @autoreleasepool {
        LGPerson *person = [LGPerson alloc];
        [person sayNB];
        [person sayHello];
    }
    return 0;
}

将 main.m 编译成 main.cpp
clang -rewrite-objc main.m -o main.cpp

int main(int argc, const char * argv[]) {
    /* @autoreleasepool */ { __AtAutoreleasePool __autoreleasepool; 
        LGPerson *person = ((LGPerson *(*)(id, SEL))(void *)objc_msgSend)((id)objc_getClass("LGPerson"), sel_registerName("alloc"));
        ((void (*)(id, SEL))(void *)objc_msgSend)((id)person, sel_registerName("sayNB"));
        ((void (*)(id, SEL))(void *)objc_msgSend)((id)person, sel_registerName("sayHello"));
    }
    return 0;
}

为了验证,通过objc_msgSend方法来完成[person sayNB]的调用，查看其打印是否是一致

注：
1、直接调用objc_msgSend，需要导入头文件#import <objc/message.h>
2、需要将target --> Build Setting -->搜索msg -- 将enable strict checking of obc_msgSend calls由YES 改为NO，将严厉的检查机制关掉，否则objc_msgSend的参数会报错

打印结果一致,所以[person sayNB]等价于objc_msgSend(person,sel_registerName("sayNB"))

我们也可以调用父类的方法查看

@interface LGTeacher : NSObject
- (void)sayHello;
@end

@implementation LGTeacher
- (void)sayHello{
    NSLog(@"666");
}
@end

@interface LGPerson : LGTeacher
- (void)sayHello;
- (void)sayNB;
@end

@implementation LGPerson
- (void)sayNB{
    NSLog(@"666");
}
@end

我们在main调用父类的sayHello

 LGPerson *person = [LGPerson alloc];
 [person sayHello];

 struct objc_super lgsuper;
 lgsuper.receiver = person; //消息的接收者还是person
 lgsuper.super_class = [LGTeacher class]; //告诉父类是谁
            
 //消息的接受者还是自己 - 父类 - 请你直接找我的父亲
 objc_msgSendSuper(&lgsuper, sel_registerName("sayHello"));

objc_msgSendSuper方法中有两个参数（结构体，sel），其结构体类型是objc_super定义的结构体对象，且需要指定receiver 和 super_class两个属性
发现不论是[person sayHello]还是objc_msgSendSuper都执行的是父类中sayHello的实现，所以这里，我们可以作一个猜测：方法调用，首先是在类中查找，如果类中没有找到，会到类的父类中查找。

objc_msgSend快速查找流程分析

在objc4-781源码中，搜索objc_msgSend，由于我们日常开发的都是架构是arm64，所以需要在arm64.s后缀的文件中查找objc_msgSend源码实现，发现是汇编实现，其汇编整体执行的流程图如下

objc_msgSend查找流程.png

objc_msgSend汇编源码

为了方便查看,我们简单看下汇编的常用指令

汇编指令.png

objc_msgSend是消息发送的源码的入口，其使用汇编实现的，_objc_msgSend源码实现如下

// 消息发送 --汇编入口--objc_msgSend主要是拿到接受者的isa信息
    ENTRY _objc_msgSend
// 无窗口
    UNWIND _objc_msgSend, NoFrame
//--- p0 和空对比,即判断接受者是否存在,其中p0是objc_msgSend的第一个参数-消息接收者receiver
    cmp p0, #0          // nil check and tagged pointer check

#if SUPPORT_TAGGED_POINTERS
//--- le小于 --支持taggedpointer(小对象类型的流程)
    b.le    LNilOrTagged        //  (MSB tagged pointer looks negative)
#else
//--- p0 等于0 时,直接返回空
    b.eq    LReturnZero
#endif
//--- p0即receiver 肯定存在的流程
//--- 根据对象拿出isa,即从x0寄存器指向的地址去除isa,存入 p13寄存器
    ldr p13, [x0]       // p13 = isa
//--- 在64位架构下通过p16 = isa(p13) & ISA_MASK, 拿出shiftcls信息，得到class信息
    GetClassFromIsa_p16 p13     // p16 = class
LGetIsaDone:
    // calls imp or objc_msgSend_uncached
//--- 如果有isa,走到CacheLookup 即缓存查找流程,也就是所谓的sel-imp快速查找流程
    CacheLookup NORMAL, _objc_msgSend

#if SUPPORT_TAGGED_POINTERS
LNilOrTagged:
//--- 等于0,返回空
    b.eq    LReturnZero     // nil check

    // tagged
    adrp    x10, _objc_debug_taggedpointer_classes@PAGE
    add x10, x10, _objc_debug_taggedpointer_classes@PAGEOFF
    ubfx    x11, x0, #60, #4
    ldr x16, [x10, x11, LSL #3]
    adrp    x10, _OBJC_CLASS_$___NSUnrecognizedTaggedPointer@PAGE
    add x10, x10, _OBJC_CLASS_$___NSUnrecognizedTaggedPointer@PAGEOFF
    cmp x10, x16
    b.ne    LGetIsaDone

    // ext tagged
    adrp    x10, _objc_debug_taggedpointer_ext_classes@PAGE
    add x10, x10, _objc_debug_taggedpointer_ext_classes@PAGEOFF
    ubfx    x11, x0, #52, #8
    ldr x16, [x10, x11, LSL #3]
    b   LGetIsaDone
// SUPPORT_TAGGED_POINTERS
#endif

LReturnZero:
    // x0 is already zero
    mov x1, #0
    movi    d0, #0
    movi    d1, #0
    movi    d2, #0
    movi    d3, #0
    ret

    END_ENTRY _objc_msgSend

**[第一步] **判断objc_msgSend第一个参数receiver是否为空

• 如果支持tagged pointer，跳转至LNilOrTagged，
  • 如果小对象为空，则直接返回空，即LReturnZero
  • 如果小对象不为空，则处理小对象的isa，走到【第二步】
• 如果即不是小对象，receiver也不为空，有以下两步
  • 从receiver中取出isa存入p13寄存器，
  • 通过 GetClassFromIsa_p16中，arm64架构下通过 isa & ISA_MASK 获取shiftcls位域的类信息，即class，GetClassFromIsa_p16的汇编实现如下，然后走到【第二步】

.macro GetClassFromIsa_p16 /* src */
//--- 此处用于watchOS
#if SUPPORT_INDEXED_ISA
    // Indexed isa
//--- 将isa的值存入p16寄存器中
    mov p16, $0         // optimistically set dst = src
//--- 判断是否是non-pointer isa
    tbz p16, #ISA_INDEX_IS_NPI_BIT, 1f  // done if not non-pointer isa
    // isa in p16 is indexed
//--- 将_objc_indexed_classes所在页的基址 读入x10寄存器
    adrp    x10, _objc_indexed_classes@PAGE
//--- x10 = x10 + _objc_indexed_classes(page中的偏移量) --x10基址 根据 偏移量 进行 内存偏移
    add x10, x10, _objc_indexed_classes@PAGEOFF
//---- 从p16的第ISA_INDEX_SHIFT位开始，提取 ISA_INDEX_BITS 位 到 p16寄存器，剩余的高位用0补充
    ubfx    p16, p16, #ISA_INDEX_SHIFT, #ISA_INDEX_BITS  // extract index
    ldr p16, [x10, p16, UXTP #PTRSHIFT] // load class from array
1:
//--用户64位系统
#elif __LP64__
    // 64-bit packed isa
    and p16, $0, #ISA_MASK

#else
    // 32-bit raw isa -- 用于32位系统
    mov p16, $0

#endif

.endmacro

[第二步] 获取isa完毕,进入缓存查找流程

.macro CacheLookup
    //
    // Restart protocol:
    //
    //   As soon as we're past the LLookupStart$1 label we may have loaded
    //   an invalid cache pointer or mask.
    //
    //   When task_restartable_ranges_synchronize() is called,
    //   (or when a signal hits us) before we're past LLookupEnd$1,
    //   then our PC will be reset to LLookupRecover$1 which forcefully
    //   jumps to the cache-miss codepath which have the following
    //   requirements:
    //
    //   GETIMP:
    //     The cache-miss is just returning NULL (setting x0 to 0)
    //
    //   NORMAL and LOOKUP:
    //   - x0 contains the receiver
    //   - x1 contains the selector
    //   - x16 contains the isa
    //   - other registers are set as per calling conventions
    //
LLookupStart$1:

    // p1 = SEL, p16 = isa --- #define CACHE (2 * __SIZEOF_POINTER__)，其中 __SIZEOF_POINTER__表示pointer的大小 ，即 2*8 = 16
//---- p11 = mask|buckets -- 从x16（即isa）中平移16字节，取出cache 存入p11寄存器 -- isa距离cache 正好16字节：isa（8字节）-superClass（8字节）-cache（mask高16位 + buckets低48位）

    ldr p11, [x16, #CACHE]              // p11 = mask|buckets
//64位真机
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16
//--- p11(cache) & 0x0000ffffffffffff,mask高16位抹零,得到buckets存入p10寄存器-- 即去掉mask,留下buckets
    and p10, p11, #0x0000ffffffffffff   // p10 = buckets
//--- p11右移48位,获得mask & p1(msgSend的第二个参数 cmd-sel) 得到sel-imp的下标index（即搜索下标） 存入p12（cache insert写入时的哈希下标计算是 通过 sel & mask，读取时也需要通过这种方式）
    and p12, p1, p11, LSR #48       // x12 = _cmd & mask
//---非64位真机
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4
    and p10, p11, #~0xf         // p10 = buckets
    and p11, p11, #0xf          // p11 = maskShift
    mov p12, #0xffff
    lsr p11, p12, p11               // p11 = mask = 0xffff >> p11
    and p12, p1, p11                // x12 = _cmd & mask
#else
#error Unsupported cache mask storage for ARM64.
#endif

//--- p12是下标,p10是buckets数组首地址, 下标*1<<4(即16)得到实际内存的偏移量,通过buckets的首地址偏移,获取bucket存入p12寄存器
//--- LSL #(1+PTRSHIFT)-- 实际含义就是得到一个bucket占用的内存大小 -- 相当于mask = occupied-1 -- _cmd & mask -- 取余数
    add p12, p10, p12, LSL #(1+PTRSHIFT)
                     // p12 = buckets + ((_cmd & mask) << (1+PTRSHIFT))
//--- 从x12(即p12)中取出bucket 分别将imp和sel存入p17(存储imp)和p9(存储sel)
    ldp p17, p9, [x12]      // {imp, sel} = *bucket
//--- 比较sel与p1(传入的参数cmd)
1:  cmp p9, p1          // if (bucket->sel != _cmd)
//--- 如果不相等,即没有找到,请跳转到2f
    b.ne    2f          //     scan more
//--- 如果相等,即CacheHit 缓存命中,直接返回imp
    CacheHit $0         // call or return imp
    
2:  // not hit: p12 = not-hit bucket
//--- 如果一直都找不到,因为是normal,跳转至__objc_msgSend_uncached
    CheckMiss $0            // miss if bucket->sel == 0
//--- 判断p12(下标对应的bucket) 是否等于p10(buckets数组第一个元素),如果相等,则跳转到3f
    cmp p12, p10        // wrap if bucket == buckets
//--- 定位到最后一个元素
    b.eq    3f
//--- 从x12(即p12 buckets首地址) - 实际需要平移的内存大小BUCKET_SIZE,则得到第二个bucket元素,imp-sel分别存入p17-p9,即向前查找
    ldp p17, p9, [x12, #-BUCKET_SIZE]!  // {imp, sel} = *--bucket
//--- 跳转到第一步,继续对比sel 与 cmd
    b   1b          // loop

3:  // wrap: p12 = first bucket, w11 = mask
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16
//--- 人为设置到最后一个元素
//--- p11(mask)右移44位,相当于mask左移4位,直接定位到buckets最后一个元素,缓存查找顺序是向前查找
    add p12, p12, p11, LSR #(48 - (1+PTRSHIFT))
                    // p12 = buckets + (mask << 1+PTRSHIFT)
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4
    add p12, p12, p11, LSL #(1+PTRSHIFT)
                    // p12 = buckets + (mask << 1+PTRSHIFT)
#else
#error Unsupported cache mask storage for ARM64.
#endif
    // Clone scanning loop to miss instead of hang when cache is corrupt.
    // The slow path may detect any corruption and halt later.
//--- 再查找一遍缓存
    ldp p17, p9, [x12]      // {imp, sel} = *bucket
//--- 比较sel与p1
1:  cmp p9, p1          // if (bucket->sel != _cmd)
//--- 如果不相等，即走到第二步
    b.ne    2f          //     scan more
    //--- 如果相等 即命中，直接返回imp
    CacheHit $0         // call or return imp
    
2:  // not hit: p12 = not-hit bucket
//--- 如果一直找不到，则CheckMiss
    CheckMiss $0            // miss if bucket->sel == 0
//--- 判断p12（下标对应的bucket） 是否 等于 p10（buckets数组第一个元素）-- 表示前面已经没有了，但是还是没有找到
    cmp p12, p10        // wrap if bucket == buckets
    b.eq    3f
//--- 从x12（即p12 buckets首地址）- 实际需要平移的内存大小BUCKET_SIZE，得到得到第二个bucket元素，imp-sel分别存入p17-p9，即向前查找
    ldp p17, p9, [x12, #-BUCKET_SIZE]!  // {imp, sel} = *--bucket
//--- 跳转至第1步，继续对比 sel 与 cmd
    b   1b          // loop

LLookupEnd$1:
LLookupRecover$1:
3:  // double wrap
//--- 跳转至JumpMiss 因为是normal ，跳转至__objc_msgSend_uncached
    JumpMiss $0

.endmacro

以下是最后跳转的汇编函数
CacheHit源码

.macro CacheHit
.if $0 == NORMAL
    TailCallCachedImp x17, x12, x1, x16 // authenticate and call imp
.elseif $0 == GETIMP
    mov p0, p17
    cbz p0, 9f          // don't ptrauth a nil imp
    AuthAndResignAsIMP x0, x12, x1, x16 // authenticate imp and re-sign as IMP
9:  ret             // return IMP
.elseif $0 == LOOKUP
    // No nil check for ptrauth: the caller would crash anyway when they
    // jump to a nil IMP. We don't care if that jump also fails ptrauth.
    AuthAndResignAsIMP x17, x12, x1, x16    // authenticate imp and re-sign as IMP
    ret             // return imp via x17
.else
.abort oops
.endif
.endmacro

CheckMiss源码

.macro CheckMiss
    // miss if bucket->sel == 0
.if $0 == GETIMP 
//--- 如果为GETIMP ，则跳转至 LGetImpMiss
    cbz p9, LGetImpMiss
.elseif $0 == NORMAL 
//--- 如果为NORMAL ，则跳转至 __objc_msgSend_uncached
    cbz p9, __objc_msgSend_uncached
.elseif $0 == LOOKUP 
//--- 如果为LOOKUP ，则跳转至 __objc_msgLookup_uncached
    cbz p9, __objc_msgLookup_uncached
.else
.abort oops
.endif
.endmacro

JumpMiss 源码

.macro JumpMiss
.if $0 == GETIMP
    b   LGetImpMiss
.elseif $0 == NORMAL
    b   __objc_msgSend_uncached
.elseif $0 == LOOKUP
    b   __objc_msgLookup_uncached
.else
.abort oops
.endif
.endmacro

主要分为以下几步

• 【第一步】通过cache首地址平移16字节（因为在objc_class中，首地址距离cache正好16字节，即isa 占8字节，superClass占8字节），获取cahce，cache中高16位存mask，低48位存buckets，即p11 = cache

• 【第二步】从cache中分别取出buckets和mask，并由mask根据哈希算法计算出哈希下标

  • 通过cache和0x0000ffffffffffff的 & 运算，将高16位mask抹零，得到buckets指针地址，即p10 = buckets

  • 将cache右移48位，得到mask，即p11 = mask

  • 将objc_msgSend的参数p1（即第二个参数_cmd）& msak,通过与运算，得到需要查找存储sel在mask的bucket下标index，即p12 = index = _cmd & mask,为什么通过这种方式呢？因为在存储sel-imp时，也是通过同样与运算获取sel下标进行存储，所以读取也需要通过同样的方式读取，如下所示

    cache_hash

• 【第三步】根据所得的下标index 和 buckets首地址，取出哈希下标对应的bucket

  • 其中PTRSHIFT等于3，左移4位（即2^4 = 16字节）的目的是计算出一个bucket实际占用的大小,结构体bucket_t中sel占8字节，imp占8字节

  • 根据计算的哈希下标index 乘以单个bucket占用的内存大小，得到buckets首地址在实际内存中的偏移量

  • 通过首地址 + 实际偏移量，获取哈希下标index对应的bucket

• 【第四步】根据获取的bucket，取出其中的sel存入p17，即p17 = sel，取出imp存入p9，即p9 = imp

• 【第五步】第一次递归循环

  • 比较获取的bucket中sel 与 objc_msgSend的第二个参数的_cmd(即p1)是否相等

  • 如果相等，则直接跳转至CacheHit，即缓存命中，返回imp

  • 如果不相等，有以下两种情况

    • 如果一直都找不到，直接跳转至CheckMiss，因为$0是normal，会跳转至__objc_msgSend_uncached,进入慢速查找流程

    • 如果根据index获取的bucket 等于 buckets的第一个元素，则将当前bucket设置为buckets的最后一个元素（通过buckets首地址+mask右移44位（等同于左移4位）直接定位到bucker的最后一个元素），然后继续向前查找，进行递归循环

• 【第六步】第二次递归循环：重复【第五步】的操作，与【第五步】中唯一区别是，如果当前的bucket等于 buckets的第一个元素，则直接跳转至JumpMiss，此时的$0是normal，也是直接跳转至__objc_msgSend_uncached,进入慢速查找流程