Unity Shader 扰动、流动效果

Unity Shader系列文章：Unity Shader目录-初级篇

Unity Shader系列文章：Unity Shader目录-中级篇

效果：

效果

所需贴图：

噪声贴图 素材

shader代码:

// 扰动、流动效果
Shader "Custom/TextureNoise"
{
    Properties
    {
        // 贴图(UIImage 的 Sprite)
        [PerRendererData] _MainTex ("MainTex", 2D) = "white" { }// 主纹理
        // [NoScaleOffset] _MainTex ("MainTex", 2D) = "white" { } // 主纹理
        [NoScaleOffset] _NoiseTex ("噪点图", 2D) = "white" { }// 噪点图
        
        _NoiseSpeedX ("水平速度(负的表示反方向)", Range(-10, 10)) = 1  // 水平扰动速度
        _NoiseScaleX ("水平波纹大小", Range(0, 1)) = 0.1 // 噪点水平放大系数
        
        [Space(10)]
        _NoiseSpeedY ("垂直速度(负的表示反方向)", Range(-10, 10)) = 1  // 垂直扰动速度
        _NoiseScaleY ("垂直波纹大小", Range(0, 1)) = 0.1 // 噪点垂直放大系数
        
        [Space(10)]
        _NoiseBrightOffset ("偏移", Range(0, 0.9)) = 0.25 // 噪点图整体的数值偏移
    }
    SubShader
    {
        Tags { "Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" }
        
        Pass
        {
            // Tags { "LightMode" = "ForwardBase" }
            // ZWrite Off
            Blend SrcAlpha OneMinusSrcAlpha
            
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag
            
            #include "UnityCG.cginc"
            
            struct appdata
            {
                float4 vertex: POSITION;
                float2 uv: TEXCOORD0;
            };
            struct v2f
            {
                float4 vertex: SV_POSITION;
                float2 uv: TEXCOORD0;
            };
            sampler2D _MainTex;
            sampler2D _NoiseTex;
            fixed _NoiseScaleX;
            fixed _NoiseScaleY;
            fixed _NoiseSpeedX;
            fixed _NoiseSpeedY;
            fixed _NoiseBrightOffset;
            float4 _MainTex_ST;
            
            v2f vert(appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }
            
            fixed4 frag(v2f i): SV_Target
            {
                // 不采用此方法，改用透明度混合
                // 主纹理采样，若主纹理透明度为0，放弃绘制
                // fixed4 mainColor = tex2D(_MainTex, i.uv);
                // clip(mainColor.a - 0.001);
                
                // 噪点图采样，用于主纹理的UV偏移的
                fixed noiseUV_X = tex2D(_NoiseTex, i.uv + fixed2(_Time.x * _NoiseSpeedX, 0)).r;
                fixed noiseUV_Y = tex2D(_NoiseTex, i.uv + fixed2(0, _Time.x * _NoiseSpeedY)).r;
                fixed2 noiseUV = fixed2(noiseUV_X, noiseUV_Y);
                
                // 0~1 to ==> -_NoiseBrightOffset~ 1 - _NoiseBrightOffset
                // 偏移
                noiseUV -= _NoiseBrightOffset;
                // 扰动放大系数
                noiseUV *= fixed2(_NoiseScaleX, _NoiseScaleY);
                
                // 加上扰动UV后再采样主纹理
                fixed4 col = tex2D(_MainTex, i.uv + noiseUV);

                return col;
            }
            ENDCG

        }
    }
}