阴影_统一管理光照衰减和阴影

Shader "Unlit/AttenuationAndShadowUseBuildInFunction"
{
    
        Properties {
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
        _Specular ("Specular", Color) = (1, 1, 1, 1)
        _Gloss ("Gloss", Range(8.0, 256)) = 20
        }
    
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        

        Pass
        {
            Tags { "LightMode"="ForwardBase" }

            CGPROGRAM

            //保证shader中使用光照衰减等光照变量可以正确被赋值 >>> multi_compile_fwdbase
            #pragma multi_compile_fwdbase       
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fog
            
            #include "Lighting.cginc"
                                                                        //加入
            #include "AutoLight.cginc"                                  

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct a2v {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f {
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
                SHADOW_COORDS(2)                                        //加入
            };

            
            
            v2f vert(a2v v) {

                v2f o;  //声明vert的输出结构
                o.pos = UnityObjectToClipPos(v.vertex);     
                o.worldNormal = UnityObjectToWorldNormal(v.normal); 
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
                TRANSFER_SHADOW(o);                                     //加入
                return o;
            }
            
            fixed4 frag(v2f i) : SV_Target 
            {   
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz; //获取环境光
                //下面可以用worldLightDir=UnityWorldSpaceLightDir(i.worldPos)来实现，这个是unity5新加的计算光照方向的函数

                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);      //灯光的方向可以通过_WorldSpaceLightPos0来访问第一个重要光源              
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz); //视角方向可以用unity5新加的计算viewDir的函数：UnityWorldSpaceViewDir(i.worldPos)
                fixed3 halfDir = normalize(worldLightDir + viewDir); //half
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss); //blinnphong光照模型
                

                UNITY_LIGHT_ATTENUATION(atten,i,i.worldPos);             //加入

                return fixed4(ambient + (diffuse + specular) * atten , 1.0);

            }
            ENDCG 
        }   //处理平行光主光源pass结束

        pass{

                Tags { "LightMode"="ForwardAdd" }
            
                Blend One One   //大小写都行。如果没有blend命令，addpass将直接覆盖掉前一个pass的光照结果

                CGPROGRAM
            
            ////这个指令可以保证我们正确访问到光照变量
            #pragma multi_compile_fwdadd        
            #pragma vertex vert
            #pragma fragment frag
            
            #include "Lighting.cginc"
            #include "AutoLight.cginc"

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct a2v {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };
            
            struct v2f {
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
            };

            v2f vert(a2v v) {

                v2f o;  //声明vert的输出结构
                o.pos = UnityObjectToClipPos(v.vertex);         
                o.worldNormal = UnityObjectToWorldNormal(v.normal);             
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;                
                return o;
            }

            fixed4 frag(v2f i) : SV_Target {

                fixed3 worldNormal = normalize(i.worldNormal);

                //下面可以用worldLightDir=UnityWorldSpaceLightDir(i.worldPos)来实现，这个是unity5新加的计算光照方向的函数
                //下面开始判断光源类型，来分别计算其灯光属性，比如灯光位置，灯光方向，因为不同类型的灯光计算方法不一样，所以必须做判断
                #ifdef USING_DIRECTIONAL_LIGHT
                    fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz); //灯光的方向可以通过_WorldSpaceLightPos0来计算平行光方向
                #else
                    fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz - i.worldPos.xyz);
                #endif
                
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));

                //视角方向可以用unity5新加的计算viewDir的函数：UnityWorldSpaceViewDir(i.worldPos)           
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
                fixed3 halfDir = normalize(worldLightDir + viewDir);
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss); //BllinPhong光照模型

                //如果定义了USING_DIRECTIONAL_LIGHT，则表示当前片元着色器是在处理的是平行光，否则是其他光源
                #ifdef USING_DIRECTIONAL_LIGHT
                    fixed atten = 1.0;
                #else
                    #if defined (POINT)
                        float3 lightCoord = mul(unity_WorldToLight, float4(i.worldPos, 1)).xyz; //把顶点从世界空间转换到光源空间
                        fixed atten = tex2D(_LightTexture0, dot(lightCoord, lightCoord).rr).UNITY_ATTEN_CHANNEL; //利用光源空间顶点坐标模的平方对纹理采样，避免开放，不开方
                        //使用宏.UNITY_ATTEN_CHANNEL来得到衰减纹理中衰减所在的分量
                    #elif defined (SPOT)
                        float4 lightCoord = mul(unity_WorldToLight, float4(i.worldPos, 1)); //把顶点从世界空间转换到光源空间
                        fixed atten = (lightCoord.z > 0) * tex2D(_LightTexture0, lightCoord.xy / lightCoord.w + 0.5).w * tex2D(_LightTextureB0, dot(lightCoord, lightCoord).rr).UNITY_ATTEN_CHANNEL;
                    #else
                        fixed atten = 1.0;
                #endif
                #endif
                

                return fixed4((diffuse + specular) * atten, 1.0);
            }

            ENDCG

        }
    }
    FallBack "Specular"                                             //一定要加 这一句
}