上一篇主要记录了一些Android的AOP编程的笔记
Android AOP面向切面编程和Gradle插件编写(一)
这一篇就大概记录一下我的关于编写Gradle插件的笔记吧
如何用Android Studio编写一个Gradle插件呢
可以参考如何使用Android Studio开发Gradle插件
首先我们需要先建立一个Android Library的模块
保留一个build.gradle文件然后其他的就删掉吧
建立如下目录结构
.
├── build.gradle
└── src
└── main
├── groovy
│ └── com
│ └── sundae
│ └── aoplib
│ └── plugin
│ └── AopLibPlugin.groovy
└── resources
└── META-INF
└── gradle-plugins
└── aoplibplugin.properties
image.png
像这样
建立src/main/groovy/包名/文件.groovy 的文件
这个文件使用来编写插件内容的，注意是.groovy结尾的文件
在文件中编写如下内容
package com.sundae.aoplib.plugin
import org.gradle.api.Plugin
import org.gradle.api.Project
class AopLibPlugin implements Plugin<Project> {
@Override
void apply(Project project) {
println("==================")
println(" Gradle插件 ")
println("==================")
}
然后在src/main/resources/META-INF/gradle-plugins(这个路径不能变，这是用来识别插件的路径)
在目录下建立 插件名.properties的文件
文件内编写
implementation-class=com.sundae.aoplib.plugin.AopLibPlugin
(这个路径对应了编写的插件的路径)
接着编写module的build.gradle文件
apply plugin: 'groovy'
apply plugin: 'maven'
dependencies {
compile gradleApi()
compile localGroovy()
}
repositories {
mavenCentral()
}
这样一个简单的gradle插件就编写好了
然而这样还不好使用这个插件
要使用这个插件我们需要将它编译发布到本地的maven中央仓库里
继续在module的build.gradle文件中写入
group='com.sundae.aoplib.plugin'
version='0.0.1'
uploadArchives {
repositories {
mavenDeployer {
repository(url: uri('../repo'))
}
}
}
上面的group和version的定义会被使用，作为maven库的坐标的一部分，group会被作为坐标的groupId，version会被作为坐标的version，而坐标的artifactId组成即module名，我们让其取一个别名moduleName。然后maven本地仓库的目录就是当前项目目录下的repo目录。
这时候，右侧的gradle Toolbar就会在module下多出一个task
image.png
点击这个Task就会将这个插件模块发布到本地maven仓库里了
image.png
这样就发布完成了，要使用它我们只需要在app的build.gardle中加入
buildscript {
repositories {
maven {
url uri('../repo')
}
}
dependencies {
classpath 'com.sundae.aoplib.plugin:aoplib-plugin:0.0.1'
//包名:插件类名:版本号
}
}
apply plugin: 'aoplibplugin' ///插件名
然后build编译或点sync now一下，就可以看到gradle console中出现了这样的输出
image.png
这样一个编写gradle的插件的流程就结束了
接下来就是重点了，接着之前的问题，如何使用gradle插件自动加入一些编译器的配置呢
需要在插件类内编写如下内容
package com.sundae.aoplib.plugin
import com.android.build.gradle.AppPlugin
import com.android.build.gradle.LibraryPlugin
import org.gradle.api.Plugin
import org.gradle.api.Project
import org.gradle.api.tasks.compile.JavaCompile
import org.aspectj.bridge.IMessage
import org.aspectj.bridge.MessageHandler
import org.aspectj.tools.ajc.Main
class AopLibPlugin implements Plugin<Project> {
@Override
void apply(Project project) {
// println("==================")
// println(" Gradle插件 ")
// println("==================")
if (!project.android) {
throw new IllegalStateException('Must apply \'com.android.application\' or \'com.android.library\' first!')
}
//// 需要分辨是在app的gradle中使用插件还是在module中使用插件
def isApp = false
def isLib = false
isApp = project.plugins.withType(AppPlugin)
isLib = project.plugins.withType(LibraryPlugin)
if (!isApp && !isLib) {
throw new IllegalStateException("'android' or 'android-library' plugin required.")
}
final def log = project.logger
final def variants
if (isApp) {
variants = project.android.applicationVariants
} else {
variants = project.android.libraryVariants
}
//////////////////////////////////////////////////////////////////////////
project.dependencies {
compile 'org.aspectj:aspectjrt:1.8.9'
}
variants.all { variant ->
JavaCompile javaCompile = variant.javaCompile
javaCompile.doLast {
String[] args = ["-showWeaveInfo",
"-1.5",
"-inpath", javaCompile.destinationDir.toString(),
"-aspectpath", javaCompile.classpath.asPath,
"-d", javaCompile.destinationDir.toString(),
"-classpath", javaCompile.classpath.asPath,
"-bootclasspath", project.android.bootClasspath.join(
File.pathSeparator)]
MessageHandler handler = new MessageHandler(true);
new Main().run(args, handler)
for (IMessage message : handler.getMessages(null, true)) {
switch (message.getKind()) {
case IMessage.ABORT:
case IMessage.ERROR:
case IMessage.FAIL:
log.error message.message, message.thrown
break;
case IMessage.WARNING:
case IMessage.INFO:
log.info message.message, message.thrown
break;
case IMessage.DEBUG:
log.debug message.message, message.thrown
break;
}
}
}
}
}
}
因为需要aspectj和gradle tool的包的缘故，所以需要将插件的build.gradle内容改为
apply plugin: 'groovy'
apply plugin: 'maven'
dependencies {
compile gradleApi()
compile localGroovy()
compile 'com.android.tools.build:gradle:2.3.0' ///add
compile 'org.aspectj:aspectjtools:1.8.9' ///add
compile 'org.aspectj:aspectjrt:1.8.9' ///add
}
repositories {
mavenCentral()
}
group='com.sundae.aoplib.plugin'
version='0.0.1'
uploadArchives {
repositories {
mavenDeployer {
repository(url: uri('../repo'))
}
}
}
点击uploadArchives重新编译发布插件模块
app项目中重新应用这个插件
这样原本需要配置的二十几行的编译器配置代码就可以直接用几行代码调用插件来完成啦，是不是不仅方便快捷，而且代码一下子清爽了不少呢，哈哈哈哈😁
上一波我的源码(GitHub)一个Android的AOP面向切面编程的小例子
明天十一放假啦，准备去张家界旅(qiong)游一趟，怕玩结束回来都忘得差不多了，所以今天熬夜记录下来。
好了 ，完事 ，上床睡觉！
ps：菜鸟上路，有问题的地方请多指教😁
网友评论