关于SAS GTL输出Figure的分组(Group)问题的分享

之前的文章关于SAS GTL输出Figure的分组(Group)问题的分享1，介绍了两种处理Figure分组问题的方式：

1. 将不同分组的反应变量，做成不同的变量，用多个出图语句对新生成的反应变量进行处理；
2. 应用Group选项，用一个出图语句生成每一分组对应的图形。

这一篇介绍，在这两种方式处理方式中，图标(Legend)是如何设置的。在GTL中，discretelegend是设置图标的语句，而对于以上两种不同处理方式，图标的输出也有一些不同。接下来，一次展示两种图标的设置。

处理一：

第一种方式，将反应变量按组别做成3个不同的变量，对3个新变量各使用一个出图语句进行出图，每一个出图语句对应一个名称。discretelegend可以一起输出这3个折线图的图标： discretelegend "Seriousplot1" "Seriousplot2" "Seriousplot3" / displayclipped=true across=3 border=false;

***Get data for figure put;
data stocks1;
  set sashelp.stocks(where=(date between "1jan02"d and "31dec02"d));
  format date MONNAME3.;
  
  if stock = "IBM" then close_ibm = close;
  else if stock = "Intel" then close_intel = close;
  else if stock = "Microsoft" then close_microsoft = close;
run;

***Create figure template;
proc template;
  define statgraph Seriesplot1;
    begingraph;
      layout overlay/
        yaxisopts=(label="Close")
        xaxisopts=(label="Month" type=discrete);

        seriesplot y = close_ibm x = date /  name = "Seriousplot1";
        seriesplot y = close_intel x = date /  name = "Seriousplot2";
        seriesplot y = close_microsoft x = date /  name = "Seriousplot3";    

        discretelegend "Seriousplot1" "Seriousplot2" "Seriousplot3" / displayclipped=true across=3 border=false;

      endlayout;
    endgraph;
  end;
run;

***Render template;
proc sgrender data=stocks1 template=Seriesplot1;
run;

出图结果如下：

Legend1-1

我们可以看到，由于每一条折线图的属性设置相同（都是默认属性），输出的图标属性与图形保持一致，也是相同的。显然，在正常的项目分析中，是不允许出现这种情况的，不同分组的显示属性应该得到区分。下面对折线图的属性进行设置。

lineattrs选项是用来设置线图的属性，我们将不同分组的线图用不同的颜色予以区分。这样，图标的颜色会与线图的颜色保持一致，也会得到区分。具体的代码和结果如下：

proc template;
  define statgraph Seriesplot1;
    begingraph;
      layout overlay/
        yaxisopts=(label="Close")
        xaxisopts=(label="Month" type=discrete);

        seriesplot y = close_ibm x = date /  name = "Seriousplot1" lineattrs=(color=green pattern=1 thickness =2);
        seriesplot y = close_intel x = date /  name = "Seriousplot2" lineattrs=(color=red pattern=1 thickness =2);
        seriesplot y = close_microsoft x = date /  name = "Seriousplot3" lineattrs=(color=blue pattern=1 thickness =2);    

      discretelegend "Seriousplot1" "Seriousplot2" "Seriousplot3" / displayclipped=true across=3 border=false;

      endlayout;
    endgraph;
  end;
run;

Legend1-2

处理二：

出图语句直接使用Group选项后，SAS系统会自动为不同组别的图形设置属性。而这时候直接使用discretelegend语句，图标的属性也会与图形的属性一致，会得到区分。具体的代码和结果如下：

***Get data for figure put;
data stocks2;
  set sashelp.stocks(where=(date between "1jan02"d and "31dec02"d));
  format date MONNAME3.;
run;

***Create figure template;
proc template;
  define statgraph Seriesplot2;
    begingraph;
      layout overlay/
        yaxisopts=(label="Close")
        xaxisopts=(label="Month" type=discrete);

        seriesplot y = close x = date / group = stock groupdisplay = cluster name = "Seriousplot";
 
         discretelegend "Seriousplot" / displayclipped=true across=3 border=false;

      endlayout;
    endgraph;
  end;
run;

***Render template;
proc sgrender data=stocks2 template=Seriesplot2;
run;

Legend2

总结

两种方式都能实现图形以及对应图标的输出，不过从代码的简易性上说，使用Group语句是相对高效一点。

从最终的两张出图看，第一张手动设置出图属性的图形比第二张看起来鲜艳多了。SAS系统默认输出的颜色过于暗淡，这里就有一个需求出现了，在使用Group选项下，图形的各分组属性如何设置。我将在下一篇文章中进行分享。

若有疑问，欢迎评论区留言讨论。

相关文章：
关于SAS GTL输出Figure的分组(Group)问题的分享1
关于SAS GTL输出Figure的分组(Group)问题的分享3--Group选项的属性设置
关于SAS GTL输出Figure的分组(Group)问题的分享4--图标(Legend)内容的设置