一. 蓝牙基础知识
1. 蓝牙4.0和BLE的区分
通常在了解一点蓝牙的朋友看来，往往将BLE等同于蓝牙4.0，其实不然。
蓝牙4.0是协议，4.0是协议版本号，蓝牙4.0是2010年6月由SIG（Special Interest Group）发布的蓝牙标准，它有2种模式：
BLE（Bluetooth low energy）只能与4.0协议设备通信，适应节能且仅收发少量数据的设备（如家用电子）；
BR/EDR（Basic Rate / Enhanced Data Rate），向下兼容（能与3.0/2.1/2.0通信），适应收发数据较多的设备（如耳机）。这个模式常常也有人称之为“传统蓝牙”或“经典蓝牙”。
可以这样理解，蓝牙4.0协议包含BLE，BLE隶属于蓝牙4.0协议的一部分
2. BLE和双模蓝牙的概念
Bluetooth Low Energy (也被称为Bluetooth 4.0、BLE、BTLE)，下面记作BLE，是使用2.4GHz的无线短距离无线通信标准。 迄今为止，虽然高速蓝牙已经实现，但BLE在通讯速度上比较普通，主要强调一个纽扣电池能够工作几年的这种省电性能。
设备端和主机端使用GATT(Generic ATTribute) profile进行通信。 如果你听到GATT这个名词，就可以将其想成使用BLE，这没什么问题。
由于与传统蓝牙不兼容，在主机端，和蓝牙3.0合并做为双模，实现成两者都可以使用的情况比较多。
3. BLE蓝牙架构图(了解)
最上面绿色的部分是应用层，主要是gatt和att我们可以把它看作是同一层。
sm是安全管理层，负责管理安全。
最下面link layer层和phy层基本上就是一些rf的处理。
4. GATT概念
GATT已经成为BLE通信的规定，每一个设备中存在很多的“service”(服务)，service中还包含有多个“Characteristic”（特征值）。
在蓝牙实际数据交换中，就是通过读写这些“Characteristic”来实现的。
- 一个鼠标是一个BLEDevice
- 一个BLEDevice建立了一个BLE服务器 BLEServer
- 一个BLE服务器里有多个服务BLEService
- 一个服务里有多个特征值BLECharacteristic 每个特征值是一种数据.就是通过读写这些“Characteristic”实现读写数据
每个characteristic的值可以在不加密的状态下读写，但配对的操作是加密的。 还有当characteristic的值已改变时，可接收通知（notify）。关于通知的概念请见下面小节.
5. UUID
服务和characteristic是通过UUID来进行识别的。
UUID是32位的，但那些被蓝牙技术联盟的标准中定义的UUID是以四个数字来表示的。UUID既有16位的也有128位的，我们需要了解的是16位的UUID是经过蓝牙组织认证的，是需要购买的，当然也有一些通用的16位UUID。
UUID：由蓝牙设备厂商提供的UUID，UUID是在硬件编程里已经确定了的，想要操作特定的服务、特征值都需要通过UUID来找。
6. notify通知的概念
如果主机的一个特征值characteristic发生改变, 可以使用通知notify来告诉客户端. 这是服务器主动给客户端发的信息, 并非是响应客户端的请求.
这样做有很多好处, 比如ESP32采集到了温度的变化, 可以将数据写入对应的特征值characteristic,然后notify通知客户端.
我们创建特征值时, 把它规定为通知类型, 当这个特征值发生变化时,可以通知客户端,像这样:
pCharacteristic = pService->createCharacteristic(CHARACTERISTIC_UUID_TX, BLECharacteristic::PROPERTY_NOTIFY);
//创建一个(读)特征值, 它是通知下发类型的特征值
其实客户端可以不接受服务器发送的notify,方法是修改自己的Descriptor. BLE服务器看到你对自己的描述中标识了不想接收notify,也就不会再给你发了.详见下面的视频.
7. write写入的概念
我们可以把特征值定为写入类型, 这样客户端可以给我们写入, 触发写入回调函数
BLECharacteristic *pCharacteristic = pService->createCharacteristic(CHARACTERISTIC_UUID_RX, BLECharacteristic::PROPERTY_WRITE);
//创建一个(写)特征, 它是写入类型的特征值
pCharacteristic->setCallbacks(new MyCallbacks());
//为特征添加一个回调
除了通知和写入, 还有好几种特征值类型, 请后续了解
其实BLE理论非常复杂,但我们理解到这个程度即可.附上一个帮助我们理解的视频:
https://www.bilibili.com/video/bv17v41117sq
二. ESP32 arduino 蓝牙BLE通讯的实现
1. 思路
把蓝牙设备看作服务器, 把手机看作一个客户端, 客户端可以给服务器发送数据, 服务器可以给客户端下发通知
实现思路:
- 创建BLE设备
BLEDevice::init(ble_name); - 创建BLE服务器
BLEServer *pServer = BLEDevice::createServer(); - 创建若干服务
BLEService *pService = pServer->createService(SERVICE_UUID); - 创建服务的特征值
下面的例子中, 我们创建了一个叫做pService 的服务, 这个服务其实是为了模拟串口
为了实现"串口",我们在这个服务下添加了两个特征值, 一个是TX. 一个是RX.
#include <Arduino.h>
#include <BLEDevice.h>
#include <BLEServer.h>
#include <BLEUtils.h>
#include <BLE2902.h>
#include <String.h>
BLECharacteristic *pCharacteristic; //创建一个BLE特性pCharacteristic
bool deviceConnected = false; //连接否标志位
uint8_t txValue = 0; //TX的值
long lastMsg = 0; //存放时间的变量
String rxload = "BlackWalnutLabs"; //RX的预置值
#define SERVICE_UUID "6E400001-B5A3-F393-E0A9-E50E24DCCA9E" // UART service UUID
#define CHARACTERISTIC_UUID_RX "6E400002-B5A3-F393-E0A9-E50E24DCCA9E"
#define CHARACTERISTIC_UUID_TX "6E400003-B5A3-F393-E0A9-E50E24DCCA9E"
//服务器回调
class MyServerCallbacks : public BLEServerCallbacks
{
void onConnect(BLEServer *pServer)
{
deviceConnected = true;
};
void onDisconnect(BLEServer *pServer)
{
deviceConnected = false;
}
};
//特性回调
class MyCallbacks : public BLECharacteristicCallbacks
{
void onWrite(BLECharacteristic *pCharacteristic)
{
std::string rxValue = pCharacteristic->getValue();
if (rxValue.length() > 0)
{
rxload = "";
for (int i = 0; i < rxValue.length(); i++)
{
rxload += (char)rxValue[i];
Serial.print(rxValue[i]);
}
Serial.println("");
}
}
};
void setupBLE(String BLEName)
{
const char *ble_name = BLEName.c_str(); //将传入的BLE的名字转换为指针
BLEDevice::init(ble_name); //初始化一个蓝牙设备
BLEServer *pServer = BLEDevice::createServer(); // 创建一个蓝牙服务器
pServer->setCallbacks(new MyServerCallbacks()); //服务器回调函数设置为MyServerCallbacks
BLEService *pService = pServer->createService(SERVICE_UUID); //创建一个BLE服务
pCharacteristic = pService->createCharacteristic(CHARACTERISTIC_UUID_TX, BLECharacteristic::PROPERTY_NOTIFY);
//创建一个(读)特征值 类型是通知
pCharacteristic->addDescriptor(new BLE2902());
//为特征添加一个描述
BLECharacteristic *pCharacteristic = pService->createCharacteristic(CHARACTERISTIC_UUID_RX, BLECharacteristic::PROPERTY_WRITE);
//创建一个(写)特征 类型是写入
pCharacteristic->setCallbacks(new MyCallbacks());
//为特征添加一个回调
pService->start(); //开启服务
pServer->getAdvertising()->start(); //服务器开始广播
Serial.println("Waiting a client connection to notify...");
}
void setup()
{
Serial.begin(115200);
setupBLE("ESP32BLE"); //设置蓝牙名称
}
void loop()
{
long now = millis(); //记录当前时间
if (now - lastMsg > 1000)
{ //每隔1秒发一次信号
if (deviceConnected && rxload.length() > 0)
{
String str = rxload;
if (str=="10086\r\n")
{
const char *newValue = str.c_str();
pCharacteristic->setValue(newValue);
pCharacteristic->notify();
}
}
lastMsg = now; //刷新上一次发送数据的时间
}
}
网友评论