写一个 Markdown translator 玩？

Markdown 早在 2004 年就被发明出来，能够普及到现在的程度离不开它的发明者和所有使用它来写作的人👏

它的基本语法说明可以在其发明者的 Blog 中找到。Markdown 的流行一定程度上离不开 github 的贡献，同时 github 也扩展了 Markdown 语法，使得它可以表达更加丰富的内容。

Markdown 的出现就是为了让文本内容变得易读易写，所以借助 Markdown 的语法格则，即使在纯文本模式下也可以获得比较好的阅读效果。不过，很多情况下，我们会将 Markdown 解析成 HTML，配合 CSS 来获得更加绚丽的阅读感受。

在我最初接触 Markdown 的时候，我发现很多解析器之间的结果存在差异，比如有这样的文本：

# header
===

相信你会找到不只一个 Markdown 解析器，那么它们对于上面的文本会产生不同的解析结果吗？

答案是肯定的。

那么是什么原因导致不同的解析器之间产生的结果会不同？我相信很多人都已经知道了 i++ * i++ * i++ 这个经典的 C语言的问题了 (如果不知道可以看这里)

没错，这就是 Markdown 中的 Undefined Behavior，究其原因就是因为 Markdown 的发明者并没有给出 Markdown 语法的完整定义，他只是在语法说明中举了一些简单的例子，并附上了自己使用 Perl 写的 Translator。不幸的是这段代码早已年久失修，你可以很容易找出它的 bug，对于下面的文本：

> ## This is an H2 in a blockquote
> > nested blockquote
> H1
> ====

它会给出下面的结果：

<blockquote>
  <h2>This is an H2 in a blockquote</h2>

<blockquote>
  <p>nested blockquote</p>

<h1>H1</h1>
</blockquote>

<p></blockquote></p>

熟悉 HTML 语法的同学很容易就会发现最后一行的错误。

正是由于 Markdown 的作者没有给出完整的语法定义，导致在遇到一些 Undefined Behavior 时，每个 translator 的作者必须自己去想一个合适的输出结果，这样就导致了各家的输出会有一些出入。可能作者也没想到 Markdown 会流行到这个程度吧，哈。

很早之前我曾用 js 写过一个简陋的 Markdown translator，它是由若干的正则配合一些流程控制语句来完成的。最近看到很多关于 Markdown 语法的文章，我就又回头看了下那些代码，于是决定使用 swift 重写一个。

这次重写我决定装出点样子，代码中将不使用正则，在解析了 Markdown 文本之后，首先生成一个 Tree，然后才是根据 Tree 中的内容产生 HTML。

当然在写之前，还是要分析下 Markdown 语法，并不能只是看看一些小例子，需要在 github 和其他几个 Markdown 编辑软件不断中试错，小结出语法，并使用 XEBNF 来描述。

XEBNF 是我自己的 extend BNF，哈哈。使用 XEBNF 是因为 BNF 的 ::= 书写太麻烦，而 ABNF 又没有 EBNF 中的 exception - 功能。我还写了一个 Atom 的 Syntax 来支持 XBNF，于是它们看起来像是这样：

下面就是我目前小结出的语法，目前只有 block 元素，因为我先写的块元素的解析：

Char                          = [#x0000-#xD7FF] | [#xE000-#x10FFFF]
SP                            = #x0020
HTAB                          = #x0009
CR                            = #x000D
LF                            = #x000A
CRLF                          = CR LF
NL                            = CR | LF | CRLF
WSP                           = HTAB | SP
LWSP                          = NL | WSP
DIGIT                         = [#x0030-#x0039]

; md
md                            = md-block*

; md-block
md-block                      = paragraph | header | blockquote | list | codeblock

; paragraph
paragraph-begin               = SP{0,3} ( Char - ( LWSP | ">" | "*" | "#" ) )
paragraph-content             = ( ( Char - NL ) NL? )+
paragraph-end                 = NL{2} | NL ( Char - ( ">" | "*" | "#" ) )
paragraph                     = paragraph-begin paragraph-content paragraph-end

; header-setext
header-setext-begin           = SP{0,3} ( Char - ( LWSP | ">" | "*" | "# ) )
header-setext-content         = Char - NL
header-setext-end             = NL ( "=" | "-" )+
header-setext                 = header-setext-begin header-setext-content header-setext-end

; header-atx
header-atx-begin              = SP{0,3} "#"+ WSP* ( Char - LWSP )
header-atx-content            = Char - NL
header-atx-end                = "#"* NL
header-atx                    = header-atx-begin header-atx-content header-atx-end

; header
header                        = header-setext | header-atx

; blockquote
blockquote-begin              = SP{0,3} ">"
blockquote-content            = ( header | paragraph | blockquote | list | codeblock )*
blockquote-end                = NL{2} ( Char - ">" )

; list-ul-item
list-ul-item-begin            = SP{0,3} "*" WSP
list-ul-item-content          = ( paragraph | blockquote | list | codeblock )*
list-ul-item-end              = NL{2} ( Char - SP )
list-ul-item                  = list-ul-item-begin list-ul-item-content list-ul-item-end

; list-ul
list-ul                       = list-ul-item+

; list-ol-item
list-ol-item-begin            = SP{0,3} DIGIT "." WSP
list-ol-item-content          = ( paragraph | blockquote | list | codeblock )*
list-ol-item-end              = NL{2} ( Char - SP )
list-ol-item                  = list-ol-item+

; list
list                          = list-ul | list-ol

; codeblock-md
codeblock-md-begin            = ( SP{4} | HTAB ) WSP* ( Char - WSP )
codeblock-md-content          = Char* - codeblock-md-end
codeblock-md-end              = NL SP{0,3} ( Char - WSP )
codeblock-md                  = codeblock-md-begin codeblock-md-content codeblock-md-end

; codeblock-ext
codeblock-ext-begin           = SP{0,3} "`"{3} ( Char - NL ) NL
codeblock-ext-content         = Char* - codeblock-ext-end
codeblock-ext-end             = NL "`"{3} ( Char - NL ) NL
codeblock-ext                 = codeblock-ext-begin codeblock-ext-content codeblock-ext-end

; codeblock
codeblock                     = codeblock-md | codeblock-ext

; html-element
html-element-attr             = Char+ - LWSP
html-element-name             = Char+ - LWSP

html-void-element             = SP{0,3} "<"html-element-name WSP* "/>" NL

html-normal-element-start     = SP{0,3} "<"html-element-name (WSP+ html-element-attr)* WSP* ">"
html-normal-element-content   = Char* - html-normal-element-end
html-normal-element-end       = "</"html-element-name WSP* ">" NL
html-normal-element           = html-normal-element-start html-normal-element-content html-normal-element-end

html-element                  = html-empty-element | html-void-element

有了语法之后，就可以开始写代码了，过程是很枯燥的，就是运用递归下降的方式，都是一些很机械的工作，代码在这里，相信会坚持写完吧🤔

希望可以给想要自己动手写一个 Markdown translator 的同学一点帮助吧😄