day12 system_call 深入研究

作者: 柯基是只dog | 来源:发表于2018-12-12 16:57 被阅读0次

day12 system_call 深入研究
分析system_call中断处理过程
卟弃丰盛日记 Day12
2018-09-13
恶魔密密麻麻密密麻麻吗
今日份摄影作品（宝宝和玩偶）
自律给我自由—Day012
极简手绘100天
2018.12.22——线条
每日单词2018-04-11

前面我们分析了下fork的流程，但对system_call从调用方法返回后并没有分析，现在来看看，首先还是先放出代码

_system_call:
    cmp eax,nr_system_calls-1 ;// 调用号如果超出范围的话就在eax 中置-1 并退出。
    ja bad_sys_call
    push ds ;// 保存原段寄存器值。
    push es
    push fs
    push edx ;// ebx,ecx,edx 中放着系统调用相应的C 语言函数的调用参数。
    push ecx ;// push %ebx,%ecx,%edx as parameters
    push ebx ;// to the system call
    mov edx,10h ;// set up ds,es to kernel space
    mov ds,dx ;// ds,es 指向内核数据段(全局描述符表中数据段描述符)。
    mov es,dx
    mov edx,17h ;// fs points to local data space
    mov fs,dx ;// fs 指向局部数据段(局部描述符表中数据段描述符)。
;// 下面这句操作数的含义是：调用地址 = _sys_call_table + %eax * 4。参见列表后的说明。
;// 对应的C 程序中的sys_call_table 在include/linux/sys.h 中，其中定义了一个包括72 个
;// 系统调用C 处理函数的地址数组表。
    call [_sys_call_table+eax*4]
    push eax ;// 调用返回值入栈。
    mov eax,_current ;// 取当前任务（进程）数据结构地址??eax。
;// 下面97-100 行查看当前任务的运行状态。如果不在就绪状态(state 不等于0)就去执行调度程序。
;// 如果该任务在就绪状态但counter[??]值等于0，则也去执行调度程序。
    cmp dword ptr [state+eax],0 ;// state
    jne reschedule
    cmp dword ptr [counter+eax],0 ;// counter
    je reschedule
;// 以下这段代码执行从系统调用C 函数返回后，对信号量进行识别处理。
ret_from_sys_call:
;// 首先判别当前任务是否是初始任务task0，如果是则不必对其进行信号量方面的处理，直接返回。
;// 103 行上的_task 对应C 程序中的task[]数组，直接引用task 相当于引用task[0]。
    mov eax,_current ;// task[0] cannot have signals
    cmp eax,_task
    je l1 ;// 向前(forward)跳转到标号l1。
;// 通过对原调用程序代码选择符的检查来判断调用程序是否是超级用户。如果是超级用户就直接
;// 退出中断，否则需进行信号量的处理。这里比较选择符是否为普通用户代码段的选择符0x000f
;// (RPL=3，局部表，第1 个段(代码段))，如果不是则跳转退出中断程序。
    cmp word ptr [R_CS+esp],0fh ;// was old code segment supervisor ?
    jne l1
;// 如果原堆栈段选择符不为0x17（也即原堆栈不在用户数据段中），则也退出。
    cmp word ptr [OLR_DSS+esp],17h ;// was stack segment = 0x17 ?
    jne l1
;// 下面这段代码（109-120）的用途是首先取当前任务结构中的信号位图(32 位，每位代表1 种信号)，
;// 然后用任务结构中的信号阻塞（屏蔽）码，阻塞不允许的信号位，取得数值最小的信号值，再把
;// 原信号位图中该信号对应的位复位（置0），最后将该信号值作为参数之一调用do_signal()。
;// do_signal()在（kernel/signal.c,82）中，其参数包括13 个入栈的信息。
    mov ebx,[signal+eax] ;// 取信号位图??ebx，每1 位代表1 种信号，共32 个信号。
    mov ecx,[blocked+eax] ;// 取阻塞（屏蔽）信号位图??ecx。
    not ecx ;// 每位取反。
    and ecx,ebx ;// 获得许可的信号位图。
    bsf ecx,ecx ;// 从低位（位0）开始扫描位图，看是否有1 的位，
;// 若有，则ecx 保留该位的偏移值（即第几位0-31）。
    je l1 ;// 如果没有信号则向前跳转退出。
    btr ebx,ecx ;// 复位该信号（ebx 含有原signal 位图）。
    mov dword ptr [signal+eax],ebx ;// 重新保存signal 位图信息??current->signal。
    inc ecx ;// 将信号调整为从1 开始的数(1-32)。
    push ecx ;// 信号值入栈作为调用do_signal 的参数之一。
    call _do_signal ;// 调用C 函数信号处理程序(kernel/signal.c,82)
    pop eax ;// 弹出信号值。
l1: pop eax
    pop ebx
    pop ecx
    pop edx
    pop fs
    pop es
    pop ds
    iretd

我们看到，当执行完call [_sys_call_table+eax*4]之后还有一大堆的代码呢，现在就看看他干了什么

C语言

首先有个比较有意思的地方，我们已经对汇编有一定了解了，c语言只是比汇编更抽象了，c语言的struct编译后其实就是根据字段类型在内存中有一片连续的内存空间。当我们对一个对象取属性的指令比如obj->name，最后编译后其实是取从obj的地址到name的偏移位置的值。在这里面就用到了这种写法，汇编中用eax保存了当前进程的描述块，然后定义了几个变量标记他们在struct的偏移量，这样在汇编里就实现了obj->name这种调用方式了

;// 以下这些是任务结构(task_struct)中变量的偏移值，参见include/linux/sched.h，77 行开始。
state = 0 ;// these are offsets into the task-struct. ;// 进程状态码
counter = 4 ;// 任务运行时间计数(递减)（滴答数），运行时间片。
priority = 8 ;// 运行优先数。任务开始运行时counter=priority，越大则运行时间越长。
signal = 12 ;// 是信号位图，每个比特位代表一种信号，信号值=位偏移值+1。
sigaction = 16 ;// MUST be 16 (=len of sigaction) // sigaction 结构长度必须是16 字节。
;// 信号执行属性结构数组的偏移值，对应信号将要执行的操作和标志信息。
blocked = (33*16) ;// 受阻塞信号位图的偏移量。

所以接下来就