From: 微信公众号ANSYS结构院
https://mp.weixin.qq.com/s/k_eLhCaGBn-Qqqu4zbgHBg

影响线

影响线的求解在对工程特殊结构进行设计时是一项比较重要的工作，例如在地铁车站设计时考虑地铁移动荷载轨道梁的内力计算。根据影响线的定义，基于ANSYS提供的荷载步、时间历程概念，利用ANSYS可以很方便的求出结构影响线。

采用ANSYS绘制影响线的步骤如下：

• 一、结合单元划分，沿结构跨度等分，在N个等分点施加单位荷载F=1;
• 二、建立N个荷载步，也即是N个工况，每个荷载步对应时间取单位荷载所在位置坐标。
• 三、求解所有工况；
• 四、在时间历程后处理器中将需求截面内力定义为变量，由此绘制各定义变量相对时间的变化情况，也即是内力影响线。

案例

四跨连续梁，第一个中间支座弯矩和剪力的影响线。

单位m

命令流

!！完整案例四跨连续梁-影响线计算及后处理相关技巧*************************************************************
!===============================
finish
/clear
/filname,lianxuliang_yxx
!单位：N,mm
!单元，截面，材料===============================
/prep7
et,1,beam188
!
mp,ex,1,3e4      !混凝土
mp,prxy,1,0.3
mp,dens,1,2600e-12
!建模===============================
!定义截面
h=1500
b=600
sectype,1,beam,rect!梁截面
secdata,b,h   
!建立节点和单元
L=55.2e3   !结构总长
ELsize=200     !单元尺寸
ELnum=L/ELsize    !结构单元数目=55200/200+1=277,stat命令显示
*do,i,1,ELnum+1,1  
n,i,ELsize*(i-1)   !建立节点
*if,i,gt,1,then
e,i-1,i       !建立单元
*endif
*enddo
!node(x,y,z)获取最靠近坐标(x,y,z)的节点编号
N1=node(8400,0,0)
N2=node(21400,0,0)
N3=node(46600,0,0)
!约束
d,1,ux,,0,,,,uy,rotx,roty
d,1+ELnum,ux,,0,,,,uy,rotx,roty
d,N1,uy
d,N2,uy
d,N3,uy
allsel,all
d,all,uz
!======================
!影响线求解===============================
!1.在N个等分点施加单位荷载F=1;
!2.建立N个荷载步工况，对应时间取单位荷载所在位置坐标
!注意：
!（1）对单元表循环提取数据的操作
!（2）数组数据与后处理变量之间的相互转换
!（3）影响线数据的输出
/solu
antype,static
!outres,item, freq, cname 规定写入数据库的求解信息
outres,all,all
!
*do,j,1,1+ELnum
time,j*0.2    !对应时间取单位荷载所在位置坐标
*if,j,gt,1,then
fdele,all,all
*endif
f,j,fy,-1   !f, node, lab, value, value2, nend, ninc 在指定节点加集中荷载 
solve
*enddo
save
!======================
!后处理,得到某个截面的剪力和弯矩的影响线===============================
/post1
!step1.定义两个数组存储数据
!*dim, par, type, imax, jmax, kmax, var1, vae2, var3 定义数组 
*dim,jianli,array,ELnum   !剪力，数组，ELnum行1列
*dim,wanju,array,ELnum
!step2.定义需要查看影响线截面的位置坐标,得到内力
location=8400
nn=location/ELsize   !对应的单元编号数
*do,i,1,ELnum  !开始循环
set,i    !第i个荷载步
*get,JL,elem,nn,smisc,6   !剪力提取SFY
jianli(i)=JL     
*get,WJ,elem,nn,smisc,3   !剪力提取MZ
wanju(i)=WJ
*enddo     
!导入数据到变量中，查看结果===============================
!vput,将数组转化为变量
!plvar,绘图显示变量
/post26
vput,wanju,2   !将弯矩数组转化为变量2
vput,jianli,3   !将剪力数组转化为变量3
plvar,2   !绘图显示变量2-弯矩影响线
plvar,3    !绘图显示变量3-剪力影响线
!end===============================